git.sur5r.net Git - i3/i3/blob - testcases/lib/i3test.pm

   1 package i3test;
   2 # vim:ts=4:sw=4:expandtab
   3 use strict; use warnings;
   4
   5 use File::Temp qw(tmpnam tempfile tempdir);
   6 use Test::Builder;
   7 use X11::XCB::Rect;
   8 use X11::XCB::Window;
   9 use X11::XCB qw(:all);
  10 use AnyEvent::I3;
  11 use List::Util qw(first);
  12 use Time::HiRes qw(sleep);
  13 use Cwd qw(abs_path);
  14 use Scalar::Util qw(blessed);
  15 use SocketActivation;
  16
  17 use v5.10;
  18
  19 use Exporter ();
  20 our @EXPORT = qw(
  21     get_workspace_names
  22     get_unused_workspace
  23     fresh_workspace
  24     get_ws_content
  25     get_ws
  26     get_focused
  27     open_empty_con
  28     open_window
  29     open_floating_window
  30     get_dock_clients
  31     cmd
  32     sync_with_i3
  33     does_i3_live
  34     exit_gracefully
  35     workspace_exists
  36     focused_ws
  37     get_socket_path
  38     launch_with_config
  39     wait_for_event
  40     wait_for_map
  41     wait_for_unmap
  42     $x
  43 );
  44
  45 my $tester = Test::Builder->new();
  46 my $_cached_socket_path = undef;
  47 my $_sync_window = undef;
  48 my $tmp_socket_path = undef;
  49
  50 our $x;
  51
  52 BEGIN {
  53     my $window_count = 0;
  54     sub counter_window {
  55         return $window_count++;
  56     }
  57 }
  58
  59 sub import {
  60     my $class = shift;
  61     my $pkg = caller;
  62
  63     my $test_more_args = @_ ? "qw(@_)" : "";
  64     local $@;
  65     eval << "__";
  66 package $pkg;
  67 use Test::More $test_more_args;
  68 use Data::Dumper;
  69 use AnyEvent::I3;
  70 use Time::HiRes qw(sleep);
  71 __
  72     $tester->bail_out("$@") if $@;
  73     feature->import(":5.10");
  74     strict->import;
  75     warnings->import;
  76
  77     $x ||= i3test::X11->new;
  78     @_ = ($class);
  79     goto \&Exporter::import;
  80 }
  81
  82 #
  83 # Waits for the next event and calls the given callback for every event to
  84 # determine if this is the event we are waiting for.
  85 #
  86 # Can be used to wait until a window is mapped, until a ClientMessage is
  87 # received, etc.
  88 #
  89 # wait_for_event $x, 0.25, sub { $_[0]->{response_type} == MAP_NOTIFY };
  90 #
  91 sub wait_for_event {
  92     my ($timeout, $cb) = @_;
  93
  94     my $cv = AE::cv;
  95
  96     $x->flush;
  97
  98     # unfortunately, there is no constant for this
  99     my $ae_read = 0;
 100
 101     my $guard = AE::io $x->get_file_descriptor, $ae_read, sub {
 102         while (defined(my $event = $x->poll_for_event)) {
 103             if ($cb->($event)) {
 104                 $cv->send(1);
 105                 last;
 106             }
 107         }
 108     };
 109
 110     # Trigger timeout after $timeout seconds (can be fractional)
 111     my $t = AE::timer $timeout, 0, sub { warn "timeout ($timeout secs)"; $cv->send(0) };
 112
 113     my $result = $cv->recv;
 114     undef $t;
 115     undef $guard;
 116     return $result;
 117 }
 118
 119 # thin wrapper around wait_for_event which waits for MAP_NOTIFY
 120 # make sure to include 'structure_notify' in the window’s event_mask attribute
 121 sub wait_for_map {
 122     my ($win) = @_;
 123     my $id = (blessed($win) && $win->isa('X11::XCB::Window')) ? $win->id : $win;
 124     wait_for_event 2, sub {
 125         $_[0]->{response_type} == MAP_NOTIFY and $_[0]->{window} == $id
 126     };
 127 }
 128
 129 # Wrapper around wait_for_event which waits for UNMAP_NOTIFY. Also calls
 130 # sync_with_i3 to make sure i3 also picked up and processed the UnmapNotify
 131 # event.
 132 sub wait_for_unmap {
 133     my ($win) = @_;
 134     # my $id = (blessed($win) && $win->isa('X11::XCB::Window')) ? $win->id : $win;
 135     wait_for_event 2, sub {
 136         $_[0]->{response_type} == UNMAP_NOTIFY # and $_[0]->{window} == $id
 137     };
 138     sync_with_i3();
 139 }
 140
 141 #
 142 # Opens a new window (see X11::XCB::Window), maps it, waits until it got mapped
 143 # and synchronizes with i3.
 144 #
 145 # set dont_map to a true value to avoid mapping
 146 #
 147 # default values:
 148 #     class => WINDOW_CLASS_INPUT_OUTPUT
 149 #     rect => [ 0, 0, 30, 30 ]
 150 #     background_color => '#c0c0c0'
 151 #     event_mask => [ 'structure_notify' ]
 152 #     name => 'Window <n>'
 153 #
 154 sub open_window {
 155     my ($args) = @_;
 156     my %args = ($args ? %$args : ());
 157
 158     my $dont_map = delete $args{dont_map};
 159
 160     $args{class} //= WINDOW_CLASS_INPUT_OUTPUT;
 161     $args{rect} //= [ 0, 0, 30, 30 ];
 162     $args{background_color} //= '#c0c0c0';
 163     $args{event_mask} //= [ 'structure_notify' ];
 164     $args{name} //= 'Window ' . counter_window();
 165
 166     my $window = $x->root->create_child(%args);
 167
 168     return $window if $dont_map;
 169
 170     $window->map;
 171     wait_for_map($window);
 172     return $window;
 173 }
 174
 175 # Thin wrapper around open_window which sets window_type to
 176 # _NET_WM_WINDOW_TYPE_UTILITY to make the window floating.
 177 sub open_floating_window {
 178     my ($args) = @_;
 179     my %args = ($args ? %$args : ());
 180
 181     $args{window_type} = $x->atom(name => '_NET_WM_WINDOW_TYPE_UTILITY');
 182
 183     return open_window(\%args);
 184 }
 185
 186 sub open_empty_con {
 187     my ($i3) = @_;
 188
 189     my $reply = $i3->command('open')->recv;
 190     return $reply->{id};
 191 }
 192
 193 sub get_workspace_names {
 194     my $i3 = i3(get_socket_path());
 195     my $tree = $i3->get_tree->recv;
 196     my @outputs = @{$tree->{nodes}};
 197     my @cons;
 198     for my $output (@outputs) {
 199         # get the first CT_CON of each output
 200         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 201         @cons = (@cons, @{$content->{nodes}});
 202     }
 203     [ map { $_->{name} } @cons ]
 204 }
 205
 206 sub get_unused_workspace {
 207     my @names = get_workspace_names();
 208     my $tmp;
 209     do { $tmp = tmpnam() } while ($tmp ~~ @names);
 210     $tmp
 211 }
 212
 213 sub fresh_workspace {
 214     my $unused = get_unused_workspace;
 215     cmd("workspace $unused");
 216     $unused
 217 }
 218
 219 sub get_ws {
 220     my ($name) = @_;
 221     my $i3 = i3(get_socket_path());
 222     my $tree = $i3->get_tree->recv;
 223
 224     my @outputs = @{$tree->{nodes}};
 225     my @workspaces;
 226     for my $output (@outputs) {
 227         # get the first CT_CON of each output
 228         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 229         @workspaces = (@workspaces, @{$content->{nodes}});
 230     }
 231
 232     # as there can only be one workspace with this name, we can safely
 233     # return the first entry
 234     return first { $_->{name} eq $name } @workspaces;
 235 }
 236
 237 #
 238 # returns the content (== tree, starting from the node of a workspace)
 239 # of a workspace. If called in array context, also includes the focus
 240 # stack of the workspace
 241 #
 242 sub get_ws_content {
 243     my ($name) = @_;
 244     my $con = get_ws($name);
 245     return wantarray ? ($con->{nodes}, $con->{focus}) : $con->{nodes};
 246 }
 247
 248 sub get_focused {
 249     my ($ws) = @_;
 250     my $con = get_ws($ws);
 251
 252     my @focused = @{$con->{focus}};
 253     my $lf;
 254     while (@focused > 0) {
 255         $lf = $focused[0];
 256         last unless defined($con->{focus});
 257         @focused = @{$con->{focus}};
 258         my @cons = grep { $_->{id} == $lf } (@{$con->{nodes}}, @{$con->{'floating_nodes'}});
 259         $con = $cons[0];
 260     }
 261
 262     return $lf;
 263 }
 264
 265 sub get_dock_clients {
 266     my $which = shift;
 267
 268     my $tree = i3(get_socket_path())->get_tree->recv;
 269     my @outputs = @{$tree->{nodes}};
 270     # Children of all dockareas
 271     my @docked;
 272     for my $output (@outputs) {
 273         if (!defined($which)) {
 274             @docked = (@docked, map { @{$_->{nodes}} }
 275                                 grep { $_->{type} == 5 }
 276                                 @{$output->{nodes}});
 277         } elsif ($which eq 'top') {
 278             my $first = first { $_->{type} == 5 } @{$output->{nodes}};
 279             @docked = (@docked, @{$first->{nodes}});
 280         } elsif ($which eq 'bottom') {
 281             my @matching = grep { $_->{type} == 5 } @{$output->{nodes}};
 282             my $last = $matching[-1];
 283             @docked = (@docked, @{$last->{nodes}});
 284         }
 285     }
 286     return @docked;
 287 }
 288
 289 sub cmd {
 290     i3(get_socket_path())->command(@_)->recv
 291 }
 292
 293 sub workspace_exists {
 294     my ($name) = @_;
 295     ($name ~~ @{get_workspace_names()})
 296 }
 297
 298 sub focused_ws {
 299     my $i3 = i3(get_socket_path());
 300     my $tree = $i3->get_tree->recv;
 301     my @outputs = @{$tree->{nodes}};
 302     my @cons;
 303     for my $output (@outputs) {
 304         # get the first CT_CON of each output
 305         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 306         my $first = first { $_->{fullscreen_mode} == 1 } @{$content->{nodes}};
 307         return $first->{name}
 308     }
 309 }
 310
 311 #
 312 # Sends an I3_SYNC ClientMessage with a random value to the root window.
 313 # i3 will reply with the same value, but, due to the order of events it
 314 # processes, only after all other events are done.
 315 #
 316 # This can be used to ensure the results of a cmd 'focus left' are pushed to
 317 # X11 and that $x->input_focus returns the correct value afterwards.
 318 #
 319 # See also docs/testsuite for a long explanation
 320 #
 321 sub sync_with_i3 {
 322     # Since we need a (mapped) window for receiving a ClientMessage, we create
 323     # one on the first call of sync_with_i3. It will be re-used in all
 324     # subsequent calls.
 325     if (!defined($_sync_window)) {
 326         $_sync_window = $x->root->create_child(
 327             class => WINDOW_CLASS_INPUT_OUTPUT,
 328             rect => X11::XCB::Rect->new(x => -15, y => -15, width => 10, height => 10 ),
 329             override_redirect => 1,
 330             background_color => '#ff0000',
 331             event_mask => [ 'structure_notify' ],
 332         );
 333
 334         $_sync_window->map;
 335
 336         wait_for_event 2, sub { $_[0]->{response_type} == MAP_NOTIFY };
 337     }
 338
 339     my $root = $x->get_root_window();
 340     # Generate a random number to identify this particular ClientMessage.
 341     my $myrnd = int(rand(255)) + 1;
 342
 343     # Generate a ClientMessage, see xcb_client_message_t
 344     my $msg = pack "CCSLLLLLLL",
 345          CLIENT_MESSAGE, # response_type
 346          32,     # format
 347          0,      # sequence
 348          $root,  # destination window
 349          $x->atom(name => 'I3_SYNC')->id,
 350
 351          $_sync_window->id,    # data[0]: our own window id
 352          $myrnd, # data[1]: a random value to identify the request
 353          0,
 354          0,
 355          0;
 356
 357     # Send it to the root window -- since i3 uses the SubstructureRedirect
 358     # event mask, it will get the ClientMessage.
 359     $x->send_event(0, $root, EVENT_MASK_SUBSTRUCTURE_REDIRECT, $msg);
 360
 361     # now wait until the reply is here
 362     return wait_for_event 2, sub {
 363         my ($event) = @_;
 364         # TODO: const
 365         return 0 unless $event->{response_type} == 161;
 366
 367         my ($win, $rnd) = unpack "LL", $event->{data};
 368         return ($rnd == $myrnd);
 369     };
 370 }
 371
 372 sub does_i3_live {
 373     my $tree = i3(get_socket_path())->get_tree->recv;
 374     my @nodes = @{$tree->{nodes}};
 375     my $ok = (@nodes > 0);
 376     $tester->ok($ok, 'i3 still lives');
 377     return $ok;
 378 }
 379
 380 # Tries to exit i3 gracefully (with the 'exit' cmd) or kills the PID if that fails
 381 sub exit_gracefully {
 382     my ($pid, $socketpath) = @_;
 383     $socketpath ||= get_socket_path();
 384
 385     my $exited = 0;
 386     eval {
 387         say "Exiting i3 cleanly...";
 388         i3($socketpath)->command('exit')->recv;
 389         $exited = 1;
 390     };
 391
 392     if (!$exited) {
 393         kill(9, $pid) or die "could not kill i3";
 394     }
 395
 396     if ($socketpath =~ m,^/tmp/i3-test-socket-,) {
 397         unlink($socketpath);
 398     }
 399 }
 400
 401 # Gets the socket path from the I3_SOCKET_PATH atom stored on the X11 root window
 402 sub get_socket_path {
 403     my ($cache) = @_;
 404     $cache ||= 1;
 405
 406     if ($cache && defined($_cached_socket_path)) {
 407         return $_cached_socket_path;
 408     }
 409
 410     my $atom = $x->atom(name => 'I3_SOCKET_PATH');
 411     my $cookie = $x->get_property(0, $x->get_root_window(), $atom->id, GET_PROPERTY_TYPE_ANY, 0, 256);
 412     my $reply = $x->get_property_reply($cookie->{sequence});
 413     my $socketpath = $reply->{value};
 414     $_cached_socket_path = $socketpath;
 415     return $socketpath;
 416 }
 417
 418 #
 419 # launches a new i3 process with the given string as configuration file.
 420 # useful for tests which test specific config file directives.
 421 #
 422 # be sure to use !NO_I3_INSTANCE! somewhere in the file to signal
 423 # complete-run.pl that it should not create an instance of i3
 424 #
 425 sub launch_with_config {
 426     my ($config, $dont_add_socket_path) = @_;
 427
 428     $dont_add_socket_path //= 0;
 429
 430     if (!defined($tmp_socket_path)) {
 431         $tmp_socket_path = File::Temp::tempnam('/tmp', 'i3-test-socket-');
 432     }
 433
 434     my ($fh, $tmpfile) = tempfile('/tmp/i3-test-config-XXXXX', UNLINK => 1);
 435     say $fh $config;
 436     say $fh "ipc-socket $tmp_socket_path" unless $dont_add_socket_path;
 437     close($fh);
 438
 439     my $cv = AnyEvent->condvar;
 440     my $pid = activate_i3(
 441         unix_socket_path => "$tmp_socket_path-activation",
 442         display => $ENV{DISPLAY},
 443         configfile => $tmpfile,
 444         outdir => $ENV{OUTDIR},
 445         testname => $ENV{TESTNAME},
 446         valgrind => $ENV{VALGRIND},
 447         strace => $ENV{STRACE},
 448         cv => $cv,
 449     );
 450
 451     # blockingly wait until i3 is ready
 452     $cv->recv;
 453
 454     # force update of the cached socket path in lib/i3test
 455     get_socket_path(0);
 456
 457     return $pid;
 458 }
 459
 460 package i3test::X11;
 461 use parent 'X11::XCB::Connection';
 462
 463 sub input_focus {
 464     my $self = shift;
 465     i3test::sync_with_i3();
 466
 467     return $self->SUPER::input_focus(@_);
 468 }
 469
 470 1