git.sur5r.net Git - u-boot/blob - board/altera/ep1s10/u-boot.lds

   1 /*
   2  * (C) Copyright 2004, Psyent Corporation <www.psyent.com>
   3  * Scott McNutt <smcnutt@psyent.com>
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24
  25 OUTPUT_FORMAT("elf32-littlenios2")
  26 OUTPUT_ARCH(nios2)
  27 ENTRY(_start)
  28
  29 SECTIONS
  30 {
  31         .text :
  32         {
  33           cpu/nios2/start.o (.text)
  34           *(.text)
  35           *(.text.*)
  36           *(.gnu.linkonce.t*)
  37           *(.rodata)
  38           *(.rodata.*)
  39           *(.gnu.linkonce.r*)
  40         }
  41         . = ALIGN (4);
  42         _etext = .;
  43         PROVIDE (etext = .);
  44
  45         /* CMD TABLE - sandwich this in between text and data so
  46          * the initialization code relocates the command table as
  47          * well -- admittedly, this is just pure laziness ;-)
  48          */
  49         __u_boot_cmd_start = .;
  50         .u_boot_cmd :
  51         {
  52           *(.u_boot_cmd)
  53         }
  54         . = ALIGN(4);
  55         __u_boot_cmd_end = .;
  56
  57         /* INIT DATA sections - "Small" data (see the gcc -G option)
  58          * is always gp-relative. Here we make all init data sections
  59          * adjacent to simplify the startup code -- and provide
  60          * the global pointer for gp-relative access.
  61          */
  62         _data = .;
  63         .data :
  64         {
  65           *(.data)
  66           *(.data.*)
  67           *(.gnu.linkonce.d*)
  68         }
  69
  70         . = ALIGN(16);
  71         _gp = .;                        /* Global pointer addr */
  72         PROVIDE (gp = .);
  73
  74         .sdata :
  75         {
  76           *(.sdata)
  77           *(.sdata.*)
  78           *(.gnu.linkonce.s.*)
  79         }
  80         . = ALIGN(4);
  81
  82         _edata = .;
  83         PROVIDE (edata = .);
  84
  85         /* UNINIT DATA - Small uninitialized data is first so it's
  86          * adjacent to sdata and can be referenced via gp. The normal
  87          * bss follows. We keep it adjacent to simplify init code.
  88          */
  89         __bss_start = .;
  90         .sbss :
  91         {
  92           *(.sbss)
  93           *(.sbss.*)
  94           *(.gnu.linkonce.sb.*)
  95           *(.scommon)
  96         }
  97         . = ALIGN(4);
  98         .bss :
  99         {
 100           *(.bss)
 101           *(.bss.*)
 102           *(.dynbss)
 103           *(COMMON)
 104           *(.scommon)
 105         }
 106         . = ALIGN(4);
 107         _end = .;
 108         PROVIDE (end = .);
 109
 110         /* DEBUG -- symbol table, string table, etc. etc.
 111          */
 112         .stab 0 : { *(.stab) }
 113         .stabstr 0 : { *(.stabstr) }
 114         .stab.excl 0 : { *(.stab.excl) }
 115         .stab.exclstr 0 : { *(.stab.exclstr) }
 116         .stab.index 0 : { *(.stab.index) }
 117         .stab.indexstr 0 : { *(.stab.indexstr) }
 118         .comment 0 : { *(.comment) }
 119         .debug          0 : { *(.debug) }
 120         .line           0 : { *(.line) }
 121         .debug_srcinfo  0 : { *(.debug_srcinfo) }
 122         .debug_sfnames  0 : { *(.debug_sfnames) }
 123         .debug_aranges  0 : { *(.debug_aranges) }
 124         .debug_pubnames 0 : { *(.debug_pubnames) }
 125         .debug_info     0 : { *(.debug_info) }
 126         .debug_abbrev   0 : { *(.debug_abbrev) }
 127         .debug_line     0 : { *(.debug_line) }
 128         .debug_frame    0 : { *(.debug_frame) }
 129         .debug_str      0 : { *(.debug_str) }
 130         .debug_loc      0 : { *(.debug_loc) }
 131         .debug_macinfo  0 : { *(.debug_macinfo) }
 132         .debug_weaknames 0 : { *(.debug_weaknames) }
 133         .debug_funcnames 0 : { *(.debug_funcnames) }
 134         .debug_typenames 0 : { *(.debug_typenames) }
 135         .debug_varnames  0 : { *(.debug_varnames) }
 136 }