dnl Process this file with autoconf to produce a configure script.

AC_INIT(glabels, 1.89.0, http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116)
AC_CONFIG_SRCDIR(src/glabels.c)
AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)

AM_MAINTAINER_MODE
AM_CONFIG_HEADER(config.h)

GNOME_PLATFORM_GNOME_2(yes, force)

AC_ISC_POSIX
AC_PROG_CC
AM_PROG_CC_STDC
AC_HEADER_STDC

GNOME_COMPILE_WARNINGS
GNOME_X_CHECKS

AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)


dnl *******************************************************************
dnl * Check for required package and version
dnl *******************************************************************
dnl Minimum versions of libraries
GTK_REQUIRED=2.0.5
LIBGNOMEUI_REQUIRED=2.0.1
LIBXML_REQUIRED=2.4.23
LIBGNOMEPRINT_REQUIRED=1.115.0
LIBGNOMEPRINTUI_REQUIRED=1.115.0
LIBGNOMECANVAS_REQUIRED=2.0.1
GDKPIXBUF_REQUIRED=2.0.5
               
PKG_CHECK_MODULES(GLABELS, gtk+-2.0 >= $GTK_REQUIRED
			   libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED
			   libxml-2.0 >= $LIBXML_REQUIRED
			   libgnomeprint-2.0 >= $LIBGNOMEPRINT_REQUIRED
			   libgnomeprintui-2.0 >= $LIBGNOMEPRINTUI_REQUIRED
			   libgnomecanvas-2.0 >= $LIBGNOMECANVAS_REQUIRED
			   gdk-pixbuf-2.0 >= $GDKPIXBUF_REQUIRED)
AC_SUBST(GLABELS_CFLAGS)
AC_SUBST(GLABELS_LIBS)

dnl ****************************************
dnl * Supported languages
dnl ****************************************
dnl Add the languages which your application supports here.
GETTEXT_PACKAGE=glabels
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE")
ALL_LINGUAS="fr de ja pt_BR es ru zh_TW.Big5 pl"
AM_GLIB_GNU_GETTEXT


dnl ****************************************
dnl * Set PACKAGE_LOCALE_DIR in config.h.
dnl ****************************************
if test "x${prefix}" = "xNONE"; then
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${ac_default_prefix}/${DATADIRNAME}/locale")
  AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/${DATADIRNAME}")
else
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${prefix}/${DATADIRNAME}/locale")
  AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/${DATADIRNAME}")
fi


dnl ****************************************
dnl * Configure barcode library
dnl ****************************************
AC_CONFIG_SUBDIRS(barcode-0.98)



dnl ****************************************
dnl * Makefiles
dnl ****************************************
AC_OUTPUT([
Makefile
src/Makefile
src/pixmaps/Makefile
src/stock-pixmaps/Makefile
po/Makefile.in
doc/Makefile
doc/C/Makefile
glabels.spec
])


echo "

Configuration:

        Source code location:   ${srcdir}
        Compiler:               ${CC} 

"