git.sur5r.net Git - u-boot/blob - board/freescale/mpc8544ds/u-boot.lds

   1 /*
   2  * Copyright 2007 Freescale Semiconductor, Inc.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 OUTPUT_ARCH(powerpc)
  24 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   .resetvec 0xFFFFFFFC :
  30   {
  31     *(.resetvec)
  32   } = 0xffff
  33
  34   .bootpg 0xFFFFF000 :
  35   {
  36     cpu/mpc85xx/start.o (.bootpg)
  37   } = 0xffff
  38
  39   /* Read-only sections, merged into text segment: */
  40   . = + SIZEOF_HEADERS;
  41   .interp : { *(.interp) }
  42   .hash          : { *(.hash)           }
  43   .dynsym        : { *(.dynsym)         }
  44   .dynstr        : { *(.dynstr)         }
  45   .rel.text      : { *(.rel.text)               }
  46   .rela.text     : { *(.rela.text)      }
  47   .rel.data      : { *(.rel.data)               }
  48   .rela.data     : { *(.rela.data)      }
  49   .rel.rodata    : { *(.rel.rodata)     }
  50   .rela.rodata   : { *(.rela.rodata)    }
  51   .rel.got       : { *(.rel.got)                }
  52   .rela.got      : { *(.rela.got)               }
  53   .rel.ctors     : { *(.rel.ctors)      }
  54   .rela.ctors    : { *(.rela.ctors)     }
  55   .rel.dtors     : { *(.rel.dtors)      }
  56   .rela.dtors    : { *(.rela.dtors)     }
  57   .rel.bss       : { *(.rel.bss)                }
  58   .rela.bss      : { *(.rela.bss)               }
  59   .rel.plt       : { *(.rel.plt)                }
  60   .rela.plt      : { *(.rela.plt)               }
  61   .init          : { *(.init)   }
  62   .plt : { *(.plt) }
  63   .text      :
  64   {
  65     cpu/mpc85xx/start.o (.text)
  66     cpu/mpc85xx/traps.o (.text)
  67     cpu/mpc85xx/interrupts.o (.text)
  68     cpu/mpc85xx/cpu_init.o (.text)
  69     cpu/mpc85xx/cpu.o (.text)
  70     cpu/mpc85xx/speed.o (.text)
  71     common/dlmalloc.o (.text)
  72     lib_generic/crc32.o (.text)
  73     lib_ppc/extable.o (.text)
  74     lib_generic/zlib.o (.text)
  75     *(.text)
  76     *(.fixup)
  77     *(.got1)
  78    }
  79     _etext = .;
  80     PROVIDE (etext = .);
  81     .rodata    :
  82    {
  83     *(.rodata)
  84     *(.rodata1)
  85     *(.rodata.str1.4)
  86     *(.eh_frame)
  87   }
  88   .fini      : { *(.fini)    } =0
  89   .ctors     : { *(.ctors)   }
  90   .dtors     : { *(.dtors)   }
  91
  92   /* Read-write section, merged into data segment: */
  93   . = (. + 0x00FF) & 0xFFFFFF00;
  94   _erotext = .;
  95   PROVIDE (erotext = .);
  96   .reloc   :
  97   {
  98     *(.got)
  99     _GOT2_TABLE_ = .;
 100     *(.got2)
 101     _FIXUP_TABLE_ = .;
 102     *(.fixup)
 103   }
 104   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
 105   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
 106
 107   .data    :
 108   {
 109     *(.data)
 110     *(.data1)
 111     *(.sdata)
 112     *(.sdata2)
 113     *(.dynamic)
 114     CONSTRUCTORS
 115   }
 116   _edata  =  .;
 117   PROVIDE (edata = .);
 118
 119   . = .;
 120   __u_boot_cmd_start = .;
 121   .u_boot_cmd : { *(.u_boot_cmd) }
 122   __u_boot_cmd_end = .;
 123
 124   . = .;
 125   __start___ex_table = .;
 126   __ex_table : { *(__ex_table) }
 127   __stop___ex_table = .;
 128
 129   . = ALIGN(256);
 130   __init_begin = .;
 131   .text.init : { *(.text.init) }
 132   .data.init : { *(.data.init) }
 133   . = ALIGN(256);
 134   __init_end = .;
 135
 136   __bss_start = .;
 137   .bss (NOLOAD)       :
 138   {
 139    *(.sbss) *(.scommon)
 140    *(.dynbss)
 141    *(.bss)
 142    *(COMMON)
 143   }
 144   _end = . ;
 145   PROVIDE (end = .);
 146 }