git.sur5r.net Git - u-boot/blob - board/davinci/da8xxevm/u-boot-spl-da850evm.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   4  *
   5  * (C) Copyright 2008
   6  * Guennadi Liakhovetki, DENX Software Engineering, <lg@denx.de>
   7  *
   8  * SPDX-License-Identifier:     GPL-2.0+
   9  */
  10
  11 MEMORY { .sram : ORIGIN = CONFIG_SPL_TEXT_BASE,\
  12                 LENGTH = CONFIG_SPL_MAX_FOOTPRINT }
  13
  14 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  15 OUTPUT_ARCH(arm)
  16 ENTRY(_start)
  17 SECTIONS
  18 {
  19         . = 0x00000000;
  20
  21         . = ALIGN(4);
  22         .text      :
  23         {
  24         __start = .;
  25           *(.vectors)
  26           arch/arm/cpu/arm926ejs/start.o        (.text*)
  27           *(.text*)
  28         } >.sram
  29
  30         . = ALIGN(4);
  31         .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
  32
  33         . = ALIGN(4);
  34         .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
  35
  36         . = ALIGN(4);
  37         .u_boot_list : { KEEP(*(SORT(.u_boot_list*))); } >.sram
  38
  39         . = ALIGN(4);
  40         .rel.dyn : {
  41                 __rel_dyn_start = .;
  42                 *(.rel*)
  43                 __rel_dyn_end = .;
  44         } >.sram
  45
  46         .bss :
  47         {
  48                 . = ALIGN(4);
  49                 __bss_start = .;
  50                 *(.bss*)
  51                 . = ALIGN(4);
  52                 __bss_end = .;
  53         } >.sram
  54
  55         __image_copy_end = .;
  56
  57         .end :
  58         {
  59                 *(.__end)
  60         }
  61 }