git.sur5r.net Git - glabels/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.63)
   4
   5 AC_INIT([glabels],[2.3.0],[http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116])
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7
   8 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   9
  10 AM_MAINTAINER_MODE
  11 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  12
  13 AC_CONFIG_HEADERS(config.h)
  14
  15 IT_PROG_INTLTOOL([0.21])
  16
  17 PKG_PROG_PKG_CONFIG
  18
  19 LT_INIT
  20
  21 GNOME_DOC_INIT
  22 GTK_DOC_CHECK(1.0)
  23
  24 AC_SEARCH_LIBS([strerror],[cposix])
  25 AC_PROG_CC
  26 AC_PROG_INSTALL
  27
  28 GNOME_COMPILE_WARNINGS
  29
  30 AC_PATH_PROG(GLIB_GENMARSHAL,         glib-genmarshal)
  31 AC_PATH_PROG(GDK_PIXBUF_CSOURCE,      gdk-pixbuf-csource)
  32 AC_PATH_PROG(UPDATE_MIME_DATABASE,    update-mime-database)
  33 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database)
  34
  35 dnl ---------------------------------------------------------------------------
  36 dnl - GLABELS branch
  37 dnl ---------------------------------------------------------------------------
  38 GLABELS_BRANCH=glabels-3.0
  39 AC_SUBST(GLABELS_BRANCH)
  40
  41 dnl ---------------------------------------------------------------------------
  42 dnl - LIBGLABELS branch
  43 dnl ---------------------------------------------------------------------------
  44 LIBGLABELS_BRANCH=libglabels-3.0
  45 AC_SUBST(LIBGLABELS_BRANCH)
  46
  47 dnl ---------------------------------------------------------------------------
  48 dnl - LIBGLABELS API versioning
  49 dnl ---------------------------------------------------------------------------
  50 dnl From the libtool manual:
  51 dnl 1. Start with version information of `0:0:0' for each libtool library.
  52 dnl 2. Update the version information only immediately before a public release.
  53 dnl    More frequent updates are unnecessary, and only guarantee that the current
  54 dnl    interface number gets larger faster.
  55 dnl 3. If the library source code has changed at all since the last update, then increment
  56 dnl    revision (`c:r:a' becomes `c:r+1:a').
  57 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  58 dnl    increment current, and set revision to 0.
  59 dnl 5. If any interfaces have been added since the last public release, then increment age.
  60 dnl 6. If any interfaces have been removed since the last public release, then set age
  61 dnl    to 0.
  62 LIBGLABELS_C=7
  63 LIBGLABELS_R=0
  64 LIBGLABELS_A=0
  65
  66 LIBGLABELS_API_VERSION=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  67 AC_SUBST(LIBGLABELS_API_VERSION)
  68
  69 dnl ---------------------------------------------------------------------------
  70 dnl - Library dependencies
  71 dnl ---------------------------------------------------------------------------
  72 dnl Required dependencies
  73 GLIB_REQUIRED=2.24.0
  74 GTK_REQUIRED=2.20.0
  75 GCONF_REQUIRED=2.28.0
  76 LIBXML_REQUIRED=2.7.0
  77
  78 dnl Optional dependencies
  79 LIBEBOOK_REQUIRED=2.28.0
  80 LIBBARCODE_REQUIRED=0.98
  81 LIBQRENCODE_REQUIRED=3.1.0
  82 LIBIEC16022_REQUIRED=0.2.4
  83 LIBZINT_REQUIRED=2.3.1
  84
  85 dnl Make above strings available for packaging files (e.g. rpm spec files)
  86 AC_SUBST(GLIB_REQUIRED)
  87 AC_SUBST(GTK_REQUIRED)
  88 AC_SUBST(GCONF_REQUIRED)
  89 AC_SUBST(LIBXML_REQUIRED)
  90 AC_SUBST(LIBEBOOK_REQUIRED)
  91 AC_SUBST(LIBBARCODE_REQUIRED)
  92 AC_SUBST(LIBQRENCODE_REQUIRED)
  93 AC_SUBST(LIBIEC16022_REQUIRED)
  94 AC_SUBST(LIBZINT_REQUIRED)
  95
  96
  97 dnl ---------------------------------------------------------------------------
  98 dnl - GLABELS prerequisites
  99 dnl ---------------------------------------------------------------------------
 100 PKG_CHECK_MODULES(GLABELS, [\
 101         glib-2.0 >= $GLIB_REQUIRED \
 102         gtk+-2.0 >= $GTK_REQUIRED \
 103         gconf-2.0 >= $GCONF_REQUIRED \
 104         libxml-2.0 >= $LIBXML_REQUIRED \
 105 ])
 106
 107 AC_SUBST(GLABELS_CFLAGS)
 108 AC_SUBST(GLABELS_LIBS)
 109
 110
 111 dnl ---------------------------------------------------------------------------
 112 dnl - LIBGLABELS more modest prerequisites
 113 dnl ---------------------------------------------------------------------------
 114 PKG_CHECK_MODULES(LIBGLABELS, [\
 115         glib-2.0 >= $GLIB_REQUIRED \
 116         gconf-2.0 >= $GCONF_REQUIRED \
 117         libxml-2.0 >= $LIBXML_REQUIRED \
 118 ])
 119
 120 AC_SUBST(LIBGLABELS_CFLAGS)
 121 AC_SUBST(LIBGLABELS_LIBS)
 122
 123
 124 dnl ---------------------------------------------------------------------------
 125 dnl - Check for optional evolution data server
 126 dnl ---------------------------------------------------------------------------
 127 AC_ARG_WITH(libebook,
 128             [AS_HELP_STRING([--without-libebook],[build without Evolution Data Server support])])
 129 have_libebook=no
 130 if test "x$with_libebook" != xno; then
 131         PKG_CHECK_MODULES(LIBEBOOK, libebook-1.2 >= $LIBEBOOK_REQUIRED,
 132                           [have_libebook=yes], [have_libebook=no])
 133 fi
 134
 135 if test "x$have_libebook" = "xyes"; then
 136         AC_DEFINE(HAVE_LIBEBOOK,1,[Define to 1 for EDS support])
 137         AC_SUBST(LIBEBOOK_CFLAGS)
 138         AC_SUBST(LIBEBOOK_LIBS)
 139 fi
 140
 141
 142 dnl ---------------------------------------------------------------------------
 143 dnl - Check for optional GNU Barcode backend
 144 dnl ---------------------------------------------------------------------------
 145 AC_ARG_WITH(libbarcode,
 146             [AS_HELP_STRING([--without-libbarcode],[build without GNU Barcode support])])
 147 have_libbarcode=no
 148 if test "x$with_libbarcode" != xno; then
 149    AC_CHECK_LIB(barcode, Barcode_Create,
 150                 [have_libbarcode=yes], [have_libbarcode=no])
 151 fi
 152
 153 if test "x$have_libbarcode" = "xyes"; then
 154         AC_DEFINE(HAVE_LIBBARCODE,1,[Define to 1 for GNU Barcode support])
 155         LIBBARCODE_CFLAGS=""
 156         LIBBARCODE_LIBS="-lbarcode"
 157         AC_SUBST(LIBBARCODE_CFLAGS)
 158         AC_SUBST(LIBBARCODE_LIBS)
 159 else
 160         help_libbarcode="(See http://www.gnu.org/software/barcode/barcode.html)"
 161 fi
 162
 163 dnl ---------------------------------------------------------------------------
 164 dnl - Check for optional Zint backend
 165 dnl ---------------------------------------------------------------------------
 166 AC_ARG_WITH(libzint,
 167             [AS_HELP_STRING([--without-libzint],[build without Zint Barcode support])])
 168 have_libzint=no
 169 if test "x$with_libzint" != xno; then
 170    AC_CHECK_LIB(zint, ZBarcode_Create,
 171                 [have_libzint=yes], [have_libzint=no])
 172 fi
 173
 174 if test "x$have_libzint" = "xyes"; then
 175         AC_DEFINE(HAVE_LIBZINT,1,[Define to 1 for Zint Barcode support])
 176         LIBZINT_CFLAGS=""
 177         LIBZINT_LIBS="-lzint"
 178         AC_SUBST(LIBZINT_CFLAGS)
 179         AC_SUBST(LIBZINT_LIBS)
 180 else
 181         help_libzint="(See http://www.zint.org.uk)"
 182 fi
 183
 184
 185 dnl ---------------------------------------------------------------------------
 186 dnl - Check for optional QRencode Barcode backend
 187 dnl ---------------------------------------------------------------------------
 188 AC_ARG_WITH(libqrencode,
 189             [AS_HELP_STRING([--without-libqrencode],[build without QR code support])])
 190 have_libqrencode=no
 191 if test "x$with_libqrencode" != xno; then
 192         PKG_CHECK_MODULES(LIBQRENCODE, libqrencode >= $LIBQRENCODE_REQUIRED,
 193                           [have_libqrencode=yes], [have_libqrencode=no])
 194 fi
 195
 196 if test "x$have_libqrencode" = "xyes"; then
 197         AC_DEFINE(HAVE_LIBQRENCODE,1,[Define to 1 for QR code support])
 198         AC_SUBST(LIBQRENCODE_CFLAGS)
 199         AC_SUBST(LIBQRENCODE_LIBS)
 200 else
 201         help_libqrencode="(See http://megaui.net/fukuchi/works/qrencode/index.en.html)"
 202 fi
 203
 204
 205 dnl ---------------------------------------------------------------------------
 206 dnl - Check for IEC16022 Barcode backend
 207 dnl ---------------------------------------------------------------------------
 208 AC_ARG_WITH(libiec16022,
 209             [AS_HELP_STRING([--without-libiec16022],[build without IEC 16022 support])])
 210 have_libiec16022=no
 211 if test "x$with_libiec16022" != xno; then
 212         PKG_CHECK_MODULES(LIBIEC16022, libiec16022 >= $LIBIEC16022_REQUIRED,
 213                           [have_libiec16022=yes], [have_libiec16022=no])
 214 fi
 215
 216 if test "x$have_libiec16022" = "xyes"; then
 217         AC_DEFINE(HAVE_LIBIEC16022,1,[Define to 1 for IEC 16022 support])
 218         AC_SUBST(LIBIEC16022_CFLAGS)
 219         AC_SUBST(LIBIEC16022_LIBS)
 220 else
 221         help_libiec16022="(See http://datenfreihafen.org/projects/iec16022.html)"
 222 fi
 223
 224
 225 dnl ---------------------------------------------------------------------------
 226 dnl - Enable deprecation testing
 227 dnl ---------------------------------------------------------------------------
 228 AC_ARG_ENABLE(deprecations,
 229               [AS_HELP_STRING([--enable-deprecations],[warn about deprecated usages [default=no]])],,
 230               [enable_deprecations=no])
 231
 232 if test "x$enable_deprecations" = "xyes"; then
 233    DISABLE_DEPRECATED_CFLAGS="\
 234 -DG_DISABLE_DEPRECATED \
 235 -DGDK_DISABLE_DEPRECATED \
 236 -DGTK_DISABLE_DEPRECATED \
 237 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 238 "
 239    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 240 fi
 241
 242
 243 dnl ---------------------------------------------------------------------------
 244 dnl - Disable updating of mime and desktop databases
 245 dnl ---------------------------------------------------------------------------
 246 AC_ARG_ENABLE(update-mimedb, AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]]),,
 247               enable_update_mimedb=yes)
 248 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 249
 250 AC_ARG_ENABLE(update-desktopdb, AS_HELP_STRING([--disable-update-desktopdb],[disable the update-desktop-database after install [default=no]]),,
 251               enable_update_desktopdb=yes)
 252 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 253
 254
 255 dnl ---------------------------------------------------------------------------
 256 dnl - i18n support
 257 dnl ---------------------------------------------------------------------------
 258 GETTEXT_PACKAGE=${GLABELS_BRANCH}
 259 AC_SUBST(GETTEXT_PACKAGE)
 260 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 261
 262 AM_GLIB_GNU_GETTEXT
 263
 264
 265 dnl ---------------------------------------------------------------------------
 266 dnl - Makefiles, etc.
 267 dnl ---------------------------------------------------------------------------
 268 AC_CONFIG_FILES([
 269 Makefile
 270 libglabels/Makefile
 271 libglabels/${LIBGLABELS_BRANCH}.pc
 272 src/Makefile
 273 src/pixmaps/Makefile
 274 src/stock-pixmaps/Makefile
 275 data/Makefile
 276 data/pixmaps/Makefile
 277 data/mime/Makefile
 278 data/ui/Makefile
 279 data/desktop/Makefile
 280 data/man/Makefile
 281 templates/Makefile
 282 po/Makefile.in
 283 help/Makefile
 284 docs/Makefile
 285 docs/libglabels/Makefile
 286 glabels.spec
 287 ])
 288 AC_OUTPUT
 289
 290
 291 dnl ---------------------------------------------------------------------------
 292 dnl - Print configuration information
 293 dnl ---------------------------------------------------------------------------
 294 echo "
 295
 296 Configuration:
 297
 298         Package ................. ${PACKAGE}-${VERSION}
 299         Installation prefix ..... ${prefix}
 300         Source code location .... ${srcdir}
 301         Compiler ................ ${CC}
 302
 303
 304 Optional data merge backends:
 305
 306         Evolution Data Server ... ${have_libebook}
 307
 308
 309 Optional barcode backends:
 310
 311         GNU Barcode ............. ${have_libbarcode} ${help_libbarcode}
 312         QR Code ................. ${have_libqrencode} ${help_libqrencode}
 313         IEC 16022 ............... ${have_libiec16022} ${help_libiec16022}
 314         Zint .................... ${have_libzint} ${help_libzint}
 315
 316
 317 "
 318
 319
 320 cat ${srcdir}/MESSAGE-OF-DOOM
 321