git.sur5r.net Git - u-boot/blob - board/freescale/mpc8540ads/u-boot.lds

   1 /*
   2  * (C) Copyright 2002,2003, Motorola,Inc.
   3  * Xianghua Xiao, X.Xiao@motorola.com.
   4  *
   5  * Copyright 2008 Freescale Semiconductor, Inc.
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27 /* Do we need any of these for elf?
  28    __DYNAMIC = 0;    */
  29 PHDRS
  30 {
  31   text PT_LOAD;
  32   bss PT_LOAD;
  33 }
  34
  35 SECTIONS
  36 {
  37   /* Read-only sections, merged into text segment: */
  38   . = + SIZEOF_HEADERS;
  39   .interp : { *(.interp) }
  40   .hash          : { *(.hash)           }
  41   .dynsym        : { *(.dynsym)         }
  42   .dynstr        : { *(.dynstr)         }
  43   .rel.text      : { *(.rel.text)               }
  44   .rela.text     : { *(.rela.text)      }
  45   .rel.data      : { *(.rel.data)               }
  46   .rela.data     : { *(.rela.data)      }
  47   .rel.rodata    : { *(.rel.rodata)     }
  48   .rela.rodata   : { *(.rela.rodata)    }
  49   .rel.got       : { *(.rel.got)                }
  50   .rela.got      : { *(.rela.got)               }
  51   .rel.ctors     : { *(.rel.ctors)      }
  52   .rela.ctors    : { *(.rela.ctors)     }
  53   .rel.dtors     : { *(.rel.dtors)      }
  54   .rela.dtors    : { *(.rela.dtors)     }
  55   .rel.bss       : { *(.rel.bss)                }
  56   .rela.bss      : { *(.rela.bss)               }
  57   .rel.plt       : { *(.rel.plt)                }
  58   .rela.plt      : { *(.rela.plt)               }
  59   .init          : { *(.init)   }
  60   .plt : { *(.plt) }
  61   .text      :
  62   {
  63     *(.text)
  64     *(.fixup)
  65     *(.got1)
  66    } :text
  67     _etext = .;
  68     PROVIDE (etext = .);
  69     .rodata    :
  70    {
  71     *(.eh_frame)
  72     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  73   } :text
  74   .fini      : { *(.fini)    } =0
  75   .ctors     : { *(.ctors)   }
  76   .dtors     : { *(.dtors)   }
  77
  78   /* Read-write section, merged into data segment: */
  79   . = (. + 0x00FF) & 0xFFFFFF00;
  80   _erotext = .;
  81   PROVIDE (erotext = .);
  82   .reloc   :
  83   {
  84     *(.got)
  85     _GOT2_TABLE_ = .;
  86     *(.got2)
  87     _FIXUP_TABLE_ = .;
  88     *(.fixup)
  89   }
  90   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  91   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  92
  93   .data    :
  94   {
  95     *(.data)
  96     *(.data1)
  97     *(.sdata)
  98     *(.sdata2)
  99     *(.dynamic)
 100     CONSTRUCTORS
 101   }
 102   _edata  =  .;
 103   PROVIDE (edata = .);
 104
 105   . = .;
 106   __u_boot_cmd_start = .;
 107   .u_boot_cmd : { *(.u_boot_cmd) }
 108   __u_boot_cmd_end = .;
 109
 110   . = .;
 111   __start___ex_table = .;
 112   __ex_table : { *(__ex_table) }
 113   __stop___ex_table = .;
 114
 115   . = ALIGN(256);
 116   __init_begin = .;
 117   .text.init : { *(.text.init) }
 118   .data.init : { *(.data.init) }
 119   . = ALIGN(256);
 120   __init_end = .;
 121
 122   .bootpg ADDR(.text) + 0x7f000 :
 123   {
 124     cpu/mpc85xx/start.o (.bootpg)
 125   } :text = 0xffff
 126
 127   .resetvec ADDR(.text) + 0x7fffc :
 128   {
 129     *(.resetvec)
 130   } :text = 0xffff
 131
 132   . = ADDR(.text) + 0x80000;
 133
 134   __bss_start = .;
 135   .bss (NOLOAD)       :
 136   {
 137    *(.sbss) *(.scommon)
 138    *(.dynbss)
 139    *(.bss)
 140    *(COMMON)
 141   } :bss
 142
 143   . = ALIGN(4);
 144   _end = . ;
 145   PROVIDE (end = .);
 146 }