git.sur5r.net Git - u-boot/blob - arch/arm/cpu/u-boot-spl.lds

   1 /*
   2  * Copyright (c) 2004-2008 Texas Instruments
   3  *
   4  * (C) Copyright 2002
   5  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  11 OUTPUT_ARCH(arm)
  12 ENTRY(_start)
  13 SECTIONS
  14 {
  15         . = 0x00000000;
  16
  17         . = ALIGN(4);
  18         .text :
  19         {
  20                 __image_copy_start = .;
  21                 *(.vectors)
  22                 CPUDIR/start.o (.text*)
  23                 *(.text*)
  24                 *(.glue*)
  25         }
  26
  27         . = ALIGN(4);
  28         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  29
  30         . = ALIGN(4);
  31         .data : {
  32                 *(.data*)
  33         }
  34
  35         . = ALIGN(4);
  36         .u_boot_list : {
  37                 KEEP(*(SORT(.u_boot_list*)));
  38         }
  39
  40         . = ALIGN(4);
  41         .binman_sym_table : {
  42                 __binman_sym_start = .;
  43                 KEEP(*(SORT(.binman_sym*)));
  44                 __binman_sym_end = .;
  45         }
  46
  47         . = ALIGN(4);
  48
  49         __image_copy_end = .;
  50
  51         .rel.dyn : {
  52                 __rel_dyn_start = .;
  53                 *(.rel*)
  54                 __rel_dyn_end = .;
  55         }
  56
  57         .end :
  58         {
  59                 *(.__end)
  60         }
  61
  62         _image_binary_end = .;
  63
  64         .bss __rel_dyn_start (OVERLAY) : {
  65                 __bss_start = .;
  66                 *(.bss*)
  67                  . = ALIGN(4);
  68                 __bss_end = .;
  69         }
  70         __bss_size = __bss_end - __bss_start;
  71         .dynsym _image_binary_end : { *(.dynsym) }
  72         .dynbss : { *(.dynbss) }
  73         .dynstr : { *(.dynstr*) }
  74         .dynamic : { *(.dynamic*) }
  75         .hash : { *(.hash*) }
  76         .plt : { *(.plt*) }
  77         .interp : { *(.interp*) }
  78         .gnu : { *(.gnu*) }
  79         .ARM.exidx : { *(.ARM.exidx*) }
  80 }
  81
  82 #if defined(CONFIG_SPL_MAX_SIZE)
  83 ASSERT(__image_copy_end - __image_copy_start < (CONFIG_SPL_MAX_SIZE), \
  84         "SPL image too big");
  85 #endif
  86
  87 #if defined(CONFIG_SPL_BSS_MAX_SIZE)
  88 ASSERT(__bss_end - __bss_start < (CONFIG_SPL_BSS_MAX_SIZE), \
  89         "SPL image BSS too big");
  90 #endif
  91
  92 #if defined(CONFIG_SPL_MAX_FOOTPRINT)
  93 ASSERT(__bss_end - _start < (CONFIG_SPL_MAX_FOOTPRINT), \
  94         "SPL image plus BSS too big");
  95 #endif