git.sur5r.net Git - u-boot/blob - cpu/mpc824x/u-boot.lds

   1 /*
   2  * (C) Copyright 2001-2007
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp : { *(.interp) }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)               }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)               }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)                }
  42   .rela.got      : { *(.rela.got)               }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)                }
  48   .rela.bss      : { *(.rela.bss)               }
  49   .rel.plt       : { *(.rel.plt)                }
  50   .rela.plt      : { *(.rela.plt)               }
  51   .init          : { *(.init)   }
  52   .plt : { *(.plt) }
  53   .text      :
  54   {
  55     cpu/mpc824x/start.o         (.text)
  56     *(.text)
  57     *(.fixup)
  58     *(.got1)
  59     . = ALIGN(16);
  60     *(.rodata)
  61     *(.rodata1)
  62     *(.rodata.str1.4)
  63     *(.eh_frame)
  64   }
  65   .fini      : { *(.fini)    } =0
  66   .ctors     : { *(.ctors)   }
  67   .dtors     : { *(.dtors)   }
  68
  69   /* Read-write section, merged into data segment: */
  70   . = (. + 0x0FFF) & 0xFFFFF000;
  71   _erotext = .;
  72   PROVIDE (erotext = .);
  73   .reloc   :
  74   {
  75     *(.got)
  76     _GOT2_TABLE_ = .;
  77     *(.got2)
  78     _FIXUP_TABLE_ = .;
  79     *(.fixup)
  80   }
  81   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  82   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  83
  84   .data    :
  85   {
  86     *(.data)
  87     *(.data1)
  88     *(.sdata)
  89     *(.sdata2)
  90     *(.dynamic)
  91     CONSTRUCTORS
  92   }
  93   _edata  =  .;
  94   PROVIDE (edata = .);
  95
  96   . = .;
  97   __u_boot_cmd_start = .;
  98   .u_boot_cmd : { *(.u_boot_cmd) }
  99   __u_boot_cmd_end = .;
 100
 101
 102   . = .;
 103   __start___ex_table = .;
 104   __ex_table : { *(__ex_table) }
 105   __stop___ex_table = .;
 106
 107   . = ALIGN(4096);
 108   __init_begin = .;
 109   .text.init : { *(.text.init) }
 110   .data.init : { *(.data.init) }
 111   . = ALIGN(4096);
 112   __init_end = .;
 113
 114   __bss_start = .;
 115   .bss (NOLOAD)       :
 116   {
 117    *(.sbss) *(.scommon)
 118    *(.dynbss)
 119    *(.bss)
 120    *(COMMON)
 121    . = ALIGN(4);
 122   }
 123   _end = . ;
 124   PROVIDE (end = .);
 125 }