git.sur5r.net Git - u-boot/blob - board/LEOX/elpt860/u-boot.lds

   1 /*
   2 **=====================================================================
   3 **
   4 ** Copyright (C) 2000, 2001, 2002, 2003
   5 ** The LEOX team <team@leox.org>, http://www.leox.org
   6 **
   7 ** LEOX.org is about the development of free hardware and software resources
   8 **   for system on chip.
   9 **
  10 ** Description: U-Boot port on the LEOX's ELPT860 CPU board
  11 ** ~~~~~~~~~~~
  12 **
  13 **=====================================================================
  14 **
  15 ** This program is free software; you can redistribute it and/or
  16 ** modify it under the terms of the GNU General Public License as
  17 ** published by the Free Software Foundation; either version 2 of
  18 ** the License, or (at your option) any later version.
  19 **
  20 ** This program is distributed in the hope that it will be useful,
  21 ** but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ** MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ** GNU General Public License for more details.
  24 **
  25 ** You should have received a copy of the GNU General Public License
  26 ** along with this program; if not, write to the Free Software
  27 ** Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  28 ** MA 02111-1307 USA
  29 **
  30 **=====================================================================
  31 */
  32
  33 OUTPUT_ARCH(powerpc)
  34 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  35 /* Do we need any of these for elf?
  36    __DYNAMIC = 0;    */
  37 SECTIONS
  38 {
  39   /* Read-only sections, merged into text segment: */
  40   . = + SIZEOF_HEADERS;
  41   .interp : { *(.interp) }
  42   .hash          : { *(.hash)           }
  43   .dynsym        : { *(.dynsym)         }
  44   .dynstr        : { *(.dynstr)         }
  45   .rel.text      : { *(.rel.text)               }
  46   .rela.text     : { *(.rela.text)      }
  47   .rel.data      : { *(.rel.data)               }
  48   .rela.data     : { *(.rela.data)      }
  49   .rel.rodata    : { *(.rel.rodata)     }
  50   .rela.rodata   : { *(.rela.rodata)    }
  51   .rel.got       : { *(.rel.got)                }
  52   .rela.got      : { *(.rela.got)               }
  53   .rel.ctors     : { *(.rel.ctors)      }
  54   .rela.ctors    : { *(.rela.ctors)     }
  55   .rel.dtors     : { *(.rel.dtors)      }
  56   .rela.dtors    : { *(.rela.dtors)     }
  57   .rel.bss       : { *(.rel.bss)                }
  58   .rela.bss      : { *(.rela.bss)               }
  59   .rel.plt       : { *(.rel.plt)                }
  60   .rela.plt      : { *(.rela.plt)               }
  61   .init          : { *(.init)   }
  62   .plt : { *(.plt) }
  63   .text      :
  64   {
  65     /* WARNING - the following is hand-optimized to fit within  */
  66     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  67
  68     cpu/mpc8xx/start.o                  (.text)
  69     common/dlmalloc.o                   (.text)
  70     lib_ppc/ppcstring.o                 (.text)
  71     lib_generic/vsprintf.o              (.text)
  72     lib_generic/crc32.o                 (.text)
  73     lib_generic/zlib.o                  (.text)
  74     lib_generic/string.o                (.text)
  75     lib_ppc/cache.o                     (.text)
  76     lib_ppc/extable.o                   (.text)
  77     lib_ppc/time.o                      (.text)
  78     lib_ppc/ticks.o                     (.text)
  79
  80     . = env_offset;
  81     common/environment.o                (.text)
  82
  83     *(.text)
  84     *(.fixup)
  85     *(.got1)
  86   }
  87   _etext = .;
  88   PROVIDE (etext = .);
  89   .rodata    :
  90   {
  91     *(.rodata)
  92     *(.rodata1)
  93   }
  94   .fini      : { *(.fini)    } =0
  95   .ctors     : { *(.ctors)   }
  96   .dtors     : { *(.dtors)   }
  97
  98   /* Read-write section, merged into data segment: */
  99   . = (. + 0x00FF) & 0xFFFFFF00;
 100   _erotext = .;
 101   PROVIDE (erotext = .);
 102   .reloc   :
 103   {
 104     *(.got)
 105     _GOT2_TABLE_ = .;
 106     *(.got2)
 107     _FIXUP_TABLE_ = .;
 108     *(.fixup)
 109   }
 110   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 111   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 112
 113   .data    :
 114   {
 115     *(.data)
 116     *(.data1)
 117     *(.sdata)
 118     *(.sdata2)
 119     *(.dynamic)
 120     CONSTRUCTORS
 121   }
 122   _edata  =  .;
 123   PROVIDE (edata = .);
 124
 125   __start___ex_table = .;
 126   __ex_table : { *(__ex_table) }
 127   __stop___ex_table = .;
 128
 129   . = ALIGN(256);
 130   __init_begin = .;
 131   .text.init : { *(.text.init) }
 132   .data.init : { *(.data.init) }
 133   . = ALIGN(256);
 134   __init_end = .;
 135
 136   __bss_start = .;
 137   .bss       :
 138   {
 139    *(.sbss) *(.scommon)
 140    *(.dynbss)
 141    *(.bss)
 142    *(COMMON)
 143   }
 144   _end = . ;
 145   PROVIDE (end = .);
 146 }