git.sur5r.net Git - u-boot/blob - arch/x86/cpu/u-boot-64.lds

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * (C) Copyright 2002
   4  * Daniel Engström, Omicron Ceti AB, daniel@omicron.se.
   5  */
   6
   7 #include <config.h>
   8 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
   9 OUTPUT_ARCH(i386:x86-64)
  10 ENTRY(_start)
  11
  12 SECTIONS
  13 {
  14 #ifndef CONFIG_CMDLINE
  15         /DISCARD/ : { *(.u_boot_list_2_cmd_*) }
  16 #endif
  17
  18         . = CONFIG_SYS_TEXT_BASE;       /* Location of bootcode in flash */
  19         __text_start = .;
  20         .text  : { *(.text*); }
  21
  22         . = ALIGN(4);
  23
  24         . = ALIGN(4);
  25         .u_boot_list : {
  26                 KEEP(*(SORT(.u_boot_list*)));
  27         }
  28
  29         . = ALIGN(4);
  30         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  31
  32         . = ALIGN(4);
  33         .data : { *(.data*) }
  34
  35         . = ALIGN(4);
  36         .hash : { *(.hash*) }
  37
  38         . = ALIGN(4);
  39         .got : { *(.got*) }
  40
  41         . = ALIGN(4);
  42         __data_end = .;
  43         __init_end = .;
  44
  45         . = ALIGN(4);
  46         .dynsym : { *(.dynsym*) }
  47
  48         . = ALIGN(4);
  49         __rel_dyn_start = .;
  50         .rela.dyn : {
  51                 *(.rela*)
  52         }
  53         __rel_dyn_end = .;
  54         . = ALIGN(4);
  55
  56         .dynamic : { *(.dynamic) }
  57
  58         . = ALIGN(4);
  59         _end = .;
  60
  61         .bss __rel_dyn_start (OVERLAY) : {
  62                 __bss_start = .;
  63                 *(.bss)
  64                 *(COM*)
  65                 . = ALIGN(4);
  66                 __bss_end = .;
  67         }
  68
  69         /DISCARD/ : { *(.dynsym) }
  70         /DISCARD/ : { *(.dynstr*) }
  71         /DISCARD/ : { *(.dynamic*) }
  72         /DISCARD/ : { *(.plt*) }
  73         /DISCARD/ : { *(.interp*) }
  74         /DISCARD/ : { *(.gnu*) }
  75 }