git.sur5r.net Git - u-boot/blob - board/gth/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp : { *(.interp) }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)               }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)               }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)                }
  42   .rela.got      : { *(.rela.got)               }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)                }
  48   .rela.bss      : { *(.rela.bss)               }
  49   .rel.plt       : { *(.rel.plt)                }
  50   .rela.plt      : { *(.rela.plt)               }
  51   .init          : { *(.init)   }
  52   .plt : { *(.plt) }
  53   .text      :
  54   {
  55     cpu/mpc8xx/start.o(.text)
  56     *(.text)
  57     common/env_embedded.o(.text)
  58     *(.fixup)
  59     *(.got1)
  60   }
  61   _etext = .;
  62   PROVIDE (etext = .);
  63   .rodata    :
  64   {
  65     *(.eh_frame)
  66     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  67   }
  68   .fini      : { *(.fini)    } =0
  69   .ctors     : { *(.ctors)   }
  70   .dtors     : { *(.dtors)   }
  71
  72   /* Read-write section, merged into data segment: */
  73   . = (. + 0x0FFF) & 0xFFFFF000;
  74   _erotext = .;
  75   PROVIDE (erotext = .);
  76   .reloc   :
  77   {
  78     *(.got)
  79     _GOT2_TABLE_ = .;
  80     *(.got2)
  81     _FIXUP_TABLE_ = .;
  82     *(.fixup)
  83   }
  84   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  85   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  86
  87   .data    :
  88   {
  89     *(.data)
  90     *(.data1)
  91     *(.sdata)
  92     *(.sdata2)
  93     *(.dynamic)
  94     CONSTRUCTORS
  95   }
  96   _edata  =  .;
  97   PROVIDE (edata = .);
  98
  99   . = .;
 100   __u_boot_cmd_start = .;
 101   .u_boot_cmd : { *(.u_boot_cmd) }
 102   __u_boot_cmd_end = .;
 103
 104
 105   . = .;
 106   __start___ex_table = .;
 107   __ex_table : { *(__ex_table) }
 108   __stop___ex_table = .;
 109
 110   . = ALIGN(4096);
 111   __init_begin = .;
 112   .text.init : { *(.text.init) }
 113   .data.init : { *(.data.init) }
 114   . = ALIGN(4096);
 115   __init_end = .;
 116
 117   __bss_start = .;
 118   .bss (NOLOAD)       :
 119   {
 120    *(.sbss) *(.scommon)
 121    *(.dynbss)
 122    *(.bss)
 123    *(COMMON)
 124    . = ALIGN(4);
 125   }
 126   _end = . ;
 127   PROVIDE (end = .);
 128 }