git.sur5r.net Git - u-boot/blob - arch/arm/mach-at91/armv7/u-boot-spl.lds

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * (C) Copyright 2002
   4  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   5  *
   6  * (C) Copyright 2010
   7  * Texas Instruments, <www.ti.com>
   8  *      Aneesh V <aneesh@ti.com>
   9  *
  10  * (C) 2013 Atmel Corporation
  11  *          Bo Shen <voice.shen@atmel.com>
  12  */
  13
  14 MEMORY { .sram : ORIGIN = CONFIG_SPL_TEXT_BASE, \
  15                 LENGTH = CONFIG_SPL_MAX_SIZE }
  16 MEMORY { .sdram : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
  17                 LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
  18
  19 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  20 OUTPUT_ARCH(arm)
  21 ENTRY(_start)
  22 SECTIONS
  23 {
  24         .text      :
  25         {
  26                 __start = .;
  27                 *(.vectors)
  28                 arch/arm/cpu/armv7/start.o      (.text*)
  29                 *(.text*)
  30         } >.sram
  31
  32         . = ALIGN(4);
  33         .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
  34
  35         . = ALIGN(4);
  36         .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
  37
  38         . = ALIGN(4);
  39         .u_boot_list : { KEEP(*(SORT(.u_boot_list*))) } > .sram
  40
  41         . = ALIGN(4);
  42         __image_copy_end = .;
  43
  44         .end :
  45         {
  46                 *(.__end)
  47         } >.sram
  48
  49         _image_binary_end = .;
  50
  51         .bss :
  52         {
  53                 . = ALIGN(4);
  54                 __bss_start = .;
  55                 *(.bss*)
  56                 . = ALIGN(4);
  57                 __bss_end = .;
  58         } >.sdram
  59 }