git.sur5r.net Git - glabels/blob - glabels1/macros/gnome-libgtop-check.m4

   1 dnl
   2 dnl GNOME_LIBGTOP_TYPES
   3 dnl
   4 dnl some typechecks for libgtop.
   5 dnl
   6
   7 AC_DEFUN([GNOME_LIBGTOP_TYPES],
   8 [
   9         AC_CHECK_TYPE(u_int64_t, unsigned long long int)
  10         AC_CHECK_TYPE(int64_t, long long int)
  11 ])
  12
  13 dnl
  14 dnl GNOME_LIBGTOP_HOOK (minversion, script-if-libgtop-enabled, failflag)
  15 dnl
  16 dnl if failflag is "fail" then GNOME_LIBGTOP_HOOK will abort if LibGTop
  17 dnl is not found.
  18 dnl
  19
  20 AC_DEFUN([GNOME_LIBGTOP_HOOK],
  21 [
  22         AC_REQUIRE([GNOME_LIBGTOP_TYPES])
  23
  24         AC_SUBST(LIBGTOP_LIBDIR)
  25         AC_SUBST(LIBGTOP_INCLUDEDIR)
  26         AC_SUBST(LIBGTOP_EXTRA_LIBS)
  27         AC_SUBST(LIBGTOP_LIBS)
  28         AC_SUBST(LIBGTOP_INCS)
  29         AC_SUBST(LIBGTOP_NAMES_LIBS)
  30         AC_SUBST(LIBGTOP_NAMES_INCS)
  31         AC_SUBST(LIBGTOP_GUILE_INCS)
  32         AC_SUBST(LIBGTOP_GUILE_LIBS)
  33         AC_SUBST(LIBGTOP_GUILE_NAMES_INCS)
  34         AC_SUBST(LIBGTOP_GUILE_NAMES_LIBS)
  35         AC_SUBST(LIBGTOP_MAJOR_VERSION)
  36         AC_SUBST(LIBGTOP_MINOR_VERSION)
  37         AC_SUBST(LIBGTOP_MICRO_VERSION)
  38         AC_SUBST(LIBGTOP_VERSION)
  39         AC_SUBST(LIBGTOP_VERSION_CODE)
  40         AC_SUBST(LIBGTOP_SERVER_VERSION)
  41         AC_SUBST(LIBGTOP_INTERFACE_AGE)
  42         AC_SUBST(LIBGTOP_BINARY_AGE)
  43         AC_SUBST(LIBGTOP_BINDIR)
  44         AC_SUBST(LIBGTOP_SERVER)
  45
  46         dnl Get the cflags and libraries from the libgtop-config script
  47         dnl
  48         AC_ARG_WITH(libgtop,
  49         [  --with-libgtop=PFX      Prefix where LIBGTOP is installed (optional)],
  50         libgtop_config_prefix="$withval", libgtop_config_prefix="")
  51         AC_ARG_WITH(libgtop-exec,
  52         [  --with-libgtop-exec=PFX Exec prefix where LIBGTOP is installed (optional)],
  53         libgtop_config_exec_prefix="$withval", libgtop_config_exec_prefix="")
  54
  55         if test x$libgtop_config_exec_prefix != x ; then
  56           libgtop_config_args="$libgtop_config_args --exec-prefix=$libgtop_config_exec_prefix"
  57           if test x${LIBGTOP_CONFIG+set} != xset ; then
  58             LIBGTOP_CONFIG=$libgtop_config_exec_prefix/bin/libgtop-config
  59           fi
  60         fi
  61         if test x$libgtop_config_prefix != x ; then
  62           libgtop_config_args="$libgtop_config_args --prefix=$libgtop_config_prefix"
  63           if test x${LIBGTOP_CONFIG+set} != xset ; then
  64             LIBGTOP_CONFIG=$libgtop_config_prefix/bin/libgtop-config
  65           fi
  66         fi
  67
  68         AC_PATH_PROG(LIBGTOP_CONFIG, libgtop-config, no)
  69         dnl IMPORTANT NOTICE:
  70         dnl   If you increase this number here, this means that *ALL*
  71         dnl   modules will require the new version, even if they explicitly
  72         dnl   give a lower number in their `configure.in' !!!
  73         real_min_libgtop_version=1.0.0
  74         min_libgtop_version=ifelse([$1], ,$real_min_libgtop_version,$1)
  75         dnl I know, the following code looks really ugly, but if you want
  76         dnl to make changes, please test it with a brain-dead /bin/sh and
  77         dnl with a brain-dead /bin/test (not all shells/tests support the
  78         dnl `<' operator to compare strings, that's why I convert everything
  79         dnl into numbers and test them).
  80         min_libgtop_major=`echo $min_libgtop_version | \
  81           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  82         min_libgtop_minor=`echo $min_libgtop_version | \
  83           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  84         min_libgtop_micro=`echo $min_libgtop_version | \
  85           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  86         test x$min_libgtop_micro = x && min_libgtop_micro=0
  87         real_min_libgtop_major=`echo $real_min_libgtop_version | \
  88           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  89         real_min_libgtop_minor=`echo $real_min_libgtop_version | \
  90           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  91         real_min_libgtop_micro=`echo $real_min_libgtop_version | \
  92           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  93         test x$real_min_libgtop_micro = x && real_min_libgtop_micro=0
  94         dnl You cannot require a version less then $real_min_libgtop_version,
  95         dnl so you don't need to update each `configure.in' when it's increased.
  96         if test $real_min_libgtop_major -gt $min_libgtop_major ; then
  97           min_libgtop_major=$real_min_libgtop_major
  98           min_libgtop_minor=$real_min_libgtop_minor
  99           min_libgtop_micro=$real_min_libgtop_micro
 100         elif test $real_min_libgtop_major = $min_libgtop_major ; then
 101           if test $real_min_libgtop_minor -gt $min_libgtop_minor ; then
 102             min_libgtop_minor=$real_min_libgtop_minor
 103             min_libgtop_micro=$real_min_libgtop_micro
 104           elif test $real_min_libgtop_minor = $min_libgtop_minor ; then
 105             if test $real_min_libgtop_micro -gt $min_libgtop_micro ; then
 106               min_libgtop_micro=$real_min_libgtop_micro
 107             fi
 108           fi
 109         fi
 110         min_libgtop_version="$min_libgtop_major.$min_libgtop_minor.$min_libgtop_micro"
 111         AC_MSG_CHECKING(for libgtop - version >= $min_libgtop_version)
 112         no_libgtop=""
 113         if test "$LIBGTOP_CONFIG" = "no" ; then
 114           no_libgtop=yes
 115         else
 116           configfile=`$LIBGTOP_CONFIG --config`
 117           libgtop_major_version=`$LIBGTOP_CONFIG --version | \
 118             sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 119           libgtop_minor_version=`$LIBGTOP_CONFIG --version | \
 120             sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 121           libgtop_micro_version=`$LIBGTOP_CONFIG --version | \
 122             sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
 123           test $libgtop_major_version != $min_libgtop_major && no_libgtop=yes
 124           test $libgtop_minor_version -lt $min_libgtop_minor && no_libgtop=yes
 125           if test $libgtop_minor_version = $min_libgtop_minor ; then
 126             test $libgtop_micro_version -lt $min_libgtop_micro && no_libgtop=yes
 127           fi
 128           . $configfile
 129         fi
 130         if test x$no_libgtop = x ; then
 131           AC_DEFINE(HAVE_LIBGTOP)
 132           AC_DEFINE_UNQUOTED(LIBGTOP_VERSION, "$LIBGTOP_VERSION")
 133           AC_DEFINE_UNQUOTED(LIBGTOP_VERSION_CODE, $LIBGTOP_VERSION_CODE)
 134           AC_DEFINE_UNQUOTED(LIBGTOP_MAJOR_VERSION, $LIBGTOP_MAJOR_VERSION)
 135           AC_DEFINE_UNQUOTED(LIBGTOP_MINOR_VERSION, $LIBGTOP_MINOR_VERSION)
 136           AC_DEFINE_UNQUOTED(LIBGTOP_MICRO_VERSION, $LIBGTOP_MICRO_VERSION)
 137           AC_DEFINE_UNQUOTED(LIBGTOP_SERVER_VERSION, $LIBGTOP_SERVER_VERSION)
 138           AC_MSG_RESULT(yes)
 139           dnl Note that an empty true branch is not valid sh syntax.
 140           ifelse([$2], [], :, [$2])
 141         else
 142           AC_MSG_RESULT(no)
 143           if test "x$3" = "xfail"; then
 144             AC_MSG_ERROR(LibGTop >= $min_libgtop_version not found)
 145           else
 146             AC_MSG_WARN(LibGTop >= $min_libgtop_version not found)
 147           fi
 148         fi
 149
 150         AM_CONDITIONAL(HAVE_LIBGTOP, test x$no_libgtop != xyes)
 151 ])
 152
 153 AC_DEFUN([GNOME_INIT_LIBGTOP],[
 154         GNOME_LIBGTOP_HOOK($1,[ifelse([$3], [], :, [$3])],$2)
 155 ])
 156
 157 dnl
 158 dnl GNOME_LIBGTOP_DOCU
 159 dnl
 160 dnl checks whether the documentation of LibGTop is installed
 161 dnl
 162
 163 AC_DEFUN([GNOME_LIBGTOP_DOCU],
 164 [
 165         AC_REQUIRE([GNOME_LIBGTOP_HOOK])
 166
 167         helpdir="$LIBGTOP_DATADIR/gnome/help/libgtop"
 168
 169         AC_MSG_CHECKING(whether you have the LibGTop Documentation)
 170
 171         if test -f "$helpdir/C/topic.dat" ; then
 172           have_libgtop_docu=yes
 173           AC_DEFINE(HAVE_LIBGTOP_DOCU)
 174         else
 175           have_libgtop_docu=no
 176         fi
 177
 178         AC_MSG_RESULT($have_libgtop_docu)
 179
 180         AM_CONDITIONAL(HAVE_LIBGTOP_DOCU, test x$have_libgtop_docu = xyes)
 181 ])
 182