git.sur5r.net Git - u-boot/blob - board/altera/ep1s10/u-boot.lds

   1 /*
   2  * (C) Copyright 2004, Psyent Corporation <www.psyent.com>
   3  * Scott McNutt <smcnutt@psyent.com>
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24
  25 OUTPUT_FORMAT("elf32-littlenios2")
  26 OUTPUT_ARCH(nios2)
  27 ENTRY(_start)
  28
  29 SECTIONS
  30 {
  31         .text :
  32         {
  33           cpu/nios2/start.o (.text)
  34           *(.text)
  35           *(.text.*)
  36           *(.gnu.linkonce.t*)
  37           *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  38           *(.gnu.linkonce.r*)
  39         }
  40         . = ALIGN (4);
  41         _etext = .;
  42         PROVIDE (etext = .);
  43
  44         /* CMD TABLE - sandwich this in between text and data so
  45          * the initialization code relocates the command table as
  46          * well -- admittedly, this is just pure laziness ;-)
  47          */
  48         __u_boot_cmd_start = .;
  49         .u_boot_cmd :
  50         {
  51           *(.u_boot_cmd)
  52         }
  53         . = ALIGN(4);
  54         __u_boot_cmd_end = .;
  55
  56         /* INIT DATA sections - "Small" data (see the gcc -G option)
  57          * is always gp-relative. Here we make all init data sections
  58          * adjacent to simplify the startup code -- and provide
  59          * the global pointer for gp-relative access.
  60          */
  61         _data = .;
  62         .data :
  63         {
  64           *(.data)
  65           *(.data.*)
  66           *(.gnu.linkonce.d*)
  67         }
  68
  69         . = ALIGN(16);
  70         _gp = .;                        /* Global pointer addr */
  71         PROVIDE (gp = .);
  72
  73         .sdata :
  74         {
  75           *(.sdata)
  76           *(.sdata.*)
  77           *(.gnu.linkonce.s.*)
  78         }
  79         . = ALIGN(4);
  80
  81         _edata = .;
  82         PROVIDE (edata = .);
  83
  84         /* UNINIT DATA - Small uninitialized data is first so it's
  85          * adjacent to sdata and can be referenced via gp. The normal
  86          * bss follows. We keep it adjacent to simplify init code.
  87          */
  88         __bss_start = .;
  89         .sbss (NOLOAD) :
  90         {
  91           *(.sbss)
  92           *(.sbss.*)
  93           *(.gnu.linkonce.sb.*)
  94           *(.scommon)
  95         }
  96         . = ALIGN(4);
  97         .bss (NOLOAD) :
  98         {
  99           *(.bss)
 100           *(.bss.*)
 101           *(.dynbss)
 102           *(COMMON)
 103           *(.scommon)
 104         }
 105         . = ALIGN(4);
 106         _end = .;
 107         PROVIDE (end = .);
 108
 109         /* DEBUG -- symbol table, string table, etc. etc.
 110          */
 111         .stab 0 : { *(.stab) }
 112         .stabstr 0 : { *(.stabstr) }
 113         .stab.excl 0 : { *(.stab.excl) }
 114         .stab.exclstr 0 : { *(.stab.exclstr) }
 115         .stab.index 0 : { *(.stab.index) }
 116         .stab.indexstr 0 : { *(.stab.indexstr) }
 117         .comment 0 : { *(.comment) }
 118         .debug          0 : { *(.debug) }
 119         .line           0 : { *(.line) }
 120         .debug_srcinfo  0 : { *(.debug_srcinfo) }
 121         .debug_sfnames  0 : { *(.debug_sfnames) }
 122         .debug_aranges  0 : { *(.debug_aranges) }
 123         .debug_pubnames 0 : { *(.debug_pubnames) }
 124         .debug_info     0 : { *(.debug_info) }
 125         .debug_abbrev   0 : { *(.debug_abbrev) }
 126         .debug_line     0 : { *(.debug_line) }
 127         .debug_frame    0 : { *(.debug_frame) }
 128         .debug_str      0 : { *(.debug_str) }
 129         .debug_loc      0 : { *(.debug_loc) }
 130         .debug_macinfo  0 : { *(.debug_macinfo) }
 131         .debug_weaknames 0 : { *(.debug_weaknames) }
 132         .debug_funcnames 0 : { *(.debug_funcnames) }
 133         .debug_typenames 0 : { *(.debug_typenames) }
 134         .debug_varnames  0 : { *(.debug_varnames) }
 135 }