git.sur5r.net Git - u-boot/blob - arch/arc/cpu/u-boot.lds

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * Copyright (C) 2013-2014 Synopsys, Inc. All rights reserved.
   4  */
   5
   6 #include <config.h>
   7
   8 OUTPUT_FORMAT("elf32-littlearc", "elf32-littlearc", "elf32-littlearc")
   9 OUTPUT_ARCH(arc)
  10 ENTRY(_start)
  11 SECTIONS
  12 {
  13         . = CONFIG_SYS_TEXT_BASE;
  14         __image_copy_start = .;
  15         __text_start = .;
  16         .text : {
  17                 arch/arc/lib/start.o (.text*)
  18                 *(.text*)
  19         }
  20         __text_end = .;
  21
  22         . = ALIGN(1024);
  23         __ivt_start = .;
  24         .ivt :
  25         {
  26                 *(.ivt)
  27         }
  28         __ivt_end = .;
  29
  30         . = ALIGN(4);
  31         .rodata : {
  32                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  33         }
  34
  35         . = ALIGN(4);
  36         .data : {
  37                 *(.data*)
  38         }
  39
  40         . = ALIGN(4);
  41         .u_boot_list : {
  42                 KEEP(*(SORT(.u_boot_list*)));
  43         }
  44
  45         . = ALIGN(4);
  46         __rel_dyn_start = .;
  47         .rela.dyn : {
  48                 *(.rela.dyn)
  49         }
  50         __rel_dyn_end = .;
  51
  52         . = ALIGN(4);
  53         __bss_start = .;
  54         .bss : {
  55                 *(.bss*)
  56         }
  57         __bss_end = .;
  58
  59         . = ALIGN(4);
  60         __image_copy_end = .;
  61         __init_end = .;
  62 }