git.sur5r.net Git - u-boot/blob - arch/powerpc/cpu/mpc83xx/u-boot.lds

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * (C) Copyright 2006-2010
   4  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   5  */
   6
   7 OUTPUT_ARCH(powerpc)
   8 SECTIONS
   9 {
  10   /* Read-only sections, merged into text segment: */
  11   .text      :
  12   {
  13     arch/powerpc/cpu/mpc83xx/start.o    (.text*)
  14     *(.text*)
  15     . = ALIGN(16);
  16     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  17   }
  18
  19   /* Read-write section, merged into data segment: */
  20   . = (. + 0x0FFF) & 0xFFFFF000;
  21   _erotext = .;
  22   PROVIDE (erotext = .);
  23   .reloc   :
  24   {
  25     _GOT2_TABLE_ = .;
  26     KEEP(*(.got2))
  27     KEEP(*(.got))
  28     _FIXUP_TABLE_ = .;
  29     KEEP(*(.fixup))
  30   }
  31   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  32   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  33
  34   .data    :
  35   {
  36     *(.data*)
  37     *(.sdata*)
  38   }
  39   _edata  =  .;
  40   PROVIDE (edata = .);
  41
  42   . = .;
  43
  44   . = ALIGN(4);
  45   .u_boot_list : {
  46         KEEP(*(SORT(.u_boot_list*)));
  47   }
  48
  49
  50   . = .;
  51   __start___ex_table = .;
  52   __ex_table : { *(__ex_table) }
  53   __stop___ex_table = .;
  54
  55   . = ALIGN(4096);
  56   __init_begin = .;
  57   .text.init : { *(.text.init) }
  58   .data.init : { *(.data.init) }
  59   . = ALIGN(4096);
  60   __init_end = .;
  61
  62   __bss_start = .;
  63   .bss (NOLOAD)       :
  64   {
  65    *(.bss*)
  66    *(.sbss*)
  67    *(COMMON)
  68    . = ALIGN(4);
  69   }
  70   __bss_end = . ;
  71   PROVIDE (end = .);
  72 }
  73 ENTRY(_start)