git.sur5r.net Git - u-boot/blob - arch/arm/mach-omap2/u-boot-spl.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   4  *
   5  * (C) Copyright 2010
   6  * Texas Instruments, <www.ti.com>
   7  *      Aneesh V <aneesh@ti.com>
   8  *
   9  * SPDX-License-Identifier:     GPL-2.0+
  10  */
  11
  12 MEMORY { .sram : ORIGIN = CONFIG_SPL_TEXT_BASE,\
  13                 LENGTH = CONFIG_SPL_MAX_SIZE }
  14 MEMORY { .sdram : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
  15                 LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
  16
  17 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  18 OUTPUT_ARCH(arm)
  19 ENTRY(_start)
  20 SECTIONS
  21 {
  22         .text      :
  23         {
  24                 __start = .;
  25                 *(.vectors)
  26                 arch/arm/cpu/armv7/start.o      (.text*)
  27                 *(.text*)
  28         } >.sram
  29
  30         . = ALIGN(4);
  31         .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
  32
  33         . = ALIGN(4);
  34         .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
  35
  36         . = ALIGN(4);
  37         .u_boot_list : {
  38                 KEEP(*(SORT(.u_boot_list*)));
  39         } >.sram
  40
  41         . = ALIGN(4);
  42         __image_copy_end = .;
  43
  44         .end :
  45         {
  46                 *(.__end)
  47         }
  48
  49         _image_binary_end = .;
  50
  51         .bss :
  52         {
  53                 . = ALIGN(4);
  54                 __bss_start = .;
  55                 *(.bss*)
  56                 . = ALIGN(4);
  57                 __bss_end = .;
  58         } >.sdram
  59 }