git.sur5r.net Git - u-boot/blob - board/ti/am335x/u-boot.lds

   1 /*
   2  * Copyright (c) 2004-2008 Texas Instruments
   3  *
   4  * (C) Copyright 2002
   5  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  27 OUTPUT_ARCH(arm)
  28 ENTRY(_start)
  29 SECTIONS
  30 {
  31         . = 0x00000000;
  32
  33         . = ALIGN(4);
  34         .text :
  35         {
  36                 *(.__image_copy_start)
  37                 *(.vectors)
  38                 CPUDIR/start.o (.text*)
  39                 board/ti/am335x/built-in.o (.text*)
  40                 *(.text*)
  41         }
  42
  43         . = ALIGN(4);
  44         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  45
  46         . = ALIGN(4);
  47         .data : {
  48                 *(.data*)
  49         }
  50
  51         . = ALIGN(4);
  52
  53         . = .;
  54
  55         . = ALIGN(4);
  56         .u_boot_list : {
  57                 KEEP(*(SORT(.u_boot_list*)));
  58         }
  59
  60         . = ALIGN(4);
  61
  62         .__efi_runtime_start : {
  63                 *(.__efi_runtime_start)
  64         }
  65
  66         .efi_runtime : {
  67                 *(efi_runtime_text)
  68                 *(efi_runtime_data)
  69         }
  70
  71         .__efi_runtime_stop : {
  72                 *(.__efi_runtime_stop)
  73         }
  74
  75         .efi_runtime_rel_start :
  76         {
  77                 *(.__efi_runtime_rel_start)
  78         }
  79
  80         .efi_runtime_rel : {
  81                 *(.relefi_runtime_text)
  82                 *(.relefi_runtime_data)
  83         }
  84
  85         .efi_runtime_rel_stop :
  86         {
  87                 *(.__efi_runtime_rel_stop)
  88         }
  89
  90         . = ALIGN(4);
  91
  92         .image_copy_end :
  93         {
  94                 *(.__image_copy_end)
  95         }
  96
  97         .rel_dyn_start :
  98         {
  99                 *(.__rel_dyn_start)
 100         }
 101
 102         .rel.dyn : {
 103                 *(.rel*)
 104         }
 105
 106         .rel_dyn_end :
 107         {
 108                 *(.__rel_dyn_end)
 109         }
 110
 111         .hash : { *(.hash*) }
 112
 113         .end :
 114         {
 115                 *(.__end)
 116         }
 117
 118         _image_binary_end = .;
 119
 120         /*
 121          * Deprecated: this MMU section is used by pxa at present but
 122          * should not be used by new boards/CPUs.
 123          */
 124         . = ALIGN(4096);
 125         .mmutable : {
 126                 *(.mmutable)
 127         }
 128
 129 /*
 130  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
 131  * __bss_base and __bss_limit are for linker only (overlay ordering)
 132  */
 133
 134         .bss_start __rel_dyn_start (OVERLAY) : {
 135                 KEEP(*(.__bss_start));
 136                 __bss_base = .;
 137         }
 138
 139         .bss __bss_base (OVERLAY) : {
 140                 *(.bss*)
 141                  . = ALIGN(4);
 142                  __bss_limit = .;
 143         }
 144
 145         .bss_end __bss_limit (OVERLAY) : {
 146                 KEEP(*(.__bss_end));
 147         }
 148
 149         .dynsym _image_binary_end : { *(.dynsym) }
 150         .dynbss : { *(.dynbss) }
 151         .dynstr : { *(.dynstr*) }
 152         .dynamic : { *(.dynamic*) }
 153         .gnu.hash : { *(.gnu.hash) }
 154         .plt : { *(.plt*) }
 155         .interp : { *(.interp*) }
 156         .gnu : { *(.gnu*) }
 157         .ARM.exidx : { *(.ARM.exidx*) }
 158 }