git.sur5r.net Git - i3/i3/blob - testcases/lib/i3test.pm

   1 package i3test;
   2 # vim:ts=4:sw=4:expandtab
   3 use strict; use warnings;
   4
   5 use File::Temp qw(tmpnam tempfile tempdir);
   6 use Test::Builder;
   7 use X11::XCB::Rect;
   8 use X11::XCB::Window;
   9 use X11::XCB qw(:all);
  10 use AnyEvent::I3;
  11 use EV;
  12 use List::Util qw(first);
  13 use Time::HiRes qw(sleep);
  14 use Cwd qw(abs_path);
  15 use Scalar::Util qw(blessed);
  16 use SocketActivation;
  17
  18 use v5.10;
  19
  20 use Exporter ();
  21 our @EXPORT = qw(
  22     get_workspace_names
  23     get_unused_workspace
  24     fresh_workspace
  25     get_ws_content
  26     get_ws
  27     get_focused
  28     open_empty_con
  29     open_window
  30     open_floating_window
  31     get_dock_clients
  32     cmd
  33     sync_with_i3
  34     does_i3_live
  35     exit_gracefully
  36     workspace_exists
  37     focused_ws
  38     get_socket_path
  39     launch_with_config
  40     wait_for_event
  41     wait_for_map
  42     wait_for_unmap
  43     $x
  44 );
  45
  46 my $tester = Test::Builder->new();
  47 my $_cached_socket_path = undef;
  48 my $_sync_window = undef;
  49 my $tmp_socket_path = undef;
  50
  51 our $x;
  52
  53 BEGIN {
  54     my $window_count = 0;
  55     sub counter_window {
  56         return $window_count++;
  57     }
  58 }
  59
  60 sub import {
  61     my $class = shift;
  62     my $pkg = caller;
  63
  64     my $test_most_args = @_ ? "qw(@_)" : "";
  65     local $@;
  66     eval << "__";
  67 package $pkg;
  68 use Test::Most $test_most_args;
  69 use Data::Dumper;
  70 use AnyEvent::I3;
  71 use Time::HiRes qw(sleep);
  72 use Test::Deep qw(eq_deeply cmp_deeply);
  73 __
  74     $tester->bail_out("$@") if $@;
  75     feature->import(":5.10");
  76     strict->import;
  77     warnings->import;
  78
  79     $x ||= i3test::X11->new;
  80     @_ = ($class);
  81     goto \&Exporter::import;
  82 }
  83
  84 #
  85 # Waits for the next event and calls the given callback for every event to
  86 # determine if this is the event we are waiting for.
  87 #
  88 # Can be used to wait until a window is mapped, until a ClientMessage is
  89 # received, etc.
  90 #
  91 # wait_for_event $x, 0.25, sub { $_[0]->{response_type} == MAP_NOTIFY };
  92 #
  93 sub wait_for_event {
  94     my ($timeout, $cb) = @_;
  95
  96     my $cv = AE::cv;
  97
  98     my $prep = EV::prepare sub {
  99         $x->flush;
 100     };
 101
 102     my $check = EV::check sub {
 103         while (defined(my $event = $x->poll_for_event)) {
 104             if ($cb->($event)) {
 105                 $cv->send(1);
 106                 last;
 107             }
 108         }
 109     };
 110
 111     my $watcher = EV::io $x->get_file_descriptor, EV::READ, sub {
 112         # do nothing, we only need this watcher so that EV picks up the events
 113     };
 114
 115     # Trigger timeout after $timeout seconds (can be fractional)
 116     my $t = AE::timer $timeout, 0, sub { warn "timeout ($timeout secs)"; $cv->send(0) };
 117
 118     my $result = $cv->recv;
 119     undef $t;
 120     return $result;
 121 }
 122
 123 # thin wrapper around wait_for_event which waits for MAP_NOTIFY
 124 # make sure to include 'structure_notify' in the window’s event_mask attribute
 125 sub wait_for_map {
 126     my ($win) = @_;
 127     my $id = (blessed($win) && $win->isa('X11::XCB::Window')) ? $win->id : $win;
 128     wait_for_event 2, sub {
 129         $_[0]->{response_type} == MAP_NOTIFY and $_[0]->{window} == $id
 130     };
 131 }
 132
 133 # Wrapper around wait_for_event which waits for UNMAP_NOTIFY. Also calls
 134 # sync_with_i3 to make sure i3 also picked up and processed the UnmapNotify
 135 # event.
 136 sub wait_for_unmap {
 137     my ($win) = @_;
 138     # my $id = (blessed($win) && $win->isa('X11::XCB::Window')) ? $win->id : $win;
 139     wait_for_event 2, sub {
 140         $_[0]->{response_type} == UNMAP_NOTIFY # and $_[0]->{window} == $id
 141     };
 142     sync_with_i3();
 143 }
 144
 145 #
 146 # Opens a new window (see X11::XCB::Window), maps it, waits until it got mapped
 147 # and synchronizes with i3.
 148 #
 149 # set dont_map to a true value to avoid mapping
 150 #
 151 # default values:
 152 #     class => WINDOW_CLASS_INPUT_OUTPUT
 153 #     rect => [ 0, 0, 30, 30 ]
 154 #     background_color => '#c0c0c0'
 155 #     event_mask => [ 'structure_notify' ]
 156 #     name => 'Window <n>'
 157 #
 158 sub open_window {
 159     my ($args) = @_;
 160     my %args = ($args ? %$args : ());
 161
 162     my $dont_map = delete $args{dont_map};
 163
 164     $args{class} //= WINDOW_CLASS_INPUT_OUTPUT;
 165     $args{rect} //= [ 0, 0, 30, 30 ];
 166     $args{background_color} //= '#c0c0c0';
 167     $args{event_mask} //= [ 'structure_notify' ];
 168     $args{name} //= 'Window ' . counter_window();
 169
 170     my $window = $x->root->create_child(%args);
 171
 172     return $window if $dont_map;
 173
 174     $window->map;
 175     wait_for_map($window);
 176     return $window;
 177 }
 178
 179 # Thin wrapper around open_window which sets window_type to
 180 # _NET_WM_WINDOW_TYPE_UTILITY to make the window floating.
 181 sub open_floating_window {
 182     my ($args) = @_;
 183     my %args = ($args ? %$args : ());
 184
 185     $args{window_type} = $x->atom(name => '_NET_WM_WINDOW_TYPE_UTILITY');
 186
 187     return open_window(\%args);
 188 }
 189
 190 sub open_empty_con {
 191     my ($i3) = @_;
 192
 193     my $reply = $i3->command('open')->recv;
 194     return $reply->{id};
 195 }
 196
 197 sub get_workspace_names {
 198     my $i3 = i3(get_socket_path());
 199     my $tree = $i3->get_tree->recv;
 200     my @outputs = @{$tree->{nodes}};
 201     my @cons;
 202     for my $output (@outputs) {
 203         # get the first CT_CON of each output
 204         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 205         @cons = (@cons, @{$content->{nodes}});
 206     }
 207     [ map { $_->{name} } @cons ]
 208 }
 209
 210 sub get_unused_workspace {
 211     my @names = get_workspace_names();
 212     my $tmp;
 213     do { $tmp = tmpnam() } while ($tmp ~~ @names);
 214     $tmp
 215 }
 216
 217 sub fresh_workspace {
 218     my $unused = get_unused_workspace;
 219     cmd("workspace $unused");
 220     $unused
 221 }
 222
 223 sub get_ws {
 224     my ($name) = @_;
 225     my $i3 = i3(get_socket_path());
 226     my $tree = $i3->get_tree->recv;
 227
 228     my @outputs = @{$tree->{nodes}};
 229     my @workspaces;
 230     for my $output (@outputs) {
 231         # get the first CT_CON of each output
 232         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 233         @workspaces = (@workspaces, @{$content->{nodes}});
 234     }
 235
 236     # as there can only be one workspace with this name, we can safely
 237     # return the first entry
 238     return first { $_->{name} eq $name } @workspaces;
 239 }
 240
 241 #
 242 # returns the content (== tree, starting from the node of a workspace)
 243 # of a workspace. If called in array context, also includes the focus
 244 # stack of the workspace
 245 #
 246 sub get_ws_content {
 247     my ($name) = @_;
 248     my $con = get_ws($name);
 249     return wantarray ? ($con->{nodes}, $con->{focus}) : $con->{nodes};
 250 }
 251
 252 sub get_focused {
 253     my ($ws) = @_;
 254     my $con = get_ws($ws);
 255
 256     my @focused = @{$con->{focus}};
 257     my $lf;
 258     while (@focused > 0) {
 259         $lf = $focused[0];
 260         last unless defined($con->{focus});
 261         @focused = @{$con->{focus}};
 262         my @cons = grep { $_->{id} == $lf } (@{$con->{nodes}}, @{$con->{'floating_nodes'}});
 263         $con = $cons[0];
 264     }
 265
 266     return $lf;
 267 }
 268
 269 sub get_dock_clients {
 270     my $which = shift;
 271
 272     my $tree = i3(get_socket_path())->get_tree->recv;
 273     my @outputs = @{$tree->{nodes}};
 274     # Children of all dockareas
 275     my @docked;
 276     for my $output (@outputs) {
 277         if (!defined($which)) {
 278             @docked = (@docked, map { @{$_->{nodes}} }
 279                                 grep { $_->{type} == 5 }
 280                                 @{$output->{nodes}});
 281         } elsif ($which eq 'top') {
 282             my $first = first { $_->{type} == 5 } @{$output->{nodes}};
 283             @docked = (@docked, @{$first->{nodes}});
 284         } elsif ($which eq 'bottom') {
 285             my @matching = grep { $_->{type} == 5 } @{$output->{nodes}};
 286             my $last = $matching[-1];
 287             @docked = (@docked, @{$last->{nodes}});
 288         }
 289     }
 290     return @docked;
 291 }
 292
 293 sub cmd {
 294     i3(get_socket_path())->command(@_)->recv
 295 }
 296
 297 sub workspace_exists {
 298     my ($name) = @_;
 299     ($name ~~ @{get_workspace_names()})
 300 }
 301
 302 sub focused_ws {
 303     my $i3 = i3(get_socket_path());
 304     my $tree = $i3->get_tree->recv;
 305     my @outputs = @{$tree->{nodes}};
 306     my @cons;
 307     for my $output (@outputs) {
 308         # get the first CT_CON of each output
 309         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 310         my $first = first { $_->{fullscreen_mode} == 1 } @{$content->{nodes}};
 311         return $first->{name}
 312     }
 313 }
 314
 315 #
 316 # Sends an I3_SYNC ClientMessage with a random value to the root window.
 317 # i3 will reply with the same value, but, due to the order of events it
 318 # processes, only after all other events are done.
 319 #
 320 # This can be used to ensure the results of a cmd 'focus left' are pushed to
 321 # X11 and that $x->input_focus returns the correct value afterwards.
 322 #
 323 # See also docs/testsuite for a long explanation
 324 #
 325 sub sync_with_i3 {
 326     # Since we need a (mapped) window for receiving a ClientMessage, we create
 327     # one on the first call of sync_with_i3. It will be re-used in all
 328     # subsequent calls.
 329     if (!defined($_sync_window)) {
 330         $_sync_window = $x->root->create_child(
 331             class => WINDOW_CLASS_INPUT_OUTPUT,
 332             rect => X11::XCB::Rect->new(x => -15, y => -15, width => 10, height => 10 ),
 333             override_redirect => 1,
 334             background_color => '#ff0000',
 335             event_mask => [ 'structure_notify' ],
 336         );
 337
 338         $_sync_window->map;
 339
 340         wait_for_event 2, sub { $_[0]->{response_type} == MAP_NOTIFY };
 341     }
 342
 343     my $root = $x->get_root_window();
 344     # Generate a random number to identify this particular ClientMessage.
 345     my $myrnd = int(rand(255)) + 1;
 346
 347     # Generate a ClientMessage, see xcb_client_message_t
 348     my $msg = pack "CCSLLLLLLL",
 349          CLIENT_MESSAGE, # response_type
 350          32,     # format
 351          0,      # sequence
 352          $root,  # destination window
 353          $x->atom(name => 'I3_SYNC')->id,
 354
 355          $_sync_window->id,    # data[0]: our own window id
 356          $myrnd, # data[1]: a random value to identify the request
 357          0,
 358          0,
 359          0;
 360
 361     # Send it to the root window -- since i3 uses the SubstructureRedirect
 362     # event mask, it will get the ClientMessage.
 363     $x->send_event(0, $root, EVENT_MASK_SUBSTRUCTURE_REDIRECT, $msg);
 364
 365     # now wait until the reply is here
 366     return wait_for_event 2, sub {
 367         my ($event) = @_;
 368         # TODO: const
 369         return 0 unless $event->{response_type} == 161;
 370
 371         my ($win, $rnd) = unpack "LL", $event->{data};
 372         return ($rnd == $myrnd);
 373     };
 374 }
 375
 376 sub does_i3_live {
 377     my $tree = i3(get_socket_path())->get_tree->recv;
 378     my @nodes = @{$tree->{nodes}};
 379     my $ok = (@nodes > 0);
 380     $tester->ok($ok, 'i3 still lives');
 381     return $ok;
 382 }
 383
 384 # Tries to exit i3 gracefully (with the 'exit' cmd) or kills the PID if that fails
 385 sub exit_gracefully {
 386     my ($pid, $socketpath) = @_;
 387     $socketpath ||= get_socket_path();
 388
 389     my $exited = 0;
 390     eval {
 391         say "Exiting i3 cleanly...";
 392         i3($socketpath)->command('exit')->recv;
 393         $exited = 1;
 394     };
 395
 396     if (!$exited) {
 397         kill(9, $pid) or die "could not kill i3";
 398     }
 399
 400     if ($socketpath =~ m,^/tmp/i3-test-socket-,) {
 401         unlink($socketpath);
 402     }
 403 }
 404
 405 # Gets the socket path from the I3_SOCKET_PATH atom stored on the X11 root window
 406 sub get_socket_path {
 407     my ($cache) = @_;
 408     $cache ||= 1;
 409
 410     if ($cache && defined($_cached_socket_path)) {
 411         return $_cached_socket_path;
 412     }
 413
 414     my $atom = $x->atom(name => 'I3_SOCKET_PATH');
 415     my $cookie = $x->get_property(0, $x->get_root_window(), $atom->id, GET_PROPERTY_TYPE_ANY, 0, 256);
 416     my $reply = $x->get_property_reply($cookie->{sequence});
 417     my $socketpath = $reply->{value};
 418     $_cached_socket_path = $socketpath;
 419     return $socketpath;
 420 }
 421
 422 #
 423 # launches a new i3 process with the given string as configuration file.
 424 # useful for tests which test specific config file directives.
 425 #
 426 # be sure to use !NO_I3_INSTANCE! somewhere in the file to signal
 427 # complete-run.pl that it should not create an instance of i3
 428 #
 429 sub launch_with_config {
 430     my ($config, $dont_add_socket_path) = @_;
 431
 432     $dont_add_socket_path //= 0;
 433
 434     if (!defined($tmp_socket_path)) {
 435         $tmp_socket_path = File::Temp::tempnam('/tmp', 'i3-test-socket-');
 436     }
 437
 438     my ($fh, $tmpfile) = tempfile('/tmp/i3-test-config-XXXXX', UNLINK => 1);
 439     say $fh $config;
 440     say $fh "ipc-socket $tmp_socket_path" unless $dont_add_socket_path;
 441     close($fh);
 442
 443     my $cv = AnyEvent->condvar;
 444     my $pid = activate_i3(
 445         unix_socket_path => "$tmp_socket_path-activation",
 446         display => $ENV{DISPLAY},
 447         configfile => $tmpfile,
 448         outdir => $ENV{OUTDIR},
 449         testname => $ENV{TESTNAME},
 450         valgrind => $ENV{VALGRIND},
 451         strace => $ENV{STRACE},
 452         cv => $cv,
 453     );
 454
 455     # blockingly wait until i3 is ready
 456     $cv->recv;
 457
 458     # force update of the cached socket path in lib/i3test
 459     get_socket_path(0);
 460
 461     return $pid;
 462 }
 463
 464 package i3test::X11;
 465 use parent 'X11::XCB::Connection';
 466
 467 sub input_focus {
 468     my $self = shift;
 469     i3test::sync_with_i3();
 470
 471     return $self->SUPER::input_focus(@_);
 472 }
 473
 474 1