git.sur5r.net Git - u-boot/blob - board/genietv/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     /* WARNING - the following is hand-optimized to fit within  */
  57     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  58
  59     cpu/mpc8xx/start.o  (.text)
  60     common/dlmalloc.o   (.text)
  61     lib_ppc/ppcstring.o (.text)
  62     lib_generic/vsprintf.o      (.text)
  63     lib_generic/crc32.o         (.text)
  64     lib_generic/zlib.o          (.text)
  65
  66     . = env_offset;
  67     common/environment.o(.text)
  68     *(.text)
  69     *(.fixup)
  70     *(.got1)
  71   }
  72   _etext = .;
  73   PROVIDE (etext = .);
  74   .rodata    :
  75   {
  76     *(.rodata)
  77     *(.rodata1)
  78     *(.rodata.str1.4)
  79     *(.eh_frame)
  80   }
  81   .fini      : { *(.fini)    } =0
  82   .ctors     : { *(.ctors)   }
  83   .dtors     : { *(.dtors)   }
  84
  85   /* Read-write section, merged into data segment: */
  86   . = (. + 0x0FFF) & 0xFFFFF000;
  87   _erotext = .;
  88   PROVIDE (erotext = .);
  89   .reloc   :
  90   {
  91     *(.got)
  92     _GOT2_TABLE_ = .;
  93     *(.got2)
  94     _FIXUP_TABLE_ = .;
  95     *(.fixup)
  96   }
  97   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  98   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  99
 100   .data    :
 101   {
 102     *(.data)
 103     *(.data1)
 104     *(.sdata)
 105     *(.sdata2)
 106     *(.dynamic)
 107     CONSTRUCTORS
 108   }
 109   _edata  =  .;
 110   PROVIDE (edata = .);
 111
 112   . = .;
 113   __u_boot_cmd_start = .;
 114   .u_boot_cmd : { *(.u_boot_cmd) }
 115   __u_boot_cmd_end = .;
 116
 117
 118   . = .;
 119   __start___ex_table = .;
 120   __ex_table : { *(__ex_table) }
 121   __stop___ex_table = .;
 122
 123   . = ALIGN(4096);
 124   __init_begin = .;
 125   .text.init : { *(.text.init) }
 126   .data.init : { *(.data.init) }
 127   . = ALIGN(4096);
 128   __init_end = .;
 129
 130   __bss_start = .;
 131   .bss       :
 132   {
 133    *(.sbss) *(.scommon)
 134    *(.dynbss)
 135    *(.bss)
 136    *(COMMON)
 137   }
 138   . = ALIGN(256 * 1024);
 139   .ppcenv       :
 140   {
 141     common/environment.o (.ppcenv)
 142   }
 143   _end = . ;
 144   PROVIDE (end = .);
 145 }