git.sur5r.net Git - u-boot/blob - arch/powerpc/cpu/mpc85xx/u-boot.lds

   1 /*
   2  * Copyright 2007-2009, 2011 Freescale Semiconductor, Inc.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 #include "config.h"     /* CONFIG_BOARDDIR */
  24
  25 #ifdef CONFIG_RESET_VECTOR_ADDRESS
  26 #define RESET_VECTOR_ADDRESS    CONFIG_RESET_VECTOR_ADDRESS
  27 #else
  28 #define RESET_VECTOR_ADDRESS    0xfffffffc
  29 #endif
  30
  31 OUTPUT_ARCH(powerpc)
  32
  33 PHDRS
  34 {
  35   text PT_LOAD;
  36   bss PT_LOAD;
  37 }
  38
  39 SECTIONS
  40 {
  41   /* Read-only sections, merged into text segment: */
  42   . = + SIZEOF_HEADERS;
  43   .interp : { *(.interp) }
  44   .text      :
  45   {
  46     *(.text*)
  47    } :text
  48     _etext = .;
  49     PROVIDE (etext = .);
  50     .rodata    :
  51    {
  52     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  53   } :text
  54
  55   /* Read-write section, merged into data segment: */
  56   . = (. + 0x00FF) & 0xFFFFFF00;
  57   _erotext = .;
  58   PROVIDE (erotext = .);
  59   .reloc   :
  60   {
  61     _GOT2_TABLE_ = .;
  62     KEEP(*(.got2))
  63     KEEP(*(.got))
  64     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  65     _FIXUP_TABLE_ = .;
  66     KEEP(*(.fixup))
  67   }
  68   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  69   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  70
  71   .data    :
  72   {
  73     *(.data*)
  74     *(.sdata*)
  75   }
  76   _edata  =  .;
  77   PROVIDE (edata = .);
  78
  79   . = .;
  80   __u_boot_cmd_start = .;
  81   .u_boot_cmd : { *(.u_boot_cmd) }
  82   __u_boot_cmd_end = .;
  83
  84   . = ALIGN(4);
  85   .u_boot_list : {
  86         #include <u-boot.lst>
  87   }
  88
  89   . = .;
  90   __start___ex_table = .;
  91   __ex_table : { *(__ex_table) }
  92   __stop___ex_table = .;
  93
  94   . = ALIGN(256);
  95   __init_begin = .;
  96   .text.init : { *(.text.init) }
  97   .data.init : { *(.data.init) }
  98   . = ALIGN(256);
  99   __init_end = .;
 100
 101   .bootpg RESET_VECTOR_ADDRESS - 0xffc :
 102   {
 103     arch/powerpc/cpu/mpc85xx/start.o    (.bootpg)
 104   } :text = 0xffff
 105
 106   .resetvec RESET_VECTOR_ADDRESS :
 107   {
 108     KEEP(*(.resetvec))
 109   } :text = 0xffff
 110
 111   . = RESET_VECTOR_ADDRESS + 0x4;
 112
 113   /*
 114    * Make sure that the bss segment isn't linked at 0x0, otherwise its
 115    * address won't be updated during relocation fixups.  Note that
 116    * this is a temporary fix.  Code to dynamically the fixup the bss
 117    * location will be added in the future.  When the bss relocation
 118    * fixup code is present this workaround should be removed.
 119    */
 120 #if (RESET_VECTOR_ADDRESS == 0xfffffffc)
 121   . |= 0x10;
 122 #endif
 123
 124   __bss_start = .;
 125   .bss (NOLOAD)       :
 126   {
 127    *(.sbss*)
 128    *(.bss*)
 129    *(COMMON)
 130   } :bss
 131
 132   . = ALIGN(4);
 133   __bss_end__ = . ;
 134   PROVIDE (end = .);
 135 }