git.sur5r.net Git - u-boot/blob - board/davinci/da8xxevm/u-boot-spl-da850evm.lds

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * (C) Copyright 2002
   4  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   5  *
   6  * (C) Copyright 2008
   7  * Guennadi Liakhovetki, DENX Software Engineering, <lg@denx.de>
   8  */
   9
  10 MEMORY { .sram : ORIGIN = CONFIG_SPL_TEXT_BASE,\
  11                 LENGTH = CONFIG_SPL_MAX_FOOTPRINT }
  12
  13 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  14 OUTPUT_ARCH(arm)
  15 ENTRY(_start)
  16 SECTIONS
  17 {
  18         . = 0x00000000;
  19
  20         . = ALIGN(4);
  21         .text      :
  22         {
  23         __start = .;
  24           *(.vectors)
  25           arch/arm/cpu/arm926ejs/start.o        (.text*)
  26           *(.text*)
  27         } >.sram
  28
  29         . = ALIGN(4);
  30         .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
  31
  32         . = ALIGN(4);
  33         .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
  34
  35         . = ALIGN(4);
  36         .u_boot_list : { KEEP(*(SORT(.u_boot_list*))); } >.sram
  37
  38         . = ALIGN(4);
  39         .rel.dyn : {
  40                 __rel_dyn_start = .;
  41                 *(.rel*)
  42                 __rel_dyn_end = .;
  43         } >.sram
  44
  45         .bss :
  46         {
  47                 . = ALIGN(4);
  48                 __bss_start = .;
  49                 *(.bss*)
  50                 . = ALIGN(4);
  51                 __bss_end = .;
  52         } >.sram
  53
  54         __image_copy_end = .;
  55
  56         .end :
  57         {
  58                 *(.__end)
  59         }
  60 }