git.sur5r.net Git - u-boot/blob - cpu/arm925t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM925 CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1510 from ARM920 code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij          <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33
  34 #include <config.h>
  35 #include <version.h>
  36
  37 #if defined(CONFIG_OMAP1510)
  38 #include <./configs/omap1510.h>
  39 #endif
  40
  41 /*
  42  *************************************************************************
  43  *
  44  * Jump vector table as in table 3.1 in [1]
  45  *
  46  *************************************************************************
  47  */
  48
  49
  50 .globl _start
  51 _start: b       reset
  52         ldr     pc, _undefined_instruction
  53         ldr     pc, _software_interrupt
  54         ldr     pc, _prefetch_abort
  55         ldr     pc, _data_abort
  56         ldr     pc, _not_used
  57         ldr     pc, _irq
  58         ldr     pc, _fiq
  59
  60 _undefined_instruction: .word undefined_instruction
  61 _software_interrupt:    .word software_interrupt
  62 _prefetch_abort:        .word prefetch_abort
  63 _data_abort:            .word data_abort
  64 _not_used:              .word not_used
  65 _irq:                   .word irq
  66 _fiq:                   .word fiq
  67
  68         .balignl 16,0xdeadbeef
  69
  70
  71 /*
  72  *************************************************************************
  73  *
  74  * Startup Code (reset vector)
  75  *
  76  * do important init only if we don't start from memory!
  77  * setup Memory and board specific bits prior to relocation.
  78  * relocate armboot to ram
  79  * setup stack
  80  *
  81  *************************************************************************
  82  */
  83
  84 _TEXT_BASE:
  85         .word   TEXT_BASE
  86
  87 .globl _armboot_start
  88 _armboot_start:
  89         .word _start
  90
  91 /*
  92  * These are defined in the board-specific linker script.
  93  */
  94 .globl _bss_start
  95 _bss_start:
  96         .word __bss_start
  97
  98 .globl _bss_end
  99 _bss_end:
 100         .word _end
 101
 102 #ifdef CONFIG_USE_IRQ
 103 /* IRQ stack memory (calculated at run-time) */
 104 .globl IRQ_STACK_START
 105 IRQ_STACK_START:
 106         .word   0x0badc0de
 107
 108 /* IRQ stack memory (calculated at run-time) */
 109 .globl FIQ_STACK_START
 110 FIQ_STACK_START:
 111         .word 0x0badc0de
 112 #endif
 113
 114
 115 /*
 116  * the actual reset code
 117  */
 118
 119 reset:
 120         /*
 121          * set the cpu to SVC32 mode
 122          */
 123         mrs     r0,cpsr
 124         bic     r0,r0,#0x1f
 125         orr     r0,r0,#0xd3
 126         msr     cpsr,r0
 127
 128         /*
 129          * Set up 925T mode
 130          */
 131         mov r1, #0x81               /* Set ARM925T configuration. */
 132         mcr p15, 0, r1, c15, c1, 0  /* Write ARM925T configuration register. */
 133
 134         /*
 135          * turn off the watchdog, unlock/diable sequence
 136          */
 137         mov  r1, #0xF5
 138         ldr  r0, =WDTIM_MODE
 139         strh r1, [r0]
 140         mov  r1, #0xA0
 141         strh r1, [r0]
 142
 143         /*
 144          * mask all IRQs by setting all bits in the INTMR - default
 145          */
 146         mov r1, #0xffffffff
 147         ldr r0, =REG_IHL1_MIR
 148         str r1, [r0]
 149         ldr r0, =REG_IHL2_MIR
 150         str r1, [r0]
 151
 152         /*
 153          * wait for dpll to lock
 154          */
 155         ldr  r0, =CK_DPLL1
 156         mov  r1, #0x10
 157         strh r1, [r0]
 158 poll1:
 159         ldrh r1, [r0]
 160         ands r1, r1, #0x01
 161         beq poll1
 162
 163         /*
 164          * we do sys-critical inits only at reboot,
 165          * not when booting from ram!
 166          */
 167 #ifdef CONFIG_INIT_CRITICAL
 168         bl  cpu_init_crit
 169 #endif
 170
 171 relocate:                               /* relocate U-Boot to RAM           */
 172         adr     r0, _start              /* r0 <- current position of code   */
 173         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 174         cmp     r0, r1                  /* don't reloc during debug         */
 175         beq     stack_setup
 176
 177         ldr     r2, _armboot_start
 178         ldr     r3, _bss_start
 179         sub     r2, r3, r2              /* r2 <- size of armboot            */
 180         add     r2, r0, r2              /* r2 <- source end address         */
 181
 182 copy_loop:
 183         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 184         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 185         cmp     r0, r2                  /* until source end addreee [r2]    */
 186         ble     copy_loop
 187
 188         /* Set up the stack                                                 */
 189 stack_setup:
 190         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 191         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 192         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 193 #ifdef CONFIG_USE_IRQ
 194         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 195 #endif
 196         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 197
 198 clear_bss:
 199         ldr     r0, _bss_start          /* find start of bss segment        */
 200         add     r0, r0, #4              /* start at first byte of bss       */
 201         ldr     r1, _bss_end            /* stop here                        */
 202         mov     r2, #0x00000000         /* clear                            */
 203
 204 clbss_l:str     r2, [r0]                /* clear loop...                    */
 205         add     r0, r0, #4
 206         cmp     r0, r1
 207         bne     clbss_l
 208
 209         ldr     pc, _start_armboot
 210
 211 _start_armboot: .word start_armboot
 212
 213
 214 /*
 215  *************************************************************************
 216  *
 217  * CPU_init_critical registers
 218  *
 219  * setup important registers
 220  * setup memory timing
 221  *
 222  *************************************************************************
 223  */
 224
 225
 226 cpu_init_crit:
 227         /*
 228          * flush v4 I/D caches
 229          */
 230         mov     r0, #0
 231         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 232         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 233
 234         /*
 235          * disable MMU stuff and caches
 236          */
 237         mrc     p15, 0, r0, c1, c0, 0
 238         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 239         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 240         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 241         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 242         mcr     p15, 0, r0, c1, c0, 0
 243
 244         /*
 245          * Go setup Memory and board specific bits prior to relocation.
 246          */
 247         mov     ip, lr          /* perserve link reg across call */
 248         bl      platformsetup   /* go setup pll,mux,memory */
 249         mov     lr, ip          /* restore link */
 250         mov     pc, lr          /* back to my caller */
 251 /*
 252  *************************************************************************
 253  *
 254  * Interrupt handling
 255  *
 256  *************************************************************************
 257  */
 258
 259 @
 260 @ IRQ stack frame.
 261 @
 262 #define S_FRAME_SIZE    72
 263
 264 #define S_OLD_R0        68
 265 #define S_PSR           64
 266 #define S_PC            60
 267 #define S_LR            56
 268 #define S_SP            52
 269
 270 #define S_IP            48
 271 #define S_FP            44
 272 #define S_R10           40
 273 #define S_R9            36
 274 #define S_R8            32
 275 #define S_R7            28
 276 #define S_R6            24
 277 #define S_R5            20
 278 #define S_R4            16
 279 #define S_R3            12
 280 #define S_R2            8
 281 #define S_R1            4
 282 #define S_R0            0
 283
 284 #define MODE_SVC 0x13
 285 #define I_BIT    0x80
 286
 287 /*
 288  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 289  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 290  */
 291
 292         .macro  bad_save_user_regs
 293         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current user stack
 294         stmia   sp, {r0 - r12}                  @ Save user registers (now in svc mode) r0-r12
 295
 296         ldr     r2, _armboot_start
 297         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 298         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 299         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc and cpsr (into parm regs)
 300         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 301
 302         add     r5, sp, #S_SP
 303         mov     r1, lr
 304         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 305         mov     r0, sp                          @ save current stack into r0 (param register)
 306         .endm
 307
 308         .macro  irq_save_user_regs
 309         sub     sp, sp, #S_FRAME_SIZE
 310         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 311         add     r8, sp, #S_PC                   @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 312         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 313         str     lr, [r8, #0]                    @ Save calling PC
 314         mrs     r6, spsr
 315         str     r6, [r8, #4]                    @ Save CPSR
 316         str     r0, [r8, #8]                    @ Save OLD_R0
 317         mov     r0, sp
 318         .endm
 319
 320         .macro  irq_restore_user_regs
 321         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 322         mov     r0, r0
 323         ldr     lr, [sp, #S_PC]                 @ Get PC
 324         add     sp, sp, #S_FRAME_SIZE
 325         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 326         .endm
 327
 328         .macro get_bad_stack
 329         ldr     r13, _armboot_start             @ setup our mode stack
 330         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 331         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 332
 333         str     lr, [r13]                       @ save caller lr in position 0 of saved stack
 334         mrs     lr, spsr                        @ get the spsr
 335         str     lr, [r13, #4]                   @ save spsr in position 1 of saved stack
 336
 337         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 338         @ msr   spsr_c, r13
 339         msr     spsr, r13                       @ switch modes, make sure moves will execute
 340         mov     lr, pc                          @ capture return pc
 341         movs    pc, lr                          @ jump to next instruction & switch modes.
 342         .endm
 343
 344         .macro get_irq_stack                    @ setup IRQ stack
 345         ldr     sp, IRQ_STACK_START
 346         .endm
 347
 348         .macro get_fiq_stack                    @ setup FIQ stack
 349         ldr     sp, FIQ_STACK_START
 350         .endm
 351
 352 /*
 353  * exception handlers
 354  */
 355         .align  5
 356 undefined_instruction:
 357         get_bad_stack
 358         bad_save_user_regs
 359         bl      do_undefined_instruction
 360
 361         .align  5
 362 software_interrupt:
 363         get_bad_stack
 364         bad_save_user_regs
 365         bl      do_software_interrupt
 366
 367         .align  5
 368 prefetch_abort:
 369         get_bad_stack
 370         bad_save_user_regs
 371         bl      do_prefetch_abort
 372
 373         .align  5
 374 data_abort:
 375         get_bad_stack
 376         bad_save_user_regs
 377         bl      do_data_abort
 378
 379         .align  5
 380 not_used:
 381         get_bad_stack
 382         bad_save_user_regs
 383         bl      do_not_used
 384
 385 #ifdef CONFIG_USE_IRQ
 386
 387         .align  5
 388 irq:
 389         get_irq_stack
 390         irq_save_user_regs
 391         bl      do_irq
 392         irq_restore_user_regs
 393
 394         .align  5
 395 fiq:
 396         get_fiq_stack
 397         /* someone ought to write a more effiction fiq_save_user_regs */
 398         irq_save_user_regs
 399         bl      do_fiq
 400         irq_restore_user_regs
 401
 402 #else
 403
 404         .align  5
 405 irq:
 406         get_bad_stack
 407         bad_save_user_regs
 408         bl      do_irq
 409
 410         .align  5
 411 fiq:
 412         get_bad_stack
 413         bad_save_user_regs
 414         bl      do_fiq
 415
 416 #endif
 417
 418         .align  5
 419 .globl reset_cpu
 420 reset_cpu:
 421         ldr     r1, rstctl1     /* get clkm1 reset ctl */
 422         mov     r3, #0x3        /* dsp_en + arm_rst = global reset */
 423         strh    r3, [r1]        /* force reset */
 424         mov     r0, r0
 425 _loop_forever:
 426         b       _loop_forever
 427 rstctl1:
 428         .word   0xfffece10