git.sur5r.net Git - i3/i3/blob - testcases/t/158-wm_take_focus.t

   1 #!perl
   2 # vim:ts=4:sw=4:expandtab
   3 #
   4 # Please read the following documents before working on tests:
   5 # • http://build.i3wm.org/docs/testsuite.html
   6 #   (or docs/testsuite)
   7 #
   8 # • http://build.i3wm.org/docs/lib-i3test.html
   9 #   (alternatively: perldoc ./testcases/lib/i3test.pm)
  10 #
  11 # • http://build.i3wm.org/docs/ipc.html
  12 #   (or docs/ipc)
  13 #
  14 # • http://onyxneon.com/books/modern_perl/modern_perl_a4.pdf
  15 #   (unless you are already familiar with Perl)
  16 #
  17 # Tests if the WM_TAKE_FOCUS protocol is correctly handled by i3
  18 #
  19 # For more information on the protocol and input handling, see:
  20 # http://tronche.com/gui/x/icccm/sec-4.html#s-4.1.7
  21 #
  22 use i3test;
  23
  24 sub recv_take_focus {
  25     my ($window) = @_;
  26
  27     # sync_with_i3 will send a ClientMessage to i3 and i3 will send the same
  28     # payload back to $window->id.
  29     my $myrnd = sync_with_i3(
  30         window_id => $window->id,
  31         dont_wait_for_event => 1,
  32     );
  33
  34     # We check whether the first received message has the correct payload — if
  35     # not, the received message was a WM_TAKE_FOCUS message.
  36     my $first_event_is_clientmessage;
  37     wait_for_event 2, sub {
  38         my ($event) = @_;
  39         # TODO: const
  40         return 0 unless $event->{response_type} == 161;
  41
  42         my ($win, $rnd) = unpack "LL", $event->{data};
  43         if (!defined($first_event_is_clientmessage)) {
  44             $first_event_is_clientmessage = ($rnd == $myrnd);
  45         }
  46         return ($rnd == $myrnd);
  47     };
  48
  49     return !$first_event_is_clientmessage;
  50 }
  51
  52 subtest 'Window without WM_TAKE_FOCUS', sub {
  53     fresh_workspace;
  54
  55     my $window = open_window;
  56
  57     ok(!recv_take_focus($window), 'did not receive ClientMessage');
  58
  59     done_testing;
  60 };
  61
  62 subtest 'Window with WM_TAKE_FOCUS and without InputHint', sub {
  63     fresh_workspace;
  64
  65     my $take_focus = $x->atom(name => 'WM_TAKE_FOCUS');
  66
  67     my $window = open_window({
  68         dont_map => 1,
  69         protocols => [ $take_focus ],
  70     });
  71
  72     # add an (empty) WM_HINTS property without the InputHint
  73     $window->delete_hint('input');
  74
  75     $window->map;
  76
  77     ok(recv_take_focus($window), 'got ClientMessage with WM_TAKE_FOCUS atom');
  78
  79     done_testing;
  80 };
  81
  82 # If the InputHint is unspecified, i3 should use the simpler method of focusing
  83 # the window directly rather than using the WM_TAKE_FOCUS protocol.
  84 # XXX: The code paths for an unspecified and set InputHint are
  85 # nearly identical presently, so this is currently used also as a proxy test
  86 # for the latter case.
  87 subtest 'Window with WM_TAKE_FOCUS and unspecified InputHint', sub {
  88     fresh_workspace;
  89
  90     my $take_focus = $x->atom(name => 'WM_TAKE_FOCUS');
  91
  92     my $window = open_window({ protocols => [ $take_focus ] });
  93
  94     ok(!recv_take_focus($window), 'did not receive ClientMessage');
  95
  96     done_testing;
  97 };
  98
  99 done_testing;