lal#
dnl#
dnl# Process this file with autoconf to produce a configure script.
dnl#
AC_INIT(version.h)
BUILD_DIR=`pwd`
cd ..
TOP_DIR=`pwd`
cd ${BUILD_DIR}
AC_SUBST(BUILD_DIR)
AC_CONFIG_AUX_DIR(${BUILD_DIR}/autoconf)

dnl require a recent autoconf
AC_PREREQ(2.13)


dnl search for true and false programs.
AC_PATH_PROGS(TRUEPRG, true, :)
AC_PATH_PROGS(FALSEPRG, false, :)

AC_PROG_AWK
# Some AWK programs fail, so test it and warn the user
if echo xfoo | $AWK 'BEGIN { prog=ARGV[1]; ARGC=1 } 
      { if ((prog == $2) || (("(" prog ")") == $2) ||
	   (("[" prog "]") == $2) ||
	   ((prog ":") == $2)) { print $1 ; exit 0 } }' xfoo>/dev/null; then :;
else
  AC_MSG_ERROR([!!!!!!!!! WARNING !!!!!!!!!!!!!!
   The regex engine of $AWK is too broken to be used you 
   might want to install GNU AWK.
   !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!])
fi
THE_AWK=$AWK
AC_PATH_PROG(AWK, $THE_AWK, $THE_AWK)


dnl Rescue version
VERSION=`sed -n -e 's/^.*VERSION.*"\(.*\)"$/\1/p' ${srcdir}/version.h`
DATE=`sed -n -e 's/^.*[ \t]*BDATE.*"\(.*\)"$/\1/p' ${srcdir}/version.h`
AC_SUBST(VERSION)dnl 
AC_SUBST(DATE)dnl 
echo "configuring for Rescue $VERSION ($DATE)"


dnl -------------------------------------------------------
dnl# Check for programs.
dnl ------------------------------------------------------
AC_PROG_INSTALL
AC_PATH_PROG(MV, mv, mv)
AC_PATH_PROG(RM, rm, rm)
AC_PATH_PROG(CP, cp, cp)
AC_PATH_PROG(ECHO, echo, echo)
AC_PATH_PROG(AR, ar, ar)
AC_PATH_PROG(CDRECORD, cdrecord, cdrecord)

dnl --------------------------------------------------
dnl OP Sys determination (see aclocal.m4)
dnl --------------------------------------------------
BA_CHECK_OPSYS

# -----------------------------------------------------------
dnl OPSys Distribution determination (see aclocal.m4)
# ----------------------------------------------------------
BA_CHECK_OPSYS_DISTNAME

# -------------------------------------------------------------------------
#  If the user has not set --exec-prefix, we default to ${prefix}
# -------------------------------------------------------------------------
if test x${exec_prefix} = xNONE ; then
    exec_prefix=${prefix}
fi

# -------------------------------------------
# check for cdrecord writer location
# get scsibus,target,lun
# -------------------------------------------
CDSTL="3,0,0"
if test ! x$CDRECORD = x ; then
   CDSTL=`${CDRECORD} -scanbus 2>/dev/null | grep CD-RW | ${AWK} '{print $1}'`
   if test x${CDSTL} = x ; then
      CDSTL=`${CDRECORD} -scanbus 2>/dev/null | grep CD+RW | ${AWK} '{print $1}'`
   fi
   if test x${CDSTL} = x ; then
      CDSTL="3,0,0"
   fi
fi
AC_SUBST(CDSTL)

dnl# --------------------------------------------------------------------------
dnl# CHECKING COMMAND LINE OPTIONS
dnl# --------------------------------------------------------------------------

# -------------------------------------------
# static-fd    (default off)
# -------------------------------------------
AC_ARG_ENABLE(static-fd,
   [  --enable-static-fd      enable static File daemon [disabled]],
   [if test x$enableval = xyes; then
     support_static_fd=yes
   fi])

STATIC_FD=
if test x$support_static_fd = xyes; then
   STATIC_FD="static-bacula-fd"
fi
AC_SUBST(STATIC_FD)

where=
# ------------------------------------------
# Where to get iso
# ------------------------------------------
AC_ARG_WITH(iso,
   [  --with-iso=PATH	 specify path to iso],
   [
       if test "x$withval" != "xno" ; then     
	   where=$withval
	   type=iso
       fi
   ]
)
AC_SUBST(iso)

# ------------------------------------------
# Where to get cdrom
# ------------------------------------------
AC_ARG_WITH(cdrom,
   [  --with-cdrom=PATH    specify path to cdrom],
   [
       if test "x$withval" != "xno" ; then     
	  where=$withval
	  type=cdrom
       fi
   ]
)

AC_SUBST(where)
AC_SUBST(type)

# ------------------------------------------
# Where to get Bacula source
# ------------------------------------------
AC_ARG_WITH(bacula,
   [  --with-bacula=PATH    specify path to bacula],
   [
       if test "x$withval" != "xno" ; then     
	  bacula=$withval
       fi
   ]
)

AC_SUBST(bacula)


#
# Finally we set appropriate distribution specific
#  variables and defaults
#
# PFILES are platform specific files
PFILES=""
WIN32=
MACOSX=
hostname=`uname -n | cut -d '.' -f 1`
case "$DISTNAME" in
aix)
	DISTVER=`uname -r`
  ;;	  
alpha)
	DISTVER=`uname -r`
  ;;
bsdi)
	DISTVER=`uname -a |awk '{print $3}'`
  ;;
cygwin)
	DISTVER=`uname -a |awk '{print $3}'`
	WIN32=win32
  ;;
darwin)
	DISTVER=`uname -r`
  ;;
debian)
	DISTVER=`cat /etc/debian_version`
  ;;
freebsd)
	DISTVER=`uname -a |awk '{print $3}'`
  ;;
hpux)
	DISTVER=`uname -r`
  ;;
irix)
	DISTVER=`uname -r`
  ;;
netbsd)
	DISTVER=`uname -a |awk '{print $3}'`
  ;;
openbsd)
	DISTVER=`uname -a |awk '{print $3}'`
  ;;
redhat)
	if test -f /etc/whitebox-release ; then
	   f=/etc/whitebox-release
	else
	   f=/etc/redhat-release
	fi
	if test `cat $f | grep release |\
		   cut -f 3 -d ' '`x = "Enterprise"x ; then
	   DISTVER="Enterprise "`cat $f | grep release |\
		    cut -f 6 -d ' '`
	else
	    DISTVER=`cat /etc/redhat-release | grep release |\
		     cut -f 5 -d ' '`
	fi
	hostname=`hostname -s`
  ;;
mandrake)
	DISTVER=`cat /etc/mandrake-release | grep release |\
	   cut -f 5 -d ' '`
  ;;
gentoo)
	DISTVER=`awk '/version / {print $5}' < /etc/gentoo-release`
  ;;
slackware)
	DISTVER=`cat /etc/slackware-version`
  ;;
solaris)
	DISTVER=`uname -r`
  ;;
suse)
	DISTVER=`cat /etc/SuSE-release |grep VERSION|\
	    cut -f 3 -d ' '`
  ;;
suse5)
	DISTNAME=suse
	DISTVER=5.x
  ;;
unknown)
	DISTVER=unknown
  ;;
*)
  echo " === Something went wrong. Unknown DISTNAME $DISTNAME ==="
  ;;
esac  

AC_SUBST(hostname)

AC_SUBST(DISTNAME)
AC_SUBST(DISTVER)

dnl# common parts of the Makefile
MCOMMON=./autoconf/Make.common
AC_SUBST_FILE(MCOMMON)


AC_OUTPUT([    \
	   autoconf/Make.common \
	   Makefile \
	   linux/Makefile \
	   linux/floppy/Makefile \
	   linux/cdrom/Makefile \
	   linux/cdrom/bacula/Makefile \
	   freebsd/Makefile \
	   solaris/Makefile \
	   $PFILES ],  
	  [ ]
)


echo "
Configuration on `date`:

  Host: 		      $host -- ${DISTNAME} ${DISTVER}
  Rescue version:	      ${VERSION} (${DATE})
  Source code location:       ${bacula}
  Rescue disk image type:     ${type}
  Rescue disk image location: ${where}


  " > config.out

cat config.out