git.sur5r.net Git - tio/blob - configure.ac

   1 AC_PREREQ([2.68])
   2 AC_INIT([tio], [1.32], [], [tio], [https://tio.github.io])
   3 AC_CONFIG_HEADERS([src/include/config.h])
   4 AM_INIT_AUTOMAKE([1.11 foreign dist-xz no-dist-gzip -Wall -Werror])
   5 AM_SILENT_RULES([yes])
   6 AC_PROG_CC
   7 AC_LANG([C])
   8 AC_PROG_INSTALL
   9 AC_SYS_LARGEFILE
  10
  11 # Handle bash completion
  12 AC_ARG_WITH([bash-completion-dir],
  13     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
  14                    [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
  15                    [],
  16                    [with_bash_completion_dir=yes])
  17
  18 if test "x$with_bash_completion_dir" = "xyes"; then
  19     BASH_COMPLETION_DIR="${datadir}/bash-completion/completions"
  20 else
  21     BASH_COMPLETION_DIR="$with_bash_completion_dir"
  22 fi
  23 AC_SUBST([BASH_COMPLETION_DIR])
  24 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
  25
  26 # TIO_CHECK_BAUDRATE(N)
  27 AC_DEFUN(
  28     [TIO_CHECK_BAUDRATE],
  29     [
  30         AC_CHECK_DECL([B$1], [tio_have_decl=1], [tio_have_decl=0], [[#include <termios.h>]])
  31         AS_IF([test $tio_have_decl = 1], [
  32             AC_SUBST([BAUDRATES], ["$BAUDRATES $1"])
  33             AC_SUBST([BAUDRATE_CASES], ["$BAUDRATE_CASES case $1: baudrate = B$1; break;"])]
  34         )
  35     ]
  36 )
  37
  38 # TIO_CHECK_BAUDRATES(N1, N2, ...)
  39 AC_DEFUN(
  40     [TIO_CHECK_BAUDRATES],
  41     [m4_foreach([n], [$@], [TIO_CHECK_BAUDRATE(m4_normalize(n))])]
  42 )
  43
  44 # Check for available terminal I/O speeds
  45 BAUDRATES=
  46 BAUDRATE_CASES=
  47 TIO_CHECK_BAUDRATES(
  48     0,
  49     50,
  50     75,
  51     110,
  52     134,
  53     150,
  54     200,
  55     300,
  56     600,
  57     1200,
  58     1800,
  59     2400,
  60     4800,
  61     7200,
  62     9600,
  63     14400,
  64     19200,
  65     28800,
  66     38400,
  67     57600,
  68     76800,
  69     115200,
  70     230400,
  71     460800,
  72     500000,
  73     576000,
  74     921600,
  75     1000000,
  76     1152000,
  77     1500000,
  78     2000000,
  79     2500000,
  80     3000000,
  81     3500000,
  82     4000000
  83 )
  84
  85 AC_DEFINE_UNQUOTED([AUTOCONF_BAUDRATE_CASES],[$BAUDRATE_CASES],[Switch cases for detected baud rates])
  86
  87 # Check for interface for setting arbitrary I/O speeds
  88 AC_CHECK_DECL([TCGETS2], [AC_DEFINE([HAVE_TERMIOS2],[1],[Define if termios2 exists.]) have_termios2=yes], , [[#include <asm/termios.h>]])
  89 AM_CONDITIONAL([ADD_SETSPEED2],[test "x$have_termios2" == "xyes"])
  90
  91 AC_CONFIG_FILES([Makefile])
  92 AC_CONFIG_FILES([src/Makefile])
  93 AC_CONFIG_FILES([src/bash-completion/tio])
  94 AC_CONFIG_FILES([man/Makefile])
  95 AC_OUTPUT