git.sur5r.net Git - u-boot/blob - board/bf537-stamp/u-boot.lds.S

   1 /*
   2  * U-boot - u-boot.lds.S
   3  *
   4  * Copyright (c) 2005-2008 Analog Device Inc.
   5  *
   6  * (C) Copyright 2000-2004
   7  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   8  *
   9  * See file CREDITS for list of people who contributed to this
  10  * project.
  11  *
  12  * This program is free software; you can redistribute it and/or
  13  * modify it under the terms of the GNU General Public License as
  14  * published by the Free Software Foundation; either version 2 of
  15  * the License, or (at your option) any later version.
  16  *
  17  * This program is distributed in the hope that it will be useful,
  18  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  19  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20  * GNU General Public License for more details.
  21  *
  22  * You should have received a copy of the GNU General Public License
  23  * along with this program; if not, write to the Free Software
  24  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  25  * MA 02111-1307 USA
  26  */
  27
  28 #include <config.h>
  29 #include <asm/blackfin.h>
  30 #undef ALIGN
  31
  32 /* If we don't actually load anything into L1 data, this will avoid
  33  * a syntax error.  If we do actually load something into L1 data,
  34  * we'll get a linker memory load error (which is what we'd want).
  35  * This is here in the first place so we can quickly test building
  36  * for different CPU's which may lack non-cache L1 data.
  37  */
  38 #ifndef L1_DATA_B_SRAM
  39 # define L1_DATA_B_SRAM      CONFIG_SYS_MONITOR_BASE
  40 # define L1_DATA_B_SRAM_SIZE 0
  41 #endif
  42
  43 OUTPUT_ARCH(bfin)
  44
  45 /* The 0xC offset is so we don't clobber the tiny LDR jump block. */
  46 MEMORY
  47 {
  48         ram     : ORIGIN = CONFIG_SYS_MONITOR_BASE, LENGTH = CONFIG_SYS_MONITOR_LEN
  49         l1_code : ORIGIN = L1_INST_SRAM+0xC, LENGTH = L1_INST_SRAM_SIZE
  50         l1_data : ORIGIN = L1_DATA_B_SRAM,   LENGTH = L1_DATA_B_SRAM_SIZE
  51 }
  52
  53 SECTIONS
  54 {
  55         .text :
  56         {
  57                 cpu/blackfin/start.o (.text)
  58
  59 #ifdef ENV_IS_EMBEDDED
  60                 /* WARNING - the following is hand-optimized to fit within
  61                  * the sector before the environment sector. If it throws
  62                  * an error during compilation remove an object here to get
  63                  * it linked after the configuration sector.
  64                  */
  65
  66                 cpu/blackfin/traps.o            (.text)
  67                 cpu/blackfin/interrupt.o        (.text)
  68                 cpu/blackfin/serial.o           (.text)
  69                 common/dlmalloc.o               (.text)
  70                 lib_generic/crc32.o             (.text)
  71
  72                 . = DEFINED(env_offset) ? env_offset : .;
  73                 common/env_embedded.o   (.text)
  74 #endif
  75
  76                 __initcode_start = .;
  77                 cpu/blackfin/initcode.o (.text)
  78                 __initcode_end = .;
  79
  80                 *(.text .text.*)
  81         } >ram
  82
  83         .rodata :
  84         {
  85                 . = ALIGN(4);
  86                 *(.rodata .rodata.*)
  87                 *(.rodata1)
  88                 *(.eh_frame)
  89                 . = ALIGN(4);
  90         } >ram
  91
  92         .data :
  93         {
  94                 . = ALIGN(256);
  95                 *(.data .data.*)
  96                 *(.data1)
  97                 *(.sdata)
  98                 *(.sdata2)
  99                 *(.dynamic)
 100                 CONSTRUCTORS
 101         } >ram
 102
 103         .u_boot_cmd :
 104         {
 105                 ___u_boot_cmd_start = .;
 106                 *(.u_boot_cmd)
 107                 ___u_boot_cmd_end = .;
 108         } >ram
 109
 110         .text_l1 :
 111         {
 112                 . = ALIGN(4);
 113                 __stext_l1 = .;
 114                 *(.l1.text)
 115                 . = ALIGN(4);
 116                 __etext_l1 = .;
 117         } >l1_code AT>ram
 118         __stext_l1_lma = LOADADDR(.text_l1);
 119
 120         .data_l1 :
 121         {
 122                 . = ALIGN(4);
 123                 __sdata_l1 = .;
 124                 *(.l1.data)
 125                 *(.l1.bss)
 126                 . = ALIGN(4);
 127                 __edata_l1 = .;
 128         } >l1_data AT>ram
 129         __sdata_l1_lma = LOADADDR(.data_l1);
 130
 131         .bss :
 132         {
 133                 . = ALIGN(4);
 134                 __bss_start = .;
 135                 *(.sbss) *(.scommon)
 136                 *(.dynbss)
 137                 *(.bss .bss.*)
 138                 *(COMMON)
 139                 __bss_end = .;
 140         } >ram
 141 }