X-Git-Url: https://git.sur5r.net/?a=blobdiff_plain;f=configure.ac;h=2f1817ef69ca9be2c526a2c25ab00dfe6a164f40;hb=1aa23b165011cf979483755c7a052c09e1240c6e;hp=6ae41e5257a30588302c0830a1dcba4c4b1e9020;hpb=ada740b52343cdeea3e8e631c3d09ac735452091;p=kconfig-frontends

diff --git a/configure.ac b/configure.ac
index 6ae41e5..2f1817e 100644
--- a/configure.ac
+++ b/configure.ac
@@ -10,7 +10,7 @@ AC_PREREQ([2.67])
 AC_INIT(
     [kconfig-frontends],
     [m4_esyscmd_s([./scripts/version.sh])],
-    [nobody@nowhere.org])
+    [yann.morin.1998@free.fr])
 AC_CONFIG_SRCDIR([frontends/conf/conf.c])
 # Use a config.h to avoid brazilions -DHAVE_FOO on compile lines
 AC_CONFIG_HEADERS([scripts/.autostuff/config.h])
@@ -19,15 +19,72 @@ AC_CONFIG_MACRO_DIR([scripts/.autostuff/m4])
 
 #----------------------------------------
 # Prepare automake
-AM_INIT_AUTOMAKE
+
+# We want to allow the user to override our default program-prefix,
+# so we must set-it now, before automake has a chance to interpret
+# it, but after the options are parsed, so as not to overwrite the
+# value (if any) set by the user
+AS_IF(
+    [test "$program_prefix" = NONE],
+    [program_prefix=kconfig-])
+
+AM_INIT_AUTOMAKE([foreign])
+
+# For releases, enable silent rules, unless the user explicitly
+# disables them.
+# For the devel tree, do build with verbose output, unless user
+# explicitly enables silent rules
+AS_IF(
+    [test "$(${srcdir}/scripts/version.sh --internal)" = "git"],
+    [AM_SILENT_RULES],
+    [AM_SILENT_RULES([yes])])
+
+AS_IF(
+    [test $AM_DEFAULT_VERBOSITY -eq 0],
+    [SILENT_MAKEFLAGS="--no-print-directory -s"],
+    [SILENT_MAKEFLAGS=""])
+AC_SUBST([SILENT_MAKEFLAGS])
 
 #----------------------------------------
 # Prepare libtool
+m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl Automake, we have a problem...
 LT_PREREQ([2.2.6])
 LT_INIT([disable-static])
 
 #---------------------------------------------------------------------------
 # Set misc options
+
+# By default, do build with -Wall, unless the user asks not to
+[wall_CFLAGS=-Wall]
+AC_ARG_ENABLE(
+    [wall],
+    [AS_HELP_STRING(
+        [--disable-wall],
+        [build with -Wall (default=yes)])],
+    [AS_CASE(
+        ["$enableval"],
+        [yes], [wall_CFLAGS=-Wall],
+        [*],   [wall_CFLAGS=""])])
+AC_SUBST([wall_CFLAGS],[${wall_CFLAGS}])
+
+# For releases, do not build with -Werror, unless the user explicitly
+# requests to build with -Werror.
+# For the devel tree, do build with -Werror by default, unless user
+# explicitly disables -Werror
+AS_IF(
+    [test "$(${srcdir}/scripts/version.sh --internal)" = "git"],
+    [werror_CFLAGS=-Werror])
+AC_ARG_ENABLE(
+    [werror],
+    [AS_HELP_STRING(
+        [--enable-werror],
+        [build with -Werror (default=no)])],
+    [AS_CASE(
+        ["$enableval"],
+        [yes], [werror_CFLAGS=-Werror],
+        [*],   [werror_CFLAGS=""])])
+AC_SUBST([werror_CFLAGS],[${werror_CFLAGS}])
+
 # Although there is a default (="linux") in the code, we do provide
 # a default here, to get a consistent autostuff behavior
 AC_ARG_ENABLE(
@@ -40,9 +97,7 @@ AC_ARG_ENABLE(
         [yes], [root_menu=Configuration],
         [no],  [root_menu=],
                [# Escape the $ signs, otherwise they would get munged by make
-                # Also, append a space at the end, to separate the package
-                # name from the literal 'Configuration'
-                root_menu="$( echo "$enableval" |sed -r -e 's/\$/\\$$/g;' )"])])
+                root_menu="$( echo "$enableval" |sed -e 's/\$/\\$$/g;' )"])])
 AC_SUBST([root_menu], [${root_menu=Configuration}])
 
 AC_ARG_ENABLE(
@@ -58,6 +113,20 @@ AC_ARG_ENABLE(
                 [config_prefix=$enableval])])
 AC_SUBST([config_prefix], [${config_prefix-CONFIG_}])
 
+AC_ARG_ENABLE(
+    [utils],
+    [AS_HELP_STRING(
+        [--disable-utils],
+        [install utilities to manage .config files (default=yes)])])
+AC_SUBST([enable_utils], [${enable_utils:-yes}])
+
+AC_ARG_ENABLE(
+    [L10n],
+    [AS_HELP_STRING(
+        [--disable-L10n],
+        [enable localisation (L10n) (default=auto)])])
+AC_SUBST([enable_L10n], [${enable_L10n:-yes}])
+
 #----------------------------------------
 # Options to selectively enable/disable frontends
 # All are selected by default
@@ -111,6 +180,10 @@ AC_ARG_ENABLE(
      done])
 AC_SUBST([enable_frontends])
 
+#----------------------------------------
+# What extra CFLAGS we will be using
+AC_SUBST([kf_CFLAGS], ["$wall_CFLAGS $werror_CFLAGS"])
+
 #----------------------------------------
 # Dependencies that will be needed, depending on the frontends
 AS_CASE(
@@ -146,60 +219,77 @@ AS_IF(
 AS_IF(
     [test "$need_pkgconfig" = "yes"],
     [PKG_PROG_PKG_CONFIG()])
+# Look for `lex'. If it cannot be found, autoconf sets $LEX to ':'.
 AC_PROG_LEX
+AS_IF(
+    [test "$LEX" = ":"],
+    [AC_MSG_ERROR([can not find a lexer generator (such as lex or flex)])])
 AC_SUBST([AM_LFLAGS], ["-L -P zconf"])
+# Look for `yacc'. If it cannot be found, autoconf sets $YACC to 'yacc'.
 AC_PROG_YACC
+AS_IF(
+    [test "$YACC" = "yacc"],
+    [AC_CHECK_PROGS(
+        [YACC_IN_PATH],
+        [yacc])]
+     AS_IF(
+        [test -z "$YACC_IN_PATH"],
+        [AC_MSG_ERROR([can not find a parser generator (such as yacc or bison)])]))
 AC_SUBST([AM_YFLAGS], ["-t -l -p zconf"])
 
-#----------------------------------------
-# Check for standard headers
-AC_HEADER_STDC
-AC_HEADER_STDBOOL
-AC_CHECK_HEADERS([ fcntl.h libintl.h limits.h locale.h ])
-AC_CHECK_HEADERS([ stdlib.h string.h sys/time.h unistd.h ])
-AC_TYPE_SIZE_T
-
-#----------------------------------------
-# Checks for library functions.
-AC_FUNC_MALLOC
-AC_FUNC_REALLOC
-AC_FUNC_ALLOCA
-AC_CHECK_FUNCS([ bzero memmove memset ])
-AC_CHECK_FUNCS([ strcasecmp strchr strcspn strdup strncasecmp strpbrk strrchr strspn strtol ])
-AC_CHECK_FUNCS([ gettimeofday mkdir regcomp setlocale uname ])
-
 #----------------------------------------
 # Check for gettext, for the kconfig frontends
-AC_SUBST([GETTEXT])
-AC_CHECK_HEADERS(
-    [libintl.h],
-    [ac_ct_gettext_hdr=$ac_header; break],
-    [AC_MSG_WARN([libintl is missing, frontends will not be localised])])
+[has_gettext="$enable_L10n"]
+AS_IF(
+    [test "$has_gettext" = "yes"],
+    [AC_CHECK_HEADERS(
+        [libintl.h],
+        [ac_ct_gettext_hdr=$ac_header; break],
+        [has_gettext=no])])
 AS_IF(
-    [test -n "$ac_ct_gettext_hdr"],
+    [test "$has_gettext" = "yes"],
     [AC_CHECK_DECL(
         [gettext],,
-        [AC_MSG_WARN([gettext is missing, frontends will not be localised])
-         GETTEXT=-DKBUILD_NO_NLS],
+        [has_gettext=no],
         [#include <$ac_ct_gettext_hdr>])])
+AS_IF(
+    [test "$has_gettext" = "yes"],
+    [LIBS_old="$LIBS"
+     LIBS=
+     AC_SEARCH_LIBS(
+        [gettext],
+        [intl],,
+        [has_gettext=no])
+    intl_LIBS="$LIBS"
+    LIBS="$LIBS_old"])
+AS_IF(
+    [test "$has_gettext" = "no"],
+    [intl_CPPFLAGS=-DKBUILD_NO_NLS])
+AC_SUBST([intl_CPPFLAGS])
+AC_SUBST([intl_LIBS])
 
 #----------------------------------------
 # Check for ncurses, for the mconf & nconf frontends
 AS_IF(
     [test "$need_curses" = "yes" -o "$need_curses" = "auto"],
-    [AC_SUBST([CURSES_LOC])
+    [AC_SUBST([ncurses_mconf_CPPFLAGS])
      AC_SUBST([ncurses_LIBS])
      LIBS_old="$LIBS"
      LIBS=
      AC_CHECK_HEADERS(
-        [ncurses/ncurses.h ncurses/curses.h ncursesw/curses.h ncurses.h curses.h],
-        [CURSES_LOC=$ac_header; break])
+        [ncursesw/curses.h ncurses/ncurses.h ncurses/curses.h ncurses.h curses.h],
+        [CURSES_LOC=$ac_header
+         ncurses_mconf_CPPFLAGS=-DCURSES_LOC=\\\"$ac_header\\\"
+         break # Stupid syntax-coloring in vim: "])
      AS_IF(
         [test -z "$CURSES_LOC"],
         [AS_IF(
             [test "$need_curses" = "yes"],
             [AC_MSG_ERROR([could not find curses headers (frontends: mconf/nconf)])],
             [has_curses=no])])
+     AS_CASE(
+        [$CURSES_LOC],
+        [ncursesw/*],[ncurses_mconf_CPPFLAGS="$ncurses_mconf_CPPFLAGS -DNCURSES_WIDECHAR=1"])
      AC_SEARCH_LIBS(
         [initscr],
         [ncursesw ncurses curses],
@@ -210,6 +300,10 @@ AS_IF(
             [test "$need_curses" = "yes"],
             [AC_MSG_ERROR([could not find curses library (frontends: mconf/nconf)])],
             [has_curses=no])])
+     AC_SEARCH_LIBS(
+        [setupterm],
+        [tinfo],
+        [break])
      ncurses_LIBS="$LIBS"
      LIBS=$LIBS_old])
 
@@ -221,7 +315,12 @@ AS_IF(
 # Check for libpanel and libmenu, for the nconf frontend
 AS_IF(
     [test "$need_panel_menu" = "yes" -o "$need_panel_menu" = "auto"],
-    [AC_SUBST([ncurses_extra_LIBS])
+    [AC_SUBST([ncurses_nconf_CPPFLAGS])
+     AC_SUBST([ncurses_panel_menu_LIBS])
+     AS_CASE(
+        [$CURSES_LOC],
+        [ncursesw/*],[ncurses_nconf_CPPFLAGS="-I/usr/include/ncursesw"],
+        [ncurses/*],[ncurses_nconf_CPPFLAGS="-I/usr/include/ncurses"])
      LIBS_old="$LIBS"
      LIBS=
      AC_SEARCH_LIBS(
@@ -246,7 +345,7 @@ AS_IF(
             [test "$need_panel_menu" = "yes"],
             [AC_MSG_ERROR([could not find libmenu library (frontend: nconf)])],
             [has_panel_menu=no])])
-     ncurses_extra_LIBS="$LIBS"
+     ncurses_panel_menu_LIBS="$LIBS"
      LIBS=$LIBS_old])
 
 AS_IF(
@@ -272,27 +371,36 @@ AS_IF(
 
 #----------------------------------------
 # Check headers and libs for qconf
-AC_ARG_VAR([MOC], [Qt meta object compiler (moc) command])
 AS_IF(
     [test "$need_qt" = "yes" -o "$need_qt" = "auto"],
     [PKG_CHECK_MODULES(
         [qt4],
         [QtCore QtGui Qt3Support],
-        [has_qt=yes],
+        [has_qt=yes; need_moc="$need_qt"],
         [AS_IF(
             [test "$need_qt" = "yes"],
             [AC_MSG_ERROR([could not find QT4 headers and/or libraries (frontend: qconf)])],
-            [has_qt=no])])])
+            [has_qt=no; need_moc=no])])])
 
+AC_ARG_VAR([MOC], [Qt meta object compiler (moc) command])
 AS_IF(
-    [test "$has_qt" = "no" ],
-    [enable_qconf=no],
+    [test "$need_moc" = "yes" -o "$need_moc" = "auto"],
     [QT4_BINDIR=`$PKG_CONFIG Qt --variable bindir`
      AC_PATH_PROGS(
         [MOC],
-        [moc-qt4 moc],
-        [moc],
-        [$QT4_BINDIR:$PATH])])
+        [moc-qt4 moc],,
+        [$QT4_BINDIR:$PATH])
+     AS_IF(
+        [test -n "$MOC"],
+        [has_moc=yes],
+        [AS_IF(
+            [test "$need_moc" = "yes"],
+            [AC_MSG_ERROR([could not find moc (frontend: qconf)])],
+            [has_moc=no])])])
+
+AS_IF(
+    [test "$has_qt" = "no" -o "$has_moc" = "no"],
+    [enable_qconf=no])
 
 #----------------------------------------
 # Per-frontends extra libraries
@@ -317,6 +425,13 @@ AS_IF(
     [need_lxdialog=yes],
     [need_lxdialog=no])
 
+#----------------------------------------
+# Check if the images library should be built
+AS_IF(
+    [test "$enable_gconf" = "yes" -o "$enable_qconf" = "yes"],
+    [need_images=yes],
+    [need_images=no])
+
 #----------------------------------------
 # Setup automake conditional build
 AM_CONDITIONAL(
@@ -337,6 +452,15 @@ AM_CONDITIONAL(
 AM_CONDITIONAL(
     [COND_lxdialog],
     [test "$need_lxdialog" = "yes"])
+AM_CONDITIONAL(
+    [COND_images],
+    [test "$need_images" = "yes"])
+AM_CONDITIONAL(
+    [COND_utils],
+    [test "$enable_utils" = "yes"])
+AM_CONDITIONAL(
+    [COND_utils_gettext],
+    [test "$has_gettext" = "yes"])
 
 #----------------------------------------
 # Get the version to apply to the parser shared library
@@ -348,6 +472,7 @@ AC_SUBST(
 # Finalise
 AC_CONFIG_FILES([
     Makefile
+    docs/Makefile
     libs/Makefile
     libs/images/Makefile
     libs/lxdialog/Makefile
@@ -358,31 +483,35 @@ AC_CONFIG_FILES([
     frontends/nconf/Makefile
     frontends/gconf/Makefile
     frontends/qconf/Makefile
+    utils/Makefile
+    scripts/Makefile
 ])
 AC_OUTPUT
 
+#----------------------------------------
+# Pretty-print the configuration settings
+[fe_list=]
+AS_IF([test "$enable_conf"  = "yes"], [fe_list="$fe_list conf" ])
+AS_IF([test "$enable_gconf" = "yes"], [fe_list="$fe_list gconf"])
+AS_IF([test "$enable_mconf" = "yes"], [fe_list="$fe_list mconf"])
+AS_IF([test "$enable_nconf" = "yes"], [fe_list="$fe_list nconf"])
+AS_IF([test "$enable_qconf" = "yes"], [fe_list="$fe_list qconf"])
+
+[lib_list=]
+AS_IF(
+    [test "$enable_shared" = "yes"],
+    [lib_list="$lib_list shared (version: $KCONFIGPARSER_LIB_VERSION)"])
+AS_IF(
+    [test "$enable_static" = "yes"],
+    [lib_list="$lib_list${lib_list:+,} static"])
+
 AC_MSG_NOTICE()
 AC_MSG_NOTICE([Configured with:])
-AC_MSG_NOTICE([- root-menu prompt: '$root_menu'])
-AC_MSG_NOTICE([- config prefix:    '$config_prefix'])
-AC_MSG_NOTICE([- frontends:])
-AS_IF([test "$enable_conf" = "yes"],
-      [AC_MSG_NOTICE([  - conf:  yes])],
-      [AC_MSG_NOTICE([  - conf:  no])])
-AS_IF([test "$enable_gconf" = "yes"],
-      [AC_MSG_NOTICE([  - gconf: yes])],
-      [AC_MSG_NOTICE([  - gconf: no])])
-AS_IF([test "$enable_mconf" = "yes"],
-      [AC_MSG_NOTICE([  - mconf: yes])],
-      [AC_MSG_NOTICE([  - mconf: no])])
-AS_IF([test "$enable_nconf" = "yes"],
-      [AC_MSG_NOTICE([  - nconf: yes])],
-      [AC_MSG_NOTICE([  - nconf: no])])
-AS_IF([test "$enable_qconf" = "yes"],
-      [AC_MSG_NOTICE([  - qconf: yes])],
-      [AC_MSG_NOTICE([  - qconf: no])])
-AC_MSG_NOTICE([- parser library:])
-AS_IF([test "$enable_shared" = "yes"],
-      [AC_MSG_NOTICE([  - shared: yes, versioned $KCONFIGPARSER_LIB_VERSION])],
-      [AC_MSG_NOTICE([  - shared: no])])
-AC_MSG_NOTICE([  - static: $enable_static])
+AC_MSG_NOTICE([- parser library     :$lib_list])
+AC_MSG_NOTICE([  - root-menu prompt : $root_menu])
+AC_MSG_NOTICE([  - config prefix    : $config_prefix])
+AC_MSG_NOTICE([- frontends          :$fe_list])
+AC_MSG_NOTICE([  - transform name   : $program_transform_name])
+AC_MSG_NOTICE([  - localised        : $has_gettext])
+AC_MSG_NOTICE([- install utilities  : $enable_utils])
+AC_MSG_NOTICE([- CFLAGS CXXFLAGS    : $wall_CFLAGS $werror_CFLAGS])