git.sur5r.net Git - u-boot/blob - board/nc650/u-boot.lds.debug

   1 /*
   2  * (C) Copyright 2001
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     cpu/mpc8xx/start.o  (.text)
  57     *(.text)
  58     *(.fixup)
  59     *(.got1)
  60   }
  61   _etext = .;
  62   PROVIDE (etext = .);
  63   .rodata    :
  64   {
  65     *(.rodata)
  66     *(.rodata1)
  67     *(.rodata.str1.4)
  68     *(.eh_frame)
  69   }
  70   .fini      : { *(.fini)    } =0
  71   .ctors     : { *(.ctors)   }
  72   .dtors     : { *(.dtors)   }
  73
  74   /* Read-write section, merged into data segment: */
  75   . = (. + 0x0FFF) & 0xFFFFF000;
  76   _erotext = .;
  77   PROVIDE (erotext = .);
  78   .reloc   :
  79   {
  80     *(.got)
  81     _GOT2_TABLE_ = .;
  82     *(.got2)
  83     _FIXUP_TABLE_ = .;
  84     *(.fixup)
  85   }
  86   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  87   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  88
  89   .data    :
  90   {
  91     *(.data)
  92     *(.data1)
  93     *(.sdata)
  94     *(.sdata2)
  95     *(.dynamic)
  96     CONSTRUCTORS
  97   }
  98   _edata  =  .;
  99   PROVIDE (edata = .);
 100
 101   __u_boot_cmd_start = .;
 102   .u_boot_cmd : { *(.u_boot_cmd) }
 103   __u_boot_cmd_end = .;
 104
 105
 106   __start___ex_table = .;
 107   __ex_table : { *(__ex_table) }
 108   __stop___ex_table = .;
 109
 110   . = ALIGN(4096);
 111   __init_begin = .;
 112   .text.init : { *(.text.init) }
 113   .data.init : { *(.data.init) }
 114   . = ALIGN(4096);
 115   __init_end = .;
 116
 117   __bss_start = .;
 118   .bss       :
 119   {
 120    *(.sbss) *(.scommon)
 121    *(.dynbss)
 122    *(.bss)
 123    *(COMMON)
 124   }
 125   _end = . ;
 126   PROVIDE (end = .);
 127 }