git.sur5r.net Git - i3/i3/blob - testcases/lib/i3test.pm

   1 package i3test;
   2 # vim:ts=4:sw=4:expandtab
   3 use strict; use warnings;
   4
   5 use File::Temp qw(tmpnam tempfile tempdir);
   6 use Test::Builder;
   7 use X11::XCB::Rect;
   8 use X11::XCB::Window;
   9 use X11::XCB qw(:all);
  10 use AnyEvent::I3;
  11 use List::Util qw(first);
  12 use Time::HiRes qw(sleep);
  13 use Cwd qw(abs_path);
  14 use Scalar::Util qw(blessed);
  15 use SocketActivation;
  16
  17 use v5.10;
  18
  19 use Exporter ();
  20 our @EXPORT = qw(
  21     get_workspace_names
  22     get_unused_workspace
  23     fresh_workspace
  24     get_ws_content
  25     get_ws
  26     get_focused
  27     open_empty_con
  28     open_window
  29     open_floating_window
  30     get_dock_clients
  31     cmd
  32     sync_with_i3
  33     does_i3_live
  34     exit_gracefully
  35     workspace_exists
  36     focused_ws
  37     get_socket_path
  38     launch_with_config
  39     wait_for_event
  40     wait_for_map
  41     wait_for_unmap
  42     $x
  43 );
  44
  45 my $tester = Test::Builder->new();
  46 my $_cached_socket_path = undef;
  47 my $_sync_window = undef;
  48 my $tmp_socket_path = undef;
  49
  50 our $x;
  51
  52 BEGIN {
  53     my $window_count = 0;
  54     sub counter_window {
  55         return $window_count++;
  56     }
  57 }
  58
  59 sub import {
  60     my $class = shift;
  61     my $pkg = caller;
  62
  63     my $test_more_args = @_ ? "qw(@_)" : "";
  64     local $@;
  65     eval << "__";
  66 package $pkg;
  67 use Test::More $test_more_args;
  68 use Data::Dumper;
  69 use AnyEvent::I3;
  70 use Time::HiRes qw(sleep);
  71 __
  72     $tester->bail_out("$@") if $@;
  73     feature->import(":5.10");
  74     strict->import;
  75     warnings->import;
  76
  77     $x ||= i3test::X11->new;
  78     @_ = ($class);
  79     goto \&Exporter::import;
  80 }
  81
  82 #
  83 # Waits for the next event and calls the given callback for every event to
  84 # determine if this is the event we are waiting for.
  85 #
  86 # Can be used to wait until a window is mapped, until a ClientMessage is
  87 # received, etc.
  88 #
  89 # wait_for_event $x, 0.25, sub { $_[0]->{response_type} == MAP_NOTIFY };
  90 #
  91 sub wait_for_event {
  92     my ($timeout, $cb) = @_;
  93
  94     my $cv = AE::cv;
  95
  96     $x->flush;
  97
  98     # unfortunately, there is no constant for this
  99     my $ae_read = 0;
 100
 101     my $guard = AE::io $x->get_file_descriptor, $ae_read, sub {
 102         while (defined(my $event = $x->poll_for_event)) {
 103             if ($cb->($event)) {
 104                 $cv->send(1);
 105                 last;
 106             }
 107         }
 108     };
 109
 110     # Trigger timeout after $timeout seconds (can be fractional)
 111     my $t = AE::timer $timeout, 0, sub { warn "timeout ($timeout secs)"; $cv->send(0) };
 112
 113     my $result = $cv->recv;
 114     undef $t;
 115     undef $guard;
 116     return $result;
 117 }
 118
 119 # thin wrapper around wait_for_event which waits for MAP_NOTIFY
 120 # make sure to include 'structure_notify' in the window’s event_mask attribute
 121 sub wait_for_map {
 122     my ($win) = @_;
 123     my $id = (blessed($win) && $win->isa('X11::XCB::Window')) ? $win->id : $win;
 124     wait_for_event 2, sub {
 125         $_[0]->{response_type} == MAP_NOTIFY and $_[0]->{window} == $id
 126     };
 127 }
 128
 129 # Wrapper around wait_for_event which waits for UNMAP_NOTIFY. Also calls
 130 # sync_with_i3 to make sure i3 also picked up and processed the UnmapNotify
 131 # event.
 132 sub wait_for_unmap {
 133     my ($win) = @_;
 134     # my $id = (blessed($win) && $win->isa('X11::XCB::Window')) ? $win->id : $win;
 135     wait_for_event 2, sub {
 136         $_[0]->{response_type} == UNMAP_NOTIFY # and $_[0]->{window} == $id
 137     };
 138     sync_with_i3();
 139 }
 140
 141 #
 142 # Opens a new window (see X11::XCB::Window), maps it, waits until it got mapped
 143 # and synchronizes with i3.
 144 #
 145 # set dont_map to a true value to avoid mapping
 146 #
 147 # default values:
 148 #     class => WINDOW_CLASS_INPUT_OUTPUT
 149 #     rect => [ 0, 0, 30, 30 ]
 150 #     background_color => '#c0c0c0'
 151 #     event_mask => [ 'structure_notify' ]
 152 #     name => 'Window <n>'
 153 #
 154 sub open_window {
 155     my %args = @_ == 1 ? %{$_[0]} : @_;
 156
 157     my $dont_map = delete $args{dont_map};
 158
 159     $args{class} //= WINDOW_CLASS_INPUT_OUTPUT;
 160     $args{rect} //= [ 0, 0, 30, 30 ];
 161     $args{background_color} //= '#c0c0c0';
 162     $args{event_mask} //= [ 'structure_notify' ];
 163     $args{name} //= 'Window ' . counter_window();
 164
 165     my $window = $x->root->create_child(%args);
 166
 167     return $window if $dont_map;
 168
 169     $window->map;
 170     wait_for_map($window);
 171     return $window;
 172 }
 173
 174 # Thin wrapper around open_window which sets window_type to
 175 # _NET_WM_WINDOW_TYPE_UTILITY to make the window floating.
 176 sub open_floating_window {
 177     my %args = @_ == 1 ? %{$_[0]} : @_;
 178
 179     $args{window_type} = $x->atom(name => '_NET_WM_WINDOW_TYPE_UTILITY');
 180
 181     return open_window(\%args);
 182 }
 183
 184 sub open_empty_con {
 185     my ($i3) = @_;
 186
 187     my $reply = $i3->command('open')->recv;
 188     return $reply->{id};
 189 }
 190
 191 sub get_workspace_names {
 192     my $i3 = i3(get_socket_path());
 193     my $tree = $i3->get_tree->recv;
 194     my @outputs = @{$tree->{nodes}};
 195     my @cons;
 196     for my $output (@outputs) {
 197         # get the first CT_CON of each output
 198         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 199         @cons = (@cons, @{$content->{nodes}});
 200     }
 201     [ map { $_->{name} } @cons ]
 202 }
 203
 204 sub get_unused_workspace {
 205     my @names = get_workspace_names();
 206     my $tmp;
 207     do { $tmp = tmpnam() } while ($tmp ~~ @names);
 208     $tmp
 209 }
 210
 211 sub fresh_workspace {
 212     my $unused = get_unused_workspace;
 213     cmd("workspace $unused");
 214     $unused
 215 }
 216
 217 sub get_ws {
 218     my ($name) = @_;
 219     my $i3 = i3(get_socket_path());
 220     my $tree = $i3->get_tree->recv;
 221
 222     my @outputs = @{$tree->{nodes}};
 223     my @workspaces;
 224     for my $output (@outputs) {
 225         # get the first CT_CON of each output
 226         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 227         @workspaces = (@workspaces, @{$content->{nodes}});
 228     }
 229
 230     # as there can only be one workspace with this name, we can safely
 231     # return the first entry
 232     return first { $_->{name} eq $name } @workspaces;
 233 }
 234
 235 #
 236 # returns the content (== tree, starting from the node of a workspace)
 237 # of a workspace. If called in array context, also includes the focus
 238 # stack of the workspace
 239 #
 240 sub get_ws_content {
 241     my ($name) = @_;
 242     my $con = get_ws($name);
 243     return wantarray ? ($con->{nodes}, $con->{focus}) : $con->{nodes};
 244 }
 245
 246 sub get_focused {
 247     my ($ws) = @_;
 248     my $con = get_ws($ws);
 249
 250     my @focused = @{$con->{focus}};
 251     my $lf;
 252     while (@focused > 0) {
 253         $lf = $focused[0];
 254         last unless defined($con->{focus});
 255         @focused = @{$con->{focus}};
 256         my @cons = grep { $_->{id} == $lf } (@{$con->{nodes}}, @{$con->{'floating_nodes'}});
 257         $con = $cons[0];
 258     }
 259
 260     return $lf;
 261 }
 262
 263 sub get_dock_clients {
 264     my $which = shift;
 265
 266     my $tree = i3(get_socket_path())->get_tree->recv;
 267     my @outputs = @{$tree->{nodes}};
 268     # Children of all dockareas
 269     my @docked;
 270     for my $output (@outputs) {
 271         if (!defined($which)) {
 272             @docked = (@docked, map { @{$_->{nodes}} }
 273                                 grep { $_->{type} == 5 }
 274                                 @{$output->{nodes}});
 275         } elsif ($which eq 'top') {
 276             my $first = first { $_->{type} == 5 } @{$output->{nodes}};
 277             @docked = (@docked, @{$first->{nodes}});
 278         } elsif ($which eq 'bottom') {
 279             my @matching = grep { $_->{type} == 5 } @{$output->{nodes}};
 280             my $last = $matching[-1];
 281             @docked = (@docked, @{$last->{nodes}});
 282         }
 283     }
 284     return @docked;
 285 }
 286
 287 sub cmd {
 288     i3(get_socket_path())->command(@_)->recv
 289 }
 290
 291 sub workspace_exists {
 292     my ($name) = @_;
 293     ($name ~~ @{get_workspace_names()})
 294 }
 295
 296 sub focused_ws {
 297     my $i3 = i3(get_socket_path());
 298     my $tree = $i3->get_tree->recv;
 299     my @outputs = @{$tree->{nodes}};
 300     my @cons;
 301     for my $output (@outputs) {
 302         # get the first CT_CON of each output
 303         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 304         my $first = first { $_->{fullscreen_mode} == 1 } @{$content->{nodes}};
 305         return $first->{name}
 306     }
 307 }
 308
 309 #
 310 # Sends an I3_SYNC ClientMessage with a random value to the root window.
 311 # i3 will reply with the same value, but, due to the order of events it
 312 # processes, only after all other events are done.
 313 #
 314 # This can be used to ensure the results of a cmd 'focus left' are pushed to
 315 # X11 and that $x->input_focus returns the correct value afterwards.
 316 #
 317 # See also docs/testsuite for a long explanation
 318 #
 319 sub sync_with_i3 {
 320     # Since we need a (mapped) window for receiving a ClientMessage, we create
 321     # one on the first call of sync_with_i3. It will be re-used in all
 322     # subsequent calls.
 323     if (!defined($_sync_window)) {
 324         $_sync_window = $x->root->create_child(
 325             class => WINDOW_CLASS_INPUT_OUTPUT,
 326             rect => X11::XCB::Rect->new(x => -15, y => -15, width => 10, height => 10 ),
 327             override_redirect => 1,
 328             background_color => '#ff0000',
 329             event_mask => [ 'structure_notify' ],
 330         );
 331
 332         $_sync_window->map;
 333
 334         wait_for_event 2, sub { $_[0]->{response_type} == MAP_NOTIFY };
 335     }
 336
 337     my $root = $x->get_root_window();
 338     # Generate a random number to identify this particular ClientMessage.
 339     my $myrnd = int(rand(255)) + 1;
 340
 341     # Generate a ClientMessage, see xcb_client_message_t
 342     my $msg = pack "CCSLLLLLLL",
 343          CLIENT_MESSAGE, # response_type
 344          32,     # format
 345          0,      # sequence
 346          $root,  # destination window
 347          $x->atom(name => 'I3_SYNC')->id,
 348
 349          $_sync_window->id,    # data[0]: our own window id
 350          $myrnd, # data[1]: a random value to identify the request
 351          0,
 352          0,
 353          0;
 354
 355     # Send it to the root window -- since i3 uses the SubstructureRedirect
 356     # event mask, it will get the ClientMessage.
 357     $x->send_event(0, $root, EVENT_MASK_SUBSTRUCTURE_REDIRECT, $msg);
 358
 359     # now wait until the reply is here
 360     return wait_for_event 2, sub {
 361         my ($event) = @_;
 362         # TODO: const
 363         return 0 unless $event->{response_type} == 161;
 364
 365         my ($win, $rnd) = unpack "LL", $event->{data};
 366         return ($rnd == $myrnd);
 367     };
 368 }
 369
 370 sub does_i3_live {
 371     my $tree = i3(get_socket_path())->get_tree->recv;
 372     my @nodes = @{$tree->{nodes}};
 373     my $ok = (@nodes > 0);
 374     $tester->ok($ok, 'i3 still lives');
 375     return $ok;
 376 }
 377
 378 # Tries to exit i3 gracefully (with the 'exit' cmd) or kills the PID if that fails
 379 sub exit_gracefully {
 380     my ($pid, $socketpath) = @_;
 381     $socketpath ||= get_socket_path();
 382
 383     my $exited = 0;
 384     eval {
 385         say "Exiting i3 cleanly...";
 386         i3($socketpath)->command('exit')->recv;
 387         $exited = 1;
 388     };
 389
 390     if (!$exited) {
 391         kill(9, $pid) or die "could not kill i3";
 392     }
 393
 394     if ($socketpath =~ m,^/tmp/i3-test-socket-,) {
 395         unlink($socketpath);
 396     }
 397 }
 398
 399 # Gets the socket path from the I3_SOCKET_PATH atom stored on the X11 root window
 400 sub get_socket_path {
 401     my ($cache) = @_;
 402     $cache ||= 1;
 403
 404     if ($cache && defined($_cached_socket_path)) {
 405         return $_cached_socket_path;
 406     }
 407
 408     my $atom = $x->atom(name => 'I3_SOCKET_PATH');
 409     my $cookie = $x->get_property(0, $x->get_root_window(), $atom->id, GET_PROPERTY_TYPE_ANY, 0, 256);
 410     my $reply = $x->get_property_reply($cookie->{sequence});
 411     my $socketpath = $reply->{value};
 412     $_cached_socket_path = $socketpath;
 413     return $socketpath;
 414 }
 415
 416 #
 417 # launches a new i3 process with the given string as configuration file.
 418 # useful for tests which test specific config file directives.
 419 #
 420 # be sure to use !NO_I3_INSTANCE! somewhere in the file to signal
 421 # complete-run.pl that it should not create an instance of i3
 422 #
 423 sub launch_with_config {
 424     my ($config, $dont_add_socket_path) = @_;
 425
 426     $dont_add_socket_path //= 0;
 427
 428     if (!defined($tmp_socket_path)) {
 429         $tmp_socket_path = File::Temp::tempnam('/tmp', 'i3-test-socket-');
 430     }
 431
 432     my ($fh, $tmpfile) = tempfile('/tmp/i3-test-config-XXXXX', UNLINK => 1);
 433     say $fh $config;
 434     say $fh "ipc-socket $tmp_socket_path" unless $dont_add_socket_path;
 435     close($fh);
 436
 437     my $cv = AnyEvent->condvar;
 438     my $pid = activate_i3(
 439         unix_socket_path => "$tmp_socket_path-activation",
 440         display => $ENV{DISPLAY},
 441         configfile => $tmpfile,
 442         outdir => $ENV{OUTDIR},
 443         testname => $ENV{TESTNAME},
 444         valgrind => $ENV{VALGRIND},
 445         strace => $ENV{STRACE},
 446         cv => $cv,
 447     );
 448
 449     # blockingly wait until i3 is ready
 450     $cv->recv;
 451
 452     # force update of the cached socket path in lib/i3test
 453     get_socket_path(0);
 454
 455     return $pid;
 456 }
 457
 458 package i3test::X11;
 459 use parent 'X11::XCB::Connection';
 460
 461 sub input_focus {
 462     my $self = shift;
 463     i3test::sync_with_i3();
 464
 465     return $self->SUPER::input_focus(@_);
 466 }
 467
 468 1