git.sur5r.net Git - u-boot/blob - cpu/arm920t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27
  28 #include <config.h>
  29 #include <version.h>
  30
  31
  32 /*
  33  *************************************************************************
  34  *
  35  * Jump vector table as in table 3.1 in [1]
  36  *
  37  *************************************************************************
  38  */
  39
  40
  41 .globl _start
  42 _start: b       reset
  43         ldr     pc, _undefined_instruction
  44         ldr     pc, _software_interrupt
  45         ldr     pc, _prefetch_abort
  46         ldr     pc, _data_abort
  47         ldr     pc, _not_used
  48         ldr     pc, _irq
  49         ldr     pc, _fiq
  50
  51 _undefined_instruction: .word undefined_instruction
  52 _software_interrupt:    .word software_interrupt
  53 _prefetch_abort:        .word prefetch_abort
  54 _data_abort:            .word data_abort
  55 _not_used:              .word not_used
  56 _irq:                   .word irq
  57 _fiq:                   .word fiq
  58
  59         .balignl 16,0xdeadbeef
  60
  61
  62 /*
  63  *************************************************************************
  64  *
  65  * Startup Code (reset vector)
  66  *
  67  * do important init only if we don't start from memory!
  68  * relocate armboot to ram
  69  * setup stack
  70  * jump to second stage
  71  *
  72  *************************************************************************
  73  */
  74
  75 _TEXT_BASE:
  76         .word   TEXT_BASE
  77
  78 .globl _armboot_start
  79 _armboot_start:
  80         .word _start
  81
  82 /*
  83  * Note: _armboot_end_data and _armboot_end are defined
  84  * by the (board-dependent) linker script.
  85  * _armboot_end_data is the first usable FLASH address after armboot
  86  */
  87 .globl _armboot_end_data
  88 _armboot_end_data:
  89         .word armboot_end_data
  90 .globl _armboot_end
  91 _armboot_end:
  92         .word armboot_end
  93
  94 /*
  95  * _armboot_real_end is the first usable RAM address behind armboot
  96  * and the various stacks
  97  */
  98 .globl _armboot_real_end
  99 _armboot_real_end:
 100         .word 0x0badc0de
 101
 102 #ifdef CONFIG_USE_IRQ
 103 /* IRQ stack memory (calculated at run-time) */
 104 .globl IRQ_STACK_START
 105 IRQ_STACK_START:
 106         .word   0x0badc0de
 107
 108 /* IRQ stack memory (calculated at run-time) */
 109 .globl FIQ_STACK_START
 110 FIQ_STACK_START:
 111         .word 0x0badc0de
 112 #endif
 113
 114
 115 /*
 116  * the actual reset code
 117  */
 118
 119 reset:
 120         /*
 121          * set the cpu to SVC32 mode
 122          */
 123         mrs     r0,cpsr
 124         bic     r0,r0,#0x1f
 125         orr     r0,r0,#0xd3
 126         msr     cpsr,r0
 127
 128 /* turn off the watchdog */
 129 #if defined(CONFIG_S3C2400)
 130 #define pWTCON          0x15300000
 131 /* Interupt-Controller base addresses */
 132 #define INTMSK          0x14400008
 133 /* clock divisor register */
 134 #define CLKDIVN         0x14800014
 135 #elif defined(CONFIG_S3C2410)
 136 #define pWTCON          0x53000000
 137 /* Interupt-Controller base addresses */
 138 #define INTMSK          0x4A000008
 139 #define INTSUBMSK       0x4A00001C
 140 /* clock divisor register */
 141 #define CLKDIVN         0x4C000014
 142 #endif
 143
 144         ldr     r0, =pWTCON
 145         mov     r1, #0x0
 146         str     r1, [r0]
 147
 148         /*
 149          * mask all IRQs by setting all bits in the INTMR - default
 150          */
 151         mov     r1, #0xffffffff
 152         ldr     r0, =INTMSK
 153         str     r1, [r0]
 154 #if defined(CONFIG_S3C2410)
 155         ldr     r1, =0x3ff
 156         ldr     r0, =INTSUBMSK
 157         str     r1, [r0]
 158 #endif
 159
 160         /* FCLK:HCLK:PCLK = 1:2:4 */
 161         /* default FCLK is 120 MHz ! */
 162         ldr     r0, =CLKDIVN
 163         mov     r1, #3
 164         str     r1, [r0]
 165
 166         /*
 167          * we do sys-critical inits only at reboot,
 168          * not when booting from ram!
 169          */
 170 #ifdef CONFIG_INIT_CRITICAL
 171         bl      cpu_init_crit
 172 #endif
 173
 174 relocate:
 175         /*
 176          * relocate armboot to RAM
 177          */
 178         adr     r0, _start              /* r0 <- current position of code */
 179         ldr     r2, _armboot_start
 180         ldr     r3, _armboot_end
 181         sub     r2, r3, r2              /* r2 <- size of armboot */
 182         ldr     r1, _TEXT_BASE          /* r1 <- destination address */
 183         add     r2, r0, r2              /* r2 <- source end address */
 184
 185         /*
 186          * r0 = source address
 187          * r1 = target address
 188          * r2 = source end address
 189          */
 190 copy_loop:
 191         ldmia   r0!, {r3-r10}
 192         stmia   r1!, {r3-r10}
 193         cmp     r0, r2
 194         ble     copy_loop
 195
 196 #if 0
 197         /* try doing this stuff after the relocation */
 198         ldr     r0, =pWTCON
 199         mov     r1, #0x0
 200         str     r1, [r0]
 201
 202         /*
 203          * mask all IRQs by setting all bits in the INTMR - default
 204          */
 205         mov     r1, #0xffffffff
 206         ldr     r0, =INTMR
 207         str     r1, [r0]
 208
 209         /* FCLK:HCLK:PCLK = 1:2:4 */
 210         /* default FCLK is 120 MHz ! */
 211         ldr     r0, =CLKDIVN
 212         mov     r1, #3
 213         str     r1, [r0]
 214         /* END stuff after relocation */
 215 #endif
 216
 217         /* set up the stack */
 218         ldr     r0, _armboot_end
 219         add     r0, r0, #CONFIG_STACKSIZE
 220         sub     sp, r0, #12             /* leave 3 words for abort-stack */
 221
 222         ldr     pc, _start_armboot
 223
 224 _start_armboot: .word start_armboot
 225
 226
 227 /*
 228  *************************************************************************
 229  *
 230  * CPU_init_critical registers
 231  *
 232  * setup important registers
 233  * setup memory timing
 234  *
 235  *************************************************************************
 236  */
 237
 238
 239 cpu_init_crit:
 240         /*
 241          * flush v4 I/D caches
 242          */
 243         mov     r0, #0
 244         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 245         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 246
 247         /*
 248          * disable MMU stuff and caches
 249          */
 250         mrc     p15, 0, r0, c1, c0, 0
 251         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 252         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 253         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 254         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 255         mcr     p15, 0, r0, c1, c0, 0
 256
 257
 258         /*
 259          * before relocating, we have to setup RAM timing
 260          * because memory timing is board-dependend, you will
 261          * find a memsetup.S in your board directory.
 262          */
 263         mov     ip, lr
 264         bl      memsetup
 265         mov     lr, ip
 266
 267         mov     pc, lr
 268
 269
 270 /*
 271  *************************************************************************
 272  *
 273  * Interrupt handling
 274  *
 275  *************************************************************************
 276  */
 277
 278 @
 279 @ IRQ stack frame.
 280 @
 281 #define S_FRAME_SIZE    72
 282
 283 #define S_OLD_R0        68
 284 #define S_PSR           64
 285 #define S_PC            60
 286 #define S_LR            56
 287 #define S_SP            52
 288
 289 #define S_IP            48
 290 #define S_FP            44
 291 #define S_R10           40
 292 #define S_R9            36
 293 #define S_R8            32
 294 #define S_R7            28
 295 #define S_R6            24
 296 #define S_R5            20
 297 #define S_R4            16
 298 #define S_R3            12
 299 #define S_R2            8
 300 #define S_R1            4
 301 #define S_R0            0
 302
 303 #define MODE_SVC 0x13
 304 #define I_BIT    0x80
 305
 306 /*
 307  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 308  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 309  */
 310
 311         .macro  bad_save_user_regs
 312         sub     sp, sp, #S_FRAME_SIZE
 313         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 314         ldr     r2, _armboot_end
 315         add     r2, r2, #CONFIG_STACKSIZE
 316         sub     r2, r2, #8
 317         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 318         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 319
 320         add     r5, sp, #S_SP
 321         mov     r1, lr
 322         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 323         mov     r0, sp
 324         .endm
 325
 326         .macro  irq_save_user_regs
 327         sub     sp, sp, #S_FRAME_SIZE
 328         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 329         add     r8, sp, #S_PC
 330         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 331         str     lr, [r8, #0]                    @ Save calling PC
 332         mrs     r6, spsr
 333         str     r6, [r8, #4]                    @ Save CPSR
 334         str     r0, [r8, #8]                    @ Save OLD_R0
 335         mov     r0, sp
 336         .endm
 337
 338         .macro  irq_restore_user_regs
 339         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 340         mov     r0, r0
 341         ldr     lr, [sp, #S_PC]                 @ Get PC
 342         add     sp, sp, #S_FRAME_SIZE
 343         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 344         .endm
 345
 346         .macro get_bad_stack
 347         ldr     r13, _armboot_end               @ setup our mode stack
 348         add     r13, r13, #CONFIG_STACKSIZE     @ resides at top of normal stack
 349         sub     r13, r13, #8
 350
 351         str     lr, [r13]                       @ save caller lr / spsr
 352         mrs     lr, spsr
 353         str     lr, [r13, #4]
 354
 355         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 356         @ msr   spsr_c, r13
 357         msr     spsr, r13
 358         mov     lr, pc
 359         movs    pc, lr
 360         .endm
 361
 362         .macro get_irq_stack                    @ setup IRQ stack
 363         ldr     sp, IRQ_STACK_START
 364         .endm
 365
 366         .macro get_fiq_stack                    @ setup FIQ stack
 367         ldr     sp, FIQ_STACK_START
 368         .endm
 369
 370 /*
 371  * exception handlers
 372  */
 373         .align  5
 374 undefined_instruction:
 375         get_bad_stack
 376         bad_save_user_regs
 377         bl      do_undefined_instruction
 378
 379         .align  5
 380 software_interrupt:
 381         get_bad_stack
 382         bad_save_user_regs
 383         bl      do_software_interrupt
 384
 385         .align  5
 386 prefetch_abort:
 387         get_bad_stack
 388         bad_save_user_regs
 389         bl      do_prefetch_abort
 390
 391         .align  5
 392 data_abort:
 393         get_bad_stack
 394         bad_save_user_regs
 395         bl      do_data_abort
 396
 397         .align  5
 398 not_used:
 399         get_bad_stack
 400         bad_save_user_regs
 401         bl      do_not_used
 402
 403 #ifdef CONFIG_USE_IRQ
 404
 405         .align  5
 406 irq:
 407         get_irq_stack
 408         irq_save_user_regs
 409         bl      do_irq
 410         irq_restore_user_regs
 411
 412         .align  5
 413 fiq:
 414         get_fiq_stack
 415         /* someone ought to write a more effiction fiq_save_user_regs */
 416         irq_save_user_regs
 417         bl      do_fiq
 418         irq_restore_user_regs
 419
 420 #else
 421
 422         .align  5
 423 irq:
 424         get_bad_stack
 425         bad_save_user_regs
 426         bl      do_irq
 427
 428         .align  5
 429 fiq:
 430         get_bad_stack
 431         bad_save_user_regs
 432         bl      do_fiq
 433
 434 #endif
 435
 436         .align  5
 437 .globl reset_cpu
 438 reset_cpu:
 439 #ifdef CONFIG_S3C2400
 440         bl      disable_interrupts
 441 # ifdef CONFIG_TRAB
 442         bl      disable_vfd
 443 # endif
 444         ldr     r1, _rWTCON
 445         ldr     r2, _rWTCNT
 446         /* Disable watchdog */
 447         mov     r3, #0x0000
 448         str     r3, [r1]
 449         /* Initialize watchdog timer count register */
 450         mov     r3, #0x0001
 451         str     r3, [r2]
 452         /* Enable watchdog timer; assert reset at timer timeout */
 453         mov     r3, #0x0021
 454         str     r3, [r1]
 455 _loop_forever:
 456         b       _loop_forever
 457 _rWTCON:
 458         .word   0x15300000
 459 _rWTCNT:
 460         .word   0x15300008
 461 #else /* ! CONFIG_S3C2400 */
 462         mov     ip, #0
 463         mcr     p15, 0, ip, c7, c7, 0           @ invalidate cache
 464         mcr     p15, 0, ip, c8, c7, 0           @ flush TLB (v4)
 465         mrc     p15, 0, ip, c1, c0, 0           @ get ctrl register
 466         bic     ip, ip, #0x000f                 @ ............wcam
 467         bic     ip, ip, #0x2100                 @ ..v....s........
 468         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 469         mov     pc, r0
 470 #endif /* CONFIG_S3C2400 */