]> git.sur5r.net Git - u-boot/blob - arch/m68k/cpu/mcf532x/start.S
Merge branch 'master' of git://git.denx.de/u-boot-mpc85xx
[u-boot] / arch / m68k / cpu / mcf532x / start.S
1 /*
2  * Copyright (C) 2003   Josef Baumgartner <josef.baumgartner@telex.de>
3  * Based on code from Bernhard Kuhn <bkuhn@metrowerks.com>
4  *
5  * (C) Copyright 2004-2008 Freescale Semiconductor, Inc.
6  * TsiChung Liew (Tsi-Chung.Liew@freescale.com)
7  *
8  * SPDX-License-Identifier:     GPL-2.0+
9  */
10
11 #include <asm-offsets.h>
12 #include <config.h>
13 #include "version.h"
14 #include <asm/cache.h>
15
16 #ifndef  CONFIG_IDENT_STRING
17 #define  CONFIG_IDENT_STRING ""
18 #endif
19
20 #define _START  _start
21 #define _FAULT  _fault
22
23 #define SAVE_ALL                                                \
24         move.w  #0x2700,%sr;            /* disable intrs */     \
25         subl    #60,%sp;                /* space for 15 regs */ \
26         moveml  %d0-%d7/%a0-%a6,%sp@;
27
28 #define RESTORE_ALL                                             \
29         moveml  %sp@,%d0-%d7/%a0-%a6;                           \
30         addl    #60,%sp;                /* space for 15 regs */ \
31         rte;
32
33 #if !defined(CONFIG_MONITOR_IS_IN_RAM)
34 .text
35 /*
36  *      Vector table. This is used for initial platform startup.
37  *      These vectors are to catch any un-intended traps.
38  */
39 _vectors:
40
41 INITSP:         .long   0x00000000      /* Initial SP   */
42 INITPC:         .long   _START  /* Initial PC           */
43 vector02:       .long   _FAULT  /* Access Error         */
44 vector03:       .long   _FAULT  /* Address Error        */
45 vector04:       .long   _FAULT  /* Illegal Instruction  */
46 vector05:       .long   _FAULT  /* Reserved             */
47 vector06:       .long   _FAULT  /* Reserved             */
48 vector07:       .long   _FAULT  /* Reserved             */
49 vector08:       .long   _FAULT  /* Privilege Violation  */
50 vector09:       .long   _FAULT  /* Trace                */
51 vector0A:       .long   _FAULT  /* Unimplemented A-Line */
52 vector0B:       .long   _FAULT  /* Unimplemented F-Line */
53 vector0C:       .long   _FAULT  /* Debug Interrupt      */
54 vector0D:       .long   _FAULT  /* Reserved             */
55 vector0E:       .long   _FAULT  /* Format Error         */
56 vector0F:       .long   _FAULT  /* Unitialized Int.     */
57
58 /* Reserved */
59 vector10_17:
60 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
61
62 vector18:       .long   _FAULT  /* Spurious Interrupt   */
63 vector19:       .long   _FAULT  /* Autovector Level 1   */
64 vector1A:       .long   _FAULT  /* Autovector Level 2   */
65 vector1B:       .long   _FAULT  /* Autovector Level 3   */
66 vector1C:       .long   _FAULT  /* Autovector Level 4   */
67 vector1D:       .long   _FAULT  /* Autovector Level 5   */
68 vector1E:       .long   _FAULT  /* Autovector Level 6   */
69 vector1F:       .long   _FAULT  /* Autovector Level 7   */
70
71 /* TRAP #0 - #15 */
72 vector20_2F:
73 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
74 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
75
76 /* Reserved     */
77 vector30_3F:
78 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
79 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
80
81 vector64_127:
82 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
83 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
84 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
85 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
86 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
87 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
88 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
89 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
90
91 vector128_191:
92 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
93 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
94 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
95 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
96 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
97 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
98 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
99 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
100
101 vector192_255:
102 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
103 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
104 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
105 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
106 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
107 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
108 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
109 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
110 #endif /* !defined(CONFIG_MONITOR_IS_IN_RAM) */
111
112         .text
113
114         .globl  _start
115 _start:
116         nop
117         nop
118         move.w #0x2700,%sr      /* Mask off Interrupt */
119
120 #if !defined(CONFIG_MONITOR_IS_IN_RAM)
121         /* Set vector base register at the beginning of the Flash */
122         move.l  #CONFIG_SYS_FLASH_BASE, %d0
123         movec   %d0, %VBR
124 #endif
125
126         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_RAM_CTRL), %d0
127         movec   %d0, %RAMBAR1
128
129         /* invalidate and disable cache */
130         move.l  #CF_CACR_CINVA, %d0             /* Invalidate cache cmd */
131         movec   %d0, %CACR                      /* Invalidate cache */
132         move.l  #0, %d0
133         movec   %d0, %ACR0
134         movec   %d0, %ACR1
135
136 #ifdef CONFIG_MCF5301x
137         move.l  #(0xFC0a0010), %a0
138         move.w  (%a0), %d0
139         and.l   %d0, 0xEFFF
140
141         move.w  %d0, (%a0)
142 #endif
143
144         /* initialize general use internal ram */
145         move.l #0, %d0
146         move.l #(ICACHE_STATUS), %a1    /* icache */
147         move.l #(DCACHE_STATUS), %a2    /* icache */
148         move.l %d0, (%a1)
149         move.l %d0, (%a2)
150
151         /* put relocation table address to a5 */
152         move.l #__got_start, %a5
153
154         /* setup stack initially on top of internal static ram  */
155         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_RAM_SIZE), %sp
156
157         /*
158          * if configured, malloc_f arena will be reserved first,
159          * then (and always) gd struct space will be reserved
160          */
161         move.l  %sp, -(%sp)
162         move.l  #board_init_f_alloc_reserve, %a1
163         jsr     (%a1)
164
165         /* update stack and frame-pointers */
166         move.l  %d0, %sp
167         move.l  %sp, %fp
168
169         /* initialize reserved area */
170         move.l  %d0, -(%sp)
171         move.l  #board_init_f_init_reserve, %a1
172         jsr     (%a1)
173
174         /* run low-level CPU init code (from flash) */
175         move.l #cpu_init_f, %a1
176         jsr (%a1)
177         /* run low-level board init code (from flash) */
178         clr.l   %sp@-
179         move.l #board_init_f, %a1
180         jsr (%a1)
181
182         /* board_init_f() does not return */
183
184 /*------------------------------------------------------------------------------*/
185
186 /*
187  * void relocate_code (addr_sp, gd, addr_moni)
188  *
189  * This "function" does not return, instead it continues in RAM
190  * after relocating the monitor code.
191  *
192  * r3 = dest
193  * r4 = src
194  * r5 = length in bytes
195  * r6 = cachelinesize
196  */
197         .globl  relocate_code
198 relocate_code:
199         link.w %a6,#0
200         move.l 8(%a6), %sp              /* set new stack pointer */
201
202         move.l 12(%a6), %d0             /* Save copy of Global Data pointer */
203         move.l 16(%a6), %a0             /* Save copy of Destination Address */
204
205         move.l #CONFIG_SYS_MONITOR_BASE, %a1
206         move.l #__init_end, %a2
207         move.l %a0, %a3
208
209         /* copy the code to RAM */
210 1:
211         move.l (%a1)+, (%a3)+
212         cmp.l  %a1,%a2
213         bgt.s    1b
214
215 /*
216  * We are done. Do not return, instead branch to second part of board
217  * initialization, now running from RAM.
218  */
219         move.l  %a0, %a1
220         add.l   #(in_ram - CONFIG_SYS_MONITOR_BASE), %a1
221         jmp     (%a1)
222
223 in_ram:
224
225 clear_bss:
226         /*
227          * Now clear BSS segment
228          */
229         move.l  %a0, %a1
230         add.l   #(_sbss - CONFIG_SYS_MONITOR_BASE),%a1
231         move.l  %a0, %d1
232         add.l   #(_ebss - CONFIG_SYS_MONITOR_BASE),%d1
233 6:
234         clr.l   (%a1)+
235         cmp.l   %a1,%d1
236         bgt.s   6b
237
238         /*
239          * fix got table in RAM
240          */
241         move.l  %a0, %a1
242         add.l   #(__got_start - CONFIG_SYS_MONITOR_BASE),%a1
243         move.l  %a1,%a5         /* * fix got pointer register a5 */
244
245         move.l  %a0, %a2
246         add.l   #(__got_end - CONFIG_SYS_MONITOR_BASE),%a2
247
248 7:
249         move.l  (%a1),%d1
250         sub.l   #_start,%d1
251         add.l   %a0,%d1
252         move.l  %d1,(%a1)+
253         cmp.l   %a2, %a1
254         bne     7b
255
256         /* calculate relative jump to board_init_r in ram */
257         move.l %a0, %a1
258         add.l #(board_init_r - CONFIG_SYS_MONITOR_BASE), %a1
259
260         /* set parameters for board_init_r */
261         move.l %a0,-(%sp)               /* dest_addr */
262         move.l %d0,-(%sp)               /* gd */
263         jsr     (%a1)
264
265 /*------------------------------------------------------------------------------*/
266 /* exception code */
267         .globl _fault
268 _fault:
269         bra _fault
270         .globl  _exc_handler
271
272 _exc_handler:
273         SAVE_ALL
274         movel   %sp,%sp@-
275         bsr exc_handler
276         addql   #4,%sp
277         RESTORE_ALL
278
279         .globl  _int_handler
280 _int_handler:
281         SAVE_ALL
282         movel   %sp,%sp@-
283         bsr int_handler
284         addql   #4,%sp
285         RESTORE_ALL
286
287 /*------------------------------------------------------------------------------*/
288         .globl  version_string
289 version_string:
290         .ascii U_BOOT_VERSION_STRING, "\0"
291         .align 4