git.sur5r.net Git - u-boot/blob - board/freescale/m5253evbe/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(m68k)
   9
  10 SECTIONS
  11 {
  12   .text      :
  13   {
  14     arch/m68k/cpu/mcf52x2/start.o       (.text*)
  15
  16     . = DEFINED(env_offset) ? env_offset : .;
  17     common/env_embedded.o      (.text)
  18
  19     *(.text*)
  20   }
  21   _etext = .;
  22   PROVIDE (etext = .);
  23   .rodata    :
  24   {
  25     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  26   }
  27
  28   /* Read-write section, merged into data segment: */
  29   . = (. + 0x00FF) & 0xFFFFFF00;
  30   _erotext = .;
  31   PROVIDE (erotext = .);
  32
  33   .reloc   :
  34   {
  35     __got_start = .;
  36     KEEP(*(.got))
  37     __got_end = .;
  38     _GOT2_TABLE_ = .;
  39     KEEP(*(.got2))
  40     _FIXUP_TABLE_ = .;
  41     KEEP(*(.fixup))
  42   }
  43   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  44   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  45
  46   .data    :
  47   {
  48     *(.data*)
  49     *(.sdata*)
  50   }
  51   _edata  =  .;
  52   PROVIDE (edata = .);
  53
  54   . = .;
  55
  56   . = ALIGN(4);
  57   .u_boot_list : {
  58         KEEP(*(SORT(.u_boot_list*)));
  59   }
  60
  61   . = .;
  62   __start___ex_table = .;
  63   __ex_table : { *(__ex_table) }
  64   __stop___ex_table = .;
  65
  66   . = ALIGN(256);
  67   __init_begin = .;
  68   .text.init : { *(.text.init) }
  69   .data.init : { *(.data.init) }
  70   . = ALIGN(256);
  71   __init_end = .;
  72
  73   __bss_start = .;
  74   .bss (NOLOAD)      :
  75   {
  76    _sbss = .;
  77    *(.bss*)
  78    *(.sbss*)
  79    *(COMMON)
  80    . = ALIGN(4);
  81    _ebss = .;
  82   }
  83   __bss_end = . ;
  84   PROVIDE (end = .);
  85 }