git.sur5r.net Git - u-boot/blob - arch/arm/cpu/armv7/omap-common/lowlevel_init.S

   1 /*
   2  * Board specific setup info
   3  *
   4  * (C) Copyright 2010
   5  * Texas Instruments, <www.ti.com>
   6  *
   7  * Author :
   8  *      Aneesh V        <aneesh@ti.com>
   9  *
  10  * See file CREDITS for list of people who contributed to this
  11  * project.
  12  *
  13  * This program is free software; you can redistribute it and/or
  14  * modify it under the terms of the GNU General Public License as
  15  * published by the Free Software Foundation; either version 2 of
  16  * the License, or (at your option) any later version.
  17  *
  18  * This program is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  21  * GNU General Public License for more details.
  22  *
  23  * You should have received a copy of the GNU General Public License
  24  * along with this program; if not, write to the Free Software
  25  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  26  * MA 02111-1307 USA
  27  */
  28
  29 #include <config.h>
  30 #include <asm/arch/omap.h>
  31 #include <asm/arch/spl.h>
  32 #include <linux/linkage.h>
  33
  34 ENTRY(save_boot_params)
  35         /*
  36          * See if the rom code passed pointer is valid:
  37          * It is not valid if it is not in non-secure SRAM
  38          * This may happen if you are booting with the help of
  39          * debugger
  40          */
  41         ldr     r2, =NON_SECURE_SRAM_START
  42         cmp     r2, r0
  43         bgt     1f
  44         ldr     r2, =NON_SECURE_SRAM_END
  45         cmp     r2, r0
  46         blt     1f
  47
  48         /*
  49          * store the boot params passed from rom code or saved
  50          * and passed by SPL
  51          */
  52         cmp     r0, #0
  53         beq     1f
  54         ldr     r1, =boot_params
  55         str     r0, [r1]
  56 #ifdef CONFIG_SPL_BUILD
  57         /* Store the boot device in spl_boot_device */
  58         ldrb    r2, [r0, #BOOT_DEVICE_OFFSET]   @ r1 <- value of boot device
  59         and     r2, #BOOT_DEVICE_MASK
  60         ldr     r3, =boot_params
  61         strb    r2, [r3, #BOOT_DEVICE_OFFSET]   @ spl_boot_device <- r1
  62
  63         /* boot mode is passed only for devices that can raw/fat mode */
  64         cmp     r2, #BOOT_DEVICE_XIP
  65         blt     2f
  66         cmp     r2, #BOOT_DEVICE_MMC2
  67         bgt     2f
  68         /* Store the boot mode (raw/FAT) in omap_bootmode */
  69         ldr     r2, [r0, #DEV_DESC_PTR_OFFSET]  @ get the device descriptor ptr
  70         ldr     r2, [r2, #DEV_DATA_PTR_OFFSET]  @ get the pDeviceData ptr
  71         ldr     r2, [r2, #BOOT_MODE_OFFSET]     @ get the boot mode
  72         ldr     r3, =omap_bootmode
  73         str     r2, [r3]
  74 #endif
  75 2:
  76         ldrb    r2, [r0, #CH_FLAGS_OFFSET]
  77         ldr     r3, =boot_params
  78         strb    r2, [r3, #CH_FLAGS_OFFSET]
  79 1:
  80         bx      lr
  81 ENDPROC(save_boot_params)
  82
  83 ENTRY(set_pl310_ctrl_reg)
  84         PUSH    {r4-r11, lr}    @ save registers - ROM code may pollute
  85                                 @ our registers
  86         LDR     r12, =0x102     @ Set PL310 control register - value in R0
  87         .word   0xe1600070      @ SMC #0 - hand assembled because -march=armv5
  88                                 @ call ROM Code API to set control register
  89         POP     {r4-r11, pc}
  90 ENDPROC(set_pl310_ctrl_reg)