git.sur5r.net Git - u-boot/blob - cpu/arm920t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27
  28 #include <config.h>
  29 #include <version.h>
  30
  31
  32 /*
  33  *************************************************************************
  34  *
  35  * Jump vector table as in table 3.1 in [1]
  36  *
  37  *************************************************************************
  38  */
  39
  40
  41 .globl _start
  42 _start: b       reset
  43         ldr     pc, _undefined_instruction
  44         ldr     pc, _software_interrupt
  45         ldr     pc, _prefetch_abort
  46         ldr     pc, _data_abort
  47         ldr     pc, _not_used
  48         ldr     pc, _irq
  49         ldr     pc, _fiq
  50
  51 _undefined_instruction: .word undefined_instruction
  52 _software_interrupt:    .word software_interrupt
  53 _prefetch_abort:        .word prefetch_abort
  54 _data_abort:            .word data_abort
  55 _not_used:              .word not_used
  56 _irq:                   .word irq
  57 _fiq:                   .word fiq
  58
  59         .balignl 16,0xdeadbeef
  60
  61
  62 /*
  63  *************************************************************************
  64  *
  65  * Startup Code (reset vector)
  66  *
  67  * do important init only if we don't start from memory!
  68  * relocate armboot to ram
  69  * setup stack
  70  * jump to second stage
  71  *
  72  *************************************************************************
  73  */
  74
  75 /*
  76  * CFG_MEM_END is in the board dependent config-file (configs/config_BOARD.h)
  77  */
  78 _TEXT_BASE:
  79         .word   TEXT_BASE
  80
  81 .globl _armboot_start
  82 _armboot_start:
  83         .word _start
  84
  85 /*
  86  * Note: _armboot_end_data and _armboot_end are defined
  87  * by the (board-dependent) linker script.
  88  * _armboot_end_data is the first usable FLASH address after armboot
  89  */
  90 .globl _armboot_end_data
  91 _armboot_end_data:
  92         .word armboot_end_data
  93 .globl _armboot_end
  94 _armboot_end:
  95         .word armboot_end
  96
  97 /*
  98  * _armboot_real_end is the first usable RAM address behind armboot
  99  * and the various stacks
 100  */
 101 .globl _armboot_real_end
 102 _armboot_real_end:
 103         .word 0x0badc0de
 104
 105 #ifdef CONFIG_USE_IRQ
 106 /* IRQ stack memory (calculated at run-time) */
 107 .globl IRQ_STACK_START
 108 IRQ_STACK_START:
 109         .word   0x0badc0de
 110
 111 /* IRQ stack memory (calculated at run-time) */
 112 .globl FIQ_STACK_START
 113 FIQ_STACK_START:
 114         .word 0x0badc0de
 115 #endif
 116
 117
 118 /*
 119  * the actual reset code
 120  */
 121
 122 reset:
 123         /*
 124          * set the cpu to SVC32 mode
 125          */
 126         mrs     r0,cpsr
 127         bic     r0,r0,#0x1f
 128         orr     r0,r0,#0xd3
 129         msr     cpsr,r0
 130
 131 /* turn off the watchdog */
 132 #if defined(CONFIG_S3C2400)
 133 #define pWTCON          0x15300000
 134 /* Interupt-Controller base addresses */
 135 #define INTMSK          0x14400008
 136 /* clock divisor register */
 137 #define CLKDIVN         0x14800014
 138 #elif defined(CONFIG_S3C2410)
 139 #define pWTCON          0x53000000
 140 /* Interupt-Controller base addresses */
 141 #define INTMSK          0x4A000008
 142 #define INTSUBMSK       0x4A00001C
 143 /* clock divisor register */
 144 #define CLKDIVN         0x4C000014
 145 #endif
 146
 147         ldr     r0, =pWTCON
 148         mov     r1, #0x0
 149         str     r1, [r0]
 150
 151         /*
 152          * mask all IRQs by setting all bits in the INTMR - default
 153          */
 154         mov     r1, #0xffffffff
 155         ldr     r0, =INTMSK
 156         str     r1, [r0]
 157 #if defined(CONFIG_S3C2410)
 158         ldr     r1, =0x3ff
 159         ldr     r0, =INTSUBMSK
 160         str     r1, [r0]
 161 #endif
 162
 163         /* FCLK:HCLK:PCLK = 1:2:4 */
 164         /* default FCLK is 120 MHz ! */
 165         ldr     r0, =CLKDIVN
 166         mov     r1, #3
 167         str     r1, [r0]
 168
 169         /*
 170          * we do sys-critical inits only at reboot,
 171          * not when booting from ram!
 172          */
 173 #ifdef CONFIG_INIT_CRITICAL
 174         bl      cpu_init_crit
 175 #endif
 176
 177 relocate:
 178         /*
 179          * relocate armboot to RAM
 180          */
 181         adr     r0, _start              /* r0 <- current position of code */
 182         ldr     r2, _armboot_start
 183         ldr     r3, _armboot_end
 184         sub     r2, r3, r2              /* r2 <- size of armboot */
 185         ldr     r1, _TEXT_BASE          /* r1 <- destination address */
 186         add     r2, r0, r2              /* r2 <- source end address */
 187
 188         /*
 189          * r0 = source address
 190          * r1 = target address
 191          * r2 = source end address
 192          */
 193 copy_loop:
 194         ldmia   r0!, {r3-r10}
 195         stmia   r1!, {r3-r10}
 196         cmp     r0, r2
 197         ble     copy_loop
 198
 199 #if 0
 200         /* try doing this stuff after the relocation */
 201         ldr     r0, =pWTCON
 202         mov     r1, #0x0
 203         str     r1, [r0]
 204
 205         /*
 206          * mask all IRQs by setting all bits in the INTMR - default
 207          */
 208         mov     r1, #0xffffffff
 209         ldr     r0, =INTMR
 210         str     r1, [r0]
 211
 212         /* FCLK:HCLK:PCLK = 1:2:4 */
 213         /* default FCLK is 120 MHz ! */
 214         ldr     r0, =CLKDIVN
 215         mov     r1, #3
 216         str     r1, [r0]
 217         /* END stuff after relocation */
 218 #endif
 219
 220         /* set up the stack */
 221         ldr     r0, _armboot_end
 222         add     r0, r0, #CONFIG_STACKSIZE
 223         sub     sp, r0, #12             /* leave 3 words for abort-stack */
 224
 225         ldr     pc, _start_armboot
 226
 227 _start_armboot: .word start_armboot
 228
 229
 230 /*
 231  *************************************************************************
 232  *
 233  * CPU_init_critical registers
 234  *
 235  * setup important registers
 236  * setup memory timing
 237  *
 238  *************************************************************************
 239  */
 240
 241
 242 cpu_init_crit:
 243         /*
 244          * flush v4 I/D caches
 245          */
 246         mov     r0, #0
 247         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 248         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 249
 250         /*
 251          * disable MMU stuff and caches
 252          */
 253         mrc     p15, 0, r0, c1, c0, 0
 254         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 255         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 256         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 257         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 258         mcr     p15, 0, r0, c1, c0, 0
 259
 260
 261         /*
 262          * before relocating, we have to setup RAM timing
 263          * because memory timing is board-dependend, you will
 264          * find a memsetup.S in your board directory.
 265          */
 266         mov     ip, lr
 267         bl      memsetup
 268         mov     lr, ip
 269
 270         mov     pc, lr
 271
 272
 273 /*
 274  *************************************************************************
 275  *
 276  * Interrupt handling
 277  *
 278  *************************************************************************
 279  */
 280
 281 @
 282 @ IRQ stack frame.
 283 @
 284 #define S_FRAME_SIZE    72
 285
 286 #define S_OLD_R0        68
 287 #define S_PSR           64
 288 #define S_PC            60
 289 #define S_LR            56
 290 #define S_SP            52
 291
 292 #define S_IP            48
 293 #define S_FP            44
 294 #define S_R10           40
 295 #define S_R9            36
 296 #define S_R8            32
 297 #define S_R7            28
 298 #define S_R6            24
 299 #define S_R5            20
 300 #define S_R4            16
 301 #define S_R3            12
 302 #define S_R2            8
 303 #define S_R1            4
 304 #define S_R0            0
 305
 306 #define MODE_SVC 0x13
 307 #define I_BIT    0x80
 308
 309 /*
 310  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 311  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 312  */
 313
 314         .macro  bad_save_user_regs
 315         sub     sp, sp, #S_FRAME_SIZE
 316         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 317         ldr     r2, _armboot_end
 318         add     r2, r2, #CONFIG_STACKSIZE
 319         sub     r2, r2, #8
 320         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 321         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 322
 323         add     r5, sp, #S_SP
 324         mov     r1, lr
 325         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 326         mov     r0, sp
 327         .endm
 328
 329         .macro  irq_save_user_regs
 330         sub     sp, sp, #S_FRAME_SIZE
 331         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 332         add     r8, sp, #S_PC
 333         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 334         str     lr, [r8, #0]                    @ Save calling PC
 335         mrs     r6, spsr
 336         str     r6, [r8, #4]                    @ Save CPSR
 337         str     r0, [r8, #8]                    @ Save OLD_R0
 338         mov     r0, sp
 339         .endm
 340
 341         .macro  irq_restore_user_regs
 342         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 343         mov     r0, r0
 344         ldr     lr, [sp, #S_PC]                 @ Get PC
 345         add     sp, sp, #S_FRAME_SIZE
 346         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 347         .endm
 348
 349         .macro get_bad_stack
 350         ldr     r13, _armboot_end               @ setup our mode stack
 351         add     r13, r13, #CONFIG_STACKSIZE     @ resides at top of normal stack
 352         sub     r13, r13, #8
 353
 354         str     lr, [r13]                       @ save caller lr / spsr
 355         mrs     lr, spsr
 356         str     lr, [r13, #4]
 357
 358         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 359         @ msr   spsr_c, r13
 360         msr     spsr, r13
 361         mov     lr, pc
 362         movs    pc, lr
 363         .endm
 364
 365         .macro get_irq_stack                    @ setup IRQ stack
 366         ldr     sp, IRQ_STACK_START
 367         .endm
 368
 369         .macro get_fiq_stack                    @ setup FIQ stack
 370         ldr     sp, FIQ_STACK_START
 371         .endm
 372
 373 /*
 374  * exception handlers
 375  */
 376         .align  5
 377 undefined_instruction:
 378         get_bad_stack
 379         bad_save_user_regs
 380         bl      do_undefined_instruction
 381
 382         .align  5
 383 software_interrupt:
 384         get_bad_stack
 385         bad_save_user_regs
 386         bl      do_software_interrupt
 387
 388         .align  5
 389 prefetch_abort:
 390         get_bad_stack
 391         bad_save_user_regs
 392         bl      do_prefetch_abort
 393
 394         .align  5
 395 data_abort:
 396         get_bad_stack
 397         bad_save_user_regs
 398         bl      do_data_abort
 399
 400         .align  5
 401 not_used:
 402         get_bad_stack
 403         bad_save_user_regs
 404         bl      do_not_used
 405
 406 #ifdef CONFIG_USE_IRQ
 407
 408         .align  5
 409 irq:
 410         get_irq_stack
 411         irq_save_user_regs
 412         bl      do_irq
 413         irq_restore_user_regs
 414
 415         .align  5
 416 fiq:
 417         get_fiq_stack
 418         /* someone ought to write a more effiction fiq_save_user_regs */
 419         irq_save_user_regs
 420         bl      do_fiq
 421         irq_restore_user_regs
 422
 423 #else
 424
 425         .align  5
 426 irq:
 427         get_bad_stack
 428         bad_save_user_regs
 429         bl      do_irq
 430
 431         .align  5
 432 fiq:
 433         get_bad_stack
 434         bad_save_user_regs
 435         bl      do_fiq
 436
 437 #endif
 438
 439         .align  5
 440 .globl reset_cpu
 441 reset_cpu:
 442 #ifdef CONFIG_S3C2400
 443         bl      disable_interrupts
 444 # ifdef CONFIG_TRAB
 445         bl      disable_vfd
 446 # endif
 447         ldr     r1, _rWTCON
 448         ldr     r2, _rWTCNT
 449         /* Disable watchdog */
 450         mov     r3, #0x0000
 451         str     r3, [r1]
 452         /* Initialize watchdog timer count register */
 453         mov     r3, #0x0001
 454         str     r3, [r2]
 455         /* Enable watchdog timer; assert reset at timer timeout */
 456         mov     r3, #0x0021
 457         str     r3, [r1]
 458 _loop_forever:
 459         b       _loop_forever
 460 _rWTCON:
 461         .word   0x15300000
 462 _rWTCNT:
 463         .word   0x15300008
 464 #else /* ! CONFIG_S3C2400 */
 465         mov     ip, #0
 466         mcr     p15, 0, ip, c7, c7, 0           @ invalidate cache
 467         mcr     p15, 0, ip, c8, c7, 0           @ flush TLB (v4)
 468         mrc     p15, 0, ip, c1, c0, 0           @ get ctrl register
 469         bic     ip, ip, #0x000f                 @ ............wcam
 470         bic     ip, ip, #0x2100                 @ ..v....s........
 471         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 472         mov     pc, r0
 473 #endif /* CONFIG_S3C2400 */