git.sur5r.net Git - i3/i3/blob - testcases/complete-run.pl

   1 #!/usr/bin/env perl
   2 # vim:ts=4:sw=4:expandtab
   3 #
   4 # © 2010-2011 Michael Stapelberg and contributors
   5 #
   6 # syntax: ./complete-run.pl --display :1 --display :2
   7 # to run the test suite on the X11 displays :1 and :2
   8 # use 'Xdummy :1' and 'Xdummy :2' before to start two
   9 # headless X11 servers
  10 #
  11
  12 use strict;
  13 use warnings;
  14 use EV;
  15 use AnyEvent;
  16 use IO::Scalar; # not in core :\
  17 use File::Temp qw(tempfile tempdir);
  18 use v5.10;
  19 use DateTime;
  20 use Data::Dumper;
  21 use Cwd qw(abs_path);
  22 use Proc::Background;
  23 use TAP::Harness;
  24 use TAP::Parser;
  25 use TAP::Parser::Aggregator;
  26 use File::Basename qw(basename);
  27 use AnyEvent::I3 qw(:all);
  28 use Try::Tiny;
  29 use Getopt::Long;
  30 use Time::HiRes qw(sleep);
  31 use X11::XCB::Connection;
  32 use IO::Socket::UNIX; # core
  33 use POSIX; # core
  34 use AnyEvent::Handle;
  35
  36 # open a file so that we get file descriptor 3. we will later close it in the
  37 # child and dup() the listening socket file descriptor to 3 to pass it to i3
  38 open(my $reserved, '<', '/dev/null');
  39 if (fileno($reserved) != 3) {
  40     warn "Socket file descriptor is not 3.";
  41     warn "Please don't start this script within a subshell of vim or something.";
  42     exit 1;
  43 }
  44
  45 # install a dummy CHLD handler to overwrite the CHLD handler of AnyEvent / EV
  46 # XXX: we could maybe also use a different loop than the default loop in EV?
  47 $SIG{CHLD} = sub {
  48 };
  49
  50 # reads in a whole file
  51 sub slurp {
  52     open my $fh, '<', shift;
  53     local $/;
  54     <$fh>;
  55 }
  56
  57 my $coverage_testing = 0;
  58 my @displays = ();
  59
  60 my $result = GetOptions(
  61     "coverage-testing" => \$coverage_testing,
  62     "display=s" => \@displays,
  63 );
  64
  65 @displays = split(/,/, join(',', @displays));
  66 @displays = map { s/ //g; $_ } @displays;
  67
  68 @displays = qw(:1) if @displays == 0;
  69
  70 # connect to all displays for two reasons:
  71 # 1: check if the display actually works
  72 # 2: keep the connection open so that i3 is not the only client. this prevents
  73 #    the X server from exiting (Xdummy will restart it, but not quick enough
  74 #    sometimes)
  75 my @conns;
  76 my @wdisplays;
  77 for my $display (@displays) {
  78     try {
  79         my $x = X11::XCB::Connection->new(display => $display);
  80         push @conns, $x;
  81         push @wdisplays, $display;
  82     } catch {
  83         say STDERR "WARNING: Not using X11 display $display, could not connect";
  84     };
  85 }
  86
  87 my $config = slurp('i3-test.config');
  88
  89 # 1: get a list of all testcases
  90 my @testfiles = @ARGV;
  91
  92 # if no files were passed on command line, run all tests from t/
  93 @testfiles = <t/*.t> if @testfiles == 0;
  94
  95 # 2: create an output directory for this test-run
  96 my $outdir = "testsuite-";
  97 $outdir .= DateTime->now->strftime("%Y-%m-%d-%H-%M-%S-");
  98 $outdir .= `git describe --tags`;
  99 chomp($outdir);
 100 mkdir($outdir) or die "Could not create $outdir";
 101 unlink("latest") if -e "latest";
 102 symlink("$outdir", "latest") or die "Could not symlink latest to $outdir";
 103
 104 # 3: run all tests
 105 my @done;
 106 my $num = @testfiles;
 107 my $harness = TAP::Harness->new({ });
 108
 109 my $aggregator = TAP::Parser::Aggregator->new();
 110 $aggregator->start();
 111
 112 my $cv = AnyEvent->condvar;
 113
 114 # We start tests concurrently: For each display, one test gets started. Every
 115 # test starts another test after completing.
 116 take_job($_) for @wdisplays;
 117
 118 #
 119 # Takes a test from the beginning of @testfiles and runs it.
 120 #
 121 # The TAP::Parser (which reads the test output) will get called as soon as
 122 # there is some activity on the stdout file descriptor of the test process
 123 # (using an AnyEvent->io watcher).
 124 #
 125 # When a test completes and @done contains $num entries, the $cv condvar gets
 126 # triggered to finish testing.
 127 #
 128 sub take_job {
 129     my ($display) = @_;
 130
 131     my $test = shift @testfiles;
 132     return unless $test;
 133     my $dont_start = (slurp($test) =~ /# !NO_I3_INSTANCE!/);
 134     my $logpath = "$outdir/i3-log-for-" . basename($test);
 135
 136     my ($fh, $tmpfile) = tempfile();
 137     say $fh $config;
 138     say $fh "ipc-socket /tmp/nested-$display";
 139     close($fh);
 140
 141     my $activate_cv = AnyEvent->condvar;
 142     my $start_i3 = sub {
 143         # remove the old unix socket
 144         unlink("/tmp/nested-$display-activation");
 145
 146         # pass all file descriptors up to three to the children.
 147         # we need to set this flag before opening the socket.
 148         open(my $fdtest, '<', '/dev/null');
 149         $^F = fileno($fdtest);
 150         close($fdtest);
 151         my $socket = IO::Socket::UNIX->new(
 152             Listen => 1,
 153             Local => "/tmp/nested-$display-activation",
 154         );
 155
 156         my $pid = fork;
 157         if (!defined($pid)) {
 158             die "could not fork()";
 159         }
 160         say "pid = $pid";
 161         if ($pid == 0) {
 162             say "child!";
 163             $ENV{LISTEN_PID} = $$;
 164             $ENV{LISTEN_FDS} = 1;
 165             $ENV{DISPLAY} = $display;
 166             $^F = 3;
 167
 168             say "fileno is " . fileno($socket);
 169             close($reserved);
 170             POSIX::dup2(fileno($socket), 3);
 171
 172             # now execute i3
 173             my $i3cmd = abs_path("../i3") . " -V -d all --disable-signalhandler";
 174             my $cmd = "exec $i3cmd -c $tmpfile >$logpath 2>&1";
 175             exec "/bin/sh", '-c', $cmd;
 176
 177             # if we are still here, i3 could not be found or exec failed. bail out.
 178             exit 1;
 179         }
 180
 181         my $child_watcher;
 182         $child_watcher = AnyEvent->child(pid => $pid, cb => sub {
 183             say "child died. pid = $pid";
 184             undef $child_watcher;
 185         });
 186
 187         # close the socket, the child process should be the only one which keeps a file
 188         # descriptor on the listening socket.
 189         $socket->close;
 190
 191         # We now connect (will succeed immediately) and send a request afterwards.
 192         # As soon as the reply is there, i3 is considered ready.
 193         my $cl = IO::Socket::UNIX->new(Peer => "/tmp/nested-$display-activation");
 194         my $hdl;
 195         $hdl = AnyEvent::Handle->new(fh => $cl, on_error => sub { $activate_cv->send(0) });
 196
 197         # send a get_tree message without payload
 198         $hdl->push_write('i3-ipc' . pack("LL", 0, 4));
 199
 200         # wait for the reply
 201         $hdl->push_read(chunk => 1, => sub {
 202             my ($h, $line) = @_;
 203             say "read something from i3";
 204             $activate_cv->send(1);
 205             undef $hdl;
 206         });
 207
 208         return $pid;
 209     };
 210
 211     my $pid;
 212     $pid = $start_i3->() unless $dont_start;
 213
 214     my $kill_i3 = sub {
 215         # Don’t bother killing i3 when we haven’t started it
 216         return if $dont_start;
 217
 218         # When measuring code coverage, try to exit i3 cleanly (otherwise, .gcda
 219         # files are not written) and fallback to killing it
 220         if ($coverage_testing) {
 221             my $exited = 0;
 222             try {
 223                 say "Exiting i3 cleanly...";
 224                 i3("/tmp/nested-$display")->command('exit')->recv;
 225                 $exited = 1;
 226             };
 227             return if $exited;
 228         }
 229
 230         say "[$display] killing i3";
 231         kill(9, $pid) or die "could not kill i3";
 232     };
 233
 234     # This will be called as soon as i3 is running and answered to our
 235     # IPC request
 236     $activate_cv->cb(sub {
 237         say "cb";
 238         my ($status) = $activate_cv->recv;
 239         say "complete-run: status = $status";
 240
 241         say "[$display] Running $test with logfile $logpath";
 242
 243         my $output;
 244         my $parser = TAP::Parser->new({
 245             exec => [ 'sh', '-c', "DISPLAY=$display /usr/bin/perl -It/lib $test" ],
 246             spool => IO::Scalar->new(\$output),
 247             merge => 1,
 248         });
 249
 250         my @watchers;
 251         my ($stdout, $stderr) = $parser->get_select_handles;
 252         for my $handle ($parser->get_select_handles) {
 253             my $w;
 254             $w = AnyEvent->io(
 255                 fh => $handle,
 256                 poll => 'r',
 257                 cb => sub {
 258                     # Ignore activity on stderr (unnecessary with merge => 1,
 259                     # but let’s keep it in here if we want to use merge => 0
 260                     # for some reason in the future).
 261                     return if defined($stderr) and $handle == $stderr;
 262
 263                     my $result = $parser->next;
 264                     if (defined($result)) {
 265                         # TODO: check if we should bail out
 266                         return;
 267                     }
 268
 269                     # $result is not defined, we are done parsing
 270                     say "[$display] $test finished";
 271                     close($parser->delete_spool);
 272                     $aggregator->add($test, $parser);
 273                     push @done, [ $test, $output ];
 274
 275                     $kill_i3->();
 276
 277                     undef $_ for @watchers;
 278                     if (@done == $num) {
 279                         $cv->send;
 280                     } else {
 281                         take_job($display);
 282                     }
 283                 }
 284             );
 285             push @watchers, $w;
 286         }
 287     });
 288
 289     $activate_cv->send(1) if $dont_start;
 290 }
 291
 292 $cv->recv;
 293
 294 $aggregator->stop();
 295
 296 for (@done) {
 297     my ($test, $output) = @$_;
 298     say "output for $test:";
 299     say $output;
 300 }
 301
 302 # 4: print summary
 303 $harness->summary($aggregator);