git.sur5r.net Git - u-boot/blob - arch/arm/lib/crt0.S

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  *  crt0 - C-runtime startup Code for ARM U-Boot
   4  *
   5  *  Copyright (c) 2012  Albert ARIBAUD <albert.u.boot@aribaud.net>
   6  */
   7
   8 #include <config.h>
   9 #include <asm-offsets.h>
  10 #include <linux/linkage.h>
  11 #ifdef CONFIG_CPU_V7M
  12 #include <asm/armv7m.h>
  13 #endif
  14
  15 /*
  16  * This file handles the target-independent stages of the U-Boot
  17  * start-up where a C runtime environment is needed. Its entry point
  18  * is _main and is branched into from the target's start.S file.
  19  *
  20  * _main execution sequence is:
  21  *
  22  * 1. Set up initial environment for calling board_init_f().
  23  *    This environment only provides a stack and a place to store
  24  *    the GD ('global data') structure, both located in some readily
  25  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
  26  *    global data, initialized or not (BSS), are UNAVAILABLE; only
  27  *    CONSTANT initialized data are available. GD should be zeroed
  28  *    before board_init_f() is called.
  29  *
  30  * 2. Call board_init_f(). This function prepares the hardware for
  31  *    execution from system RAM (DRAM, DDR...) As system RAM may not
  32  *    be available yet, , board_init_f() must use the current GD to
  33  *    store any data which must be passed on to later stages. These
  34  *    data include the relocation destination, the future stack, and
  35  *    the future GD location.
  36  *
  37  * 3. Set up intermediate environment where the stack and GD are the
  38  *    ones allocated by board_init_f() in system RAM, but BSS and
  39  *    initialized non-const data are still not available.
  40  *
  41  * 4a.For U-Boot proper (not SPL), call relocate_code(). This function
  42  *    relocates U-Boot from its current location into the relocation
  43  *    destination computed by board_init_f().
  44  *
  45  * 4b.For SPL, board_init_f() just returns (to crt0). There is no
  46  *    code relocation in SPL.
  47  *
  48  * 5. Set up final environment for calling board_init_r(). This
  49  *    environment has BSS (initialized to 0), initialized non-const
  50  *    data (initialized to their intended value), and stack in system
  51  *    RAM (for SPL moving the stack and GD into RAM is optional - see
  52  *    CONFIG_SPL_STACK_R). GD has retained values set by board_init_f().
  53  *
  54  * 6. For U-Boot proper (not SPL), some CPUs have some work left to do
  55  *    at this point regarding memory, so call c_runtime_cpu_setup.
  56  *
  57  * 7. Branch to board_init_r().
  58  *
  59  * For more information see 'Board Initialisation Flow in README.
  60  */
  61
  62 /*
  63  * entry point of crt0 sequence
  64  */
  65
  66 ENTRY(_main)
  67
  68 /*
  69  * Set up initial C runtime environment and call board_init_f(0).
  70  */
  71
  72 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
  73         ldr     r0, =(CONFIG_SPL_STACK)
  74 #else
  75         ldr     r0, =(CONFIG_SYS_INIT_SP_ADDR)
  76 #endif
  77         bic     r0, r0, #7      /* 8-byte alignment for ABI compliance */
  78         mov     sp, r0
  79         bl      board_init_f_alloc_reserve
  80         mov     sp, r0
  81         /* set up gd here, outside any C code */
  82         mov     r9, r0
  83         bl      board_init_f_init_reserve
  84
  85         mov     r0, #0
  86         bl      board_init_f
  87
  88 #if ! defined(CONFIG_SPL_BUILD)
  89
  90 /*
  91  * Set up intermediate environment (new sp and gd) and call
  92  * relocate_code(addr_moni). Trick here is that we'll return
  93  * 'here' but relocated.
  94  */
  95
  96         ldr     r0, [r9, #GD_START_ADDR_SP]     /* sp = gd->start_addr_sp */
  97         bic     r0, r0, #7      /* 8-byte alignment for ABI compliance */
  98         mov     sp, r0
  99         ldr     r9, [r9, #GD_BD]                /* r9 = gd->bd */
 100         sub     r9, r9, #GD_SIZE                /* new GD is below bd */
 101
 102         adr     lr, here
 103         ldr     r0, [r9, #GD_RELOC_OFF]         /* r0 = gd->reloc_off */
 104         add     lr, lr, r0
 105 #if defined(CONFIG_CPU_V7M)
 106         orr     lr, #1                          /* As required by Thumb-only */
 107 #endif
 108         ldr     r0, [r9, #GD_RELOCADDR]         /* r0 = gd->relocaddr */
 109         b       relocate_code
 110 here:
 111 /*
 112  * now relocate vectors
 113  */
 114
 115         bl      relocate_vectors
 116
 117 /* Set up final (full) environment */
 118
 119         bl      c_runtime_cpu_setup     /* we still call old routine here */
 120 #endif
 121 #if !defined(CONFIG_SPL_BUILD) || defined(CONFIG_SPL_FRAMEWORK)
 122 # ifdef CONFIG_SPL_BUILD
 123         /* Use a DRAM stack for the rest of SPL, if requested */
 124         bl      spl_relocate_stack_gd
 125         cmp     r0, #0
 126         movne   sp, r0
 127         movne   r9, r0
 128 # endif
 129         ldr     r0, =__bss_start        /* this is auto-relocated! */
 130
 131 #ifdef CONFIG_USE_ARCH_MEMSET
 132         ldr     r3, =__bss_end          /* this is auto-relocated! */
 133         mov     r1, #0x00000000         /* prepare zero to clear BSS */
 134
 135         subs    r2, r3, r0              /* r2 = memset len */
 136         bl      memset
 137 #else
 138         ldr     r1, =__bss_end          /* this is auto-relocated! */
 139         mov     r2, #0x00000000         /* prepare zero to clear BSS */
 140
 141 clbss_l:cmp     r0, r1                  /* while not at end of BSS */
 142 #if defined(CONFIG_CPU_V7M)
 143         itt     lo
 144 #endif
 145         strlo   r2, [r0]                /* clear 32-bit BSS word */
 146         addlo   r0, r0, #4              /* move to next */
 147         blo     clbss_l
 148 #endif
 149
 150 #if ! defined(CONFIG_SPL_BUILD)
 151         bl coloured_LED_init
 152         bl red_led_on
 153 #endif
 154         /* call board_init_r(gd_t *id, ulong dest_addr) */
 155         mov     r0, r9                  /* gd_t */
 156         ldr     r1, [r9, #GD_RELOCADDR] /* dest_addr */
 157         /* call board_init_r */
 158 #if CONFIG_IS_ENABLED(SYS_THUMB_BUILD)
 159         ldr     lr, =board_init_r       /* this is auto-relocated! */
 160         bx      lr
 161 #else
 162         ldr     pc, =board_init_r       /* this is auto-relocated! */
 163 #endif
 164         /* we should not return here. */
 165 #endif
 166
 167 ENDPROC(_main)