git.sur5r.net Git - u-boot/blob - arch/mips/cpu/mips64/start.S

   1 /*
   2  *  Startup Code for MIPS64 CPU-core
   3  *
   4  *  Copyright (c) 2003  Wolfgang Denk <wd@denx.de>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any dlater version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICUdlaR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Pdlace, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 #include <asm-offsets.h>
  26 #include <config.h>
  27 #include <asm/regdef.h>
  28 #include <asm/mipsregs.h>
  29
  30 #ifndef CONFIG_SYS_MIPS_CACHE_MODE
  31 #define CONFIG_SYS_MIPS_CACHE_MODE CONF_CM_CACHABLE_NONCOHERENT
  32 #endif
  33
  34         /*
  35          * For the moment disable interrupts, mark the kernel mode and
  36          * set ST0_KX so that the CPU does not spit fire when using
  37          * 64-bit addresses.
  38          */
  39         .macro  setup_c0_status set clr
  40         .set    push
  41         mfc0    t0, CP0_STATUS
  42         or      t0, ST0_CU0 | \set | 0x1f | \clr
  43         xor     t0, 0x1f | \clr
  44         mtc0    t0, CP0_STATUS
  45         .set    noreorder
  46         sll     zero, 3                         # ehb
  47         .set    pop
  48         .endm
  49
  50         .set noreorder
  51
  52         .globl _start
  53         .text
  54 _start:
  55         /* U-boot entry point */
  56         b       reset
  57          nop
  58
  59         .org 0x200
  60         /* TLB refill, 32 bit task */
  61 1:      b       1b
  62          nop
  63
  64         .org 0x280
  65         /* XTLB refill, 64 bit task */
  66 1:      b       1b
  67          nop
  68
  69         .org 0x300
  70         /* Cache error exception */
  71 1:      b       1b
  72          nop
  73
  74         .org 0x380
  75         /* General exception */
  76 1:      b       1b
  77          nop
  78
  79         .org 0x400
  80         /* Catch interrupt exceptions */
  81 1:      b       1b
  82          nop
  83
  84         .org 0x480
  85         /* EJTAG debug exception */
  86 1:      b       1b
  87          nop
  88
  89         .align 4
  90 reset:
  91
  92         /* Clear watch registers */
  93         dmtc0   zero, CP0_WATCHLO
  94         dmtc0   zero, CP0_WATCHHI
  95
  96         /* WP(Watch Pending), SW0/1 should be cleared */
  97         mtc0    zero, CP0_CAUSE
  98
  99         setup_c0_status ST0_KX 0
 100
 101         /* Init Timer */
 102         mtc0    zero, CP0_COUNT
 103         mtc0    zero, CP0_COMPARE
 104
 105 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 106         /* CONFIG0 register */
 107         dli     t0, CONF_CM_UNCACHED
 108         mtc0    t0, CP0_CONFIG
 109 #endif
 110
 111         /*
 112          * Initialize $gp, force 8 byte alignment of bal instruction to forbid
 113          * the compiler to put nop's between bal and _gp. This is required to
 114          * keep _gp and ra aligned to 8 byte.
 115          */
 116         .align  3
 117         bal     1f
 118          nop
 119         .dword  _gp
 120 1:
 121         ld      gp, 0(ra)
 122
 123 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 124         /* Initialize any external memory */
 125         dla     t9, lowlevel_init
 126         jalr    t9
 127          nop
 128
 129         /* Initialize caches... */
 130         dla     t9, mips_cache_reset
 131         jalr    t9
 132          nop
 133
 134         /* ... and enable them */
 135         dli     t0, CONFIG_SYS_MIPS_CACHE_MODE
 136         mtc0    t0, CP0_CONFIG
 137 #endif
 138
 139         /* Set up temporary stack */
 140         dli     sp, CONFIG_SYS_SDRAM_BASE + CONFIG_SYS_INIT_SP_OFFSET
 141
 142         dla     t9, board_init_f
 143         jr      t9
 144          nop
 145
 146 /*
 147  * void relocate_code (addr_sp, gd, addr_moni)
 148  *
 149  * This "function" does not return, instead it continues in RAM
 150  * after relocating the monitor code.
 151  *
 152  * a0 = addr_sp
 153  * a1 = gd
 154  * a2 = destination address
 155  */
 156         .globl  relocate_code
 157         .ent    relocate_code
 158 relocate_code:
 159         move    sp, a0                  # set new stack pointer
 160
 161         move    s0, a1                  # save gd in s0
 162         move    s2, a2                  # save destination address in s2
 163
 164         dli     t0, CONFIG_SYS_MONITOR_BASE
 165         dsub    s1, s2, t0              # s1 <-- relocation offset
 166
 167         dla     t3, in_ram
 168         ld      t2, -24(t3)             # t2 <-- uboot_end_data
 169         move    t1, a2
 170
 171         dadd    gp, s1                  # adjust gp
 172
 173         /*
 174          * t0 = source address
 175          * t1 = target address
 176          * t2 = source end address
 177          */
 178 1:
 179         lw      t3, 0(t0)
 180         sw      t3, 0(t1)
 181         daddu   t0, 4
 182         blt     t0, t2, 1b
 183          daddu  t1, 4
 184
 185         /* If caches were enabled, we would have to flush them here. */
 186         dsub    a1, t1, s2              # a1 <-- size
 187         dla     t9, flush_cache
 188         jalr    t9
 189          move   a0, s2                  # a0 <-- destination address
 190
 191         /* Jump to where we've relocated ourselves */
 192         daddi   t0, s2, in_ram - _start
 193         jr      t0
 194          nop
 195
 196         .dword  _GLOBAL_OFFSET_TABLE_
 197         .dword  uboot_end_data
 198         .dword  uboot_end
 199         .dword  num_got_entries
 200
 201 in_ram:
 202         /*
 203          * Now we want to update GOT.
 204          *
 205          * GOT[0] is reserved. GOT[1] is also reserved for the dynamic object
 206          * generated by GNU ld. Skip these reserved entries from relocation.
 207          */
 208         ld      t3, -8(t0)              # t3 <-- num_got_entries
 209         ld      t8, -32(t0)             # t8 <-- _GLOBAL_OFFSET_TABLE_
 210         dadd    t8, s1                  # t8 now holds relocated _G_O_T_
 211         daddi   t8, t8, 16              # skipping first two entries
 212         dli     t2, 2
 213 1:
 214         ld      t1, 0(t8)
 215         beqz    t1, 2f
 216          dadd   t1, s1
 217         sd      t1, 0(t8)
 218 2:
 219         daddi   t2, 1
 220         blt     t2, t3, 1b
 221          daddi  t8, 8
 222
 223         /* Clear BSS */
 224         ld      t1, -24(t0)             # t1 <-- uboot_end_data
 225         ld      t2, -16(t0)             # t2 <-- uboot_end
 226         dadd    t1, s1                  # adjust pointers
 227         dadd    t2, s1
 228
 229         dsub    t1, 8
 230 1:
 231         daddi   t1, 8
 232         bltl    t1, t2, 1b
 233          sd     zero, 0(t1)
 234
 235         move    a0, s0                  # a0 <-- gd
 236         dla     t9, board_init_r
 237         jr      t9
 238          move   a1, s2
 239
 240         .end    relocate_code