git.sur5r.net Git - u-boot/blob - cpu/at91rm9200/start.S

   1 /*
   2  *  armboot - Startup Code for ARM720 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26
  27 #include "config.h"
  28 #include "version.h"
  29
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 _TEXT_BASE:
  75         .word   TEXT_BASE
  76
  77 .globl _armboot_start
  78 _armboot_start:
  79         .word _start
  80
  81 /*
  82  * Note: _armboot_end_data and _armboot_end are defined
  83  * by the (board-dependent) linker script.
  84  * _armboot_end_data is the first usable FLASH address after armboot
  85  */
  86 .globl _armboot_end_data
  87 _armboot_end_data:
  88         .word armboot_end_data
  89 /*
  90  * Note: armboot_end is defined by the (board-dependent) linker script
  91  */
  92 .globl _armboot_end
  93 _armboot_end:
  94         .word armboot_end
  95
  96 #ifdef CONFIG_USE_IRQ
  97 /* IRQ stack memory (calculated at run-time) */
  98 .globl IRQ_STACK_START
  99 IRQ_STACK_START:
 100         .word   0x0badc0de
 101
 102 /* IRQ stack memory (calculated at run-time) */
 103 .globl FIQ_STACK_START
 104 FIQ_STACK_START:
 105         .word 0x0badc0de
 106 #endif
 107
 108
 109 /*
 110  * the actual reset code
 111  */
 112
 113 reset:
 114         /*
 115          * set the cpu to SVC32 mode
 116          */
 117         mrs     r0,cpsr
 118         bic     r0,r0,#0x1f
 119         orr     r0,r0,#0x13
 120         msr     cpsr,r0
 121
 122         /*
 123          * relocate exeception table
 124          */
 125         ldr     r0, =_start
 126         ldr     r1, =0x0
 127         mov     r2, #16
 128 copyex:
 129         subs    r2, r2, #1
 130         ldr     r3, [r0], #4
 131         str     r3, [r1], #4
 132         bne     copyex
 133
 134         /*
 135          * we do sys-critical inits only at reboot,
 136          * not when booting from ram!
 137          */
 138 #ifdef CONFIG_INIT_CRITICAL
 139         bl      cpu_init_crit
 140 #endif
 141
 142         /* Set up the stack                                                 */
 143 stack_setup:
 144         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 145         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 146         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 147 #ifdef CONFIG_USE_IRQ
 148         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 149 #endif
 150         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 151
 152         ldr pc,_start_armboot
 153
 154 _start_armboot: .word start_armboot
 155
 156 /*
 157  *************************************************************************
 158  *
 159  * CPU_init_critical registers
 160  *
 161  *************************************************************************
 162  */
 163
 164 cpu_init_crit:
 165         # actually do nothing for now!
 166         mov     pc, lr
 167
 168
 169 /*
 170  *************************************************************************
 171  *
 172  * Interrupt handling
 173  *
 174  *************************************************************************
 175  */
 176
 177 @
 178 @ IRQ stack frame.
 179 @
 180 #define S_FRAME_SIZE    72
 181
 182 #define S_OLD_R0        68
 183 #define S_PSR           64
 184 #define S_PC            60
 185 #define S_LR            56
 186 #define S_SP            52
 187
 188 #define S_IP            48
 189 #define S_FP            44
 190 #define S_R10           40
 191 #define S_R9            36
 192 #define S_R8            32
 193 #define S_R7            28
 194 #define S_R6            24
 195 #define S_R5            20
 196 #define S_R4            16
 197 #define S_R3            12
 198 #define S_R2            8
 199 #define S_R1            4
 200 #define S_R0            0
 201
 202 #define MODE_SVC 0x13
 203 #define I_BIT    0x80
 204
 205 /*
 206  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 207  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 208  */
 209
 210         .macro  bad_save_user_regs
 211         sub     sp, sp, #S_FRAME_SIZE
 212         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 213         add     r8, sp, #S_PC
 214
 215         ldr     r2, _armboot_end
 216         add     r2, r2, #CONFIG_STACKSIZE
 217         sub     r2, r2, #8
 218         ldmia   r2, {r2 - r4}                   @ get pc, cpsr, old_r0
 219         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 220
 221         add     r5, sp, #S_SP
 222         mov     r1, lr
 223         stmia   r5, {r0 - r4}                   @ save sp_SVC, lr_SVC, pc, cpsr, old_r
 224         mov     r0, sp
 225         .endm
 226
 227         .macro  irq_save_user_regs
 228         sub     sp, sp, #S_FRAME_SIZE
 229         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 230         add     r8, sp, #S_PC
 231         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 232         str     lr, [r8, #0]                    @ Save calling PC
 233         mrs     r6, spsr
 234         str     r6, [r8, #4]                    @ Save CPSR
 235         str     r0, [r8, #8]                    @ Save OLD_R0
 236         mov     r0, sp
 237         .endm
 238
 239         .macro  irq_restore_user_regs
 240         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 241         mov     r0, r0
 242         ldr     lr, [sp, #S_PC]                 @ Get PC
 243         add     sp, sp, #S_FRAME_SIZE
 244         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 245         .endm
 246
 247         .macro get_bad_stack
 248         ldr     r13, _armboot_end               @ setup our mode stack
 249         add     r13, r13, #CONFIG_STACKSIZE     @ resides at top of normal stack
 250         sub     r13, r13, #8
 251
 252         str     lr, [r13]                       @ save caller lr / spsr
 253         mrs     lr, spsr
 254         str     lr, [r13, #4]
 255
 256         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 257         msr     spsr_c, r13
 258         mov     lr, pc
 259         movs    pc, lr
 260         .endm
 261
 262         .macro get_irq_stack                    @ setup IRQ stack
 263         ldr     sp, IRQ_STACK_START
 264         .endm
 265
 266         .macro get_fiq_stack                    @ setup FIQ stack
 267         ldr     sp, FIQ_STACK_START
 268         .endm
 269
 270 /*
 271  * exception handlers
 272  */
 273         .align  5
 274 undefined_instruction:
 275         get_bad_stack
 276         bad_save_user_regs
 277         bl      do_undefined_instruction
 278
 279         .align  5
 280 software_interrupt:
 281         get_bad_stack
 282         bad_save_user_regs
 283         bl      do_software_interrupt
 284
 285         .align  5
 286 prefetch_abort:
 287         get_bad_stack
 288         bad_save_user_regs
 289         bl      do_prefetch_abort
 290
 291         .align  5
 292 data_abort:
 293         get_bad_stack
 294         bad_save_user_regs
 295         bl      do_data_abort
 296
 297         .align  5
 298 not_used:
 299         get_bad_stack
 300         bad_save_user_regs
 301         bl      do_not_used
 302
 303 #ifdef CONFIG_USE_IRQ
 304
 305         .align  5
 306 irq:
 307         get_irq_stack
 308         irq_save_user_regs
 309         bl      do_irq
 310         irq_restore_user_regs
 311
 312         .align  5
 313 fiq:
 314         get_fiq_stack
 315         /* someone ought to write a more effiction fiq_save_user_regs */
 316         irq_save_user_regs
 317         bl      do_fiq
 318         irq_restore_user_regs
 319
 320 #else
 321
 322         .align  5
 323 irq:
 324         get_bad_stack
 325         bad_save_user_regs
 326         bl      do_irq
 327
 328         .align  5
 329 fiq:
 330         get_bad_stack
 331         bad_save_user_regs
 332         bl      do_fiq
 333
 334 #endif
 335
 336         .align  5
 337 .globl reset_cpu
 338 reset_cpu:
 339         mov     pc, r0