git.sur5r.net Git - glabels/blob - glabels2/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.52)
   4
   5 AC_INIT(glabels, 2.1.1, http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116)
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   8
   9 AM_MAINTAINER_MODE
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AC_PROG_INTLTOOL([0.21])
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_HEADER_STDC
  20
  21 GNOME_COMPILE_WARNINGS
  22
  23 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
  24
  25 GTK_DOC_CHECK(1.0)
  26
  27 dnl ---------------------------------------------------------------------------
  28 dnl - LIBGLABELS API versioning
  29 dnl ---------------------------------------------------------------------------
  30 dnl From the libtool manual:
  31 dnl 1. Start with version information of `0:0:0' for each libtool library.
  32 dnl 2. Update the version information only immediately before a public release.
  33 dnl    More frequent updates are unnecessary, and only guarantee that the current
  34 dnl    interface number gets larger faster.
  35 dnl 3. If the library source code has changed at all since the last update, then increment
  36 dnl    revision (`c:r:a' becomes `c:r+1:a').
  37 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  38 dnl    increment current, and set revision to 0.
  39 dnl 5. If any interfaces have been added since the last public release, then increment age.
  40 dnl 6. If any interfaces have been removed since the last public release, then set age
  41 dnl    to 0.
  42 LIBGLABELS_C=2
  43 LIBGLABELS_R=0
  44 LIBGLABELS_A=0
  45
  46 LIBGLABELS_VERSION_INFO=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  47 AC_SUBST(LIBGLABELS_VERSION_INFO)
  48
  49
  50 dnl ---------------------------------------------------------------------------
  51 dnl - Library dependencies
  52 dnl ---------------------------------------------------------------------------
  53 GLIB_REQUIRED=2.6.0
  54 GTK_REQUIRED=2.6.0
  55 LIBGNOME_REQUIRED=2.10.0
  56 LIBGNOMEUI_REQUIRED=2.10.0
  57 LIBXML_REQUIRED=2.6.0
  58 LIBGNOMEPRINT_REQUIRED=2.10.0
  59 LIBGNOMEPRINTUI_REQUIRED=2.10.0
  60 LIBGNOMECANVAS_REQUIRED=2.10.0
  61 LIBGLADE_REQUIRED=2.5.0
  62
  63 dnl Make above strings available for packaging files (e.g. rpm spec files)
  64 AC_SUBST(GLIB_REQUIRED)
  65 AC_SUBST(GTK_REQUIRED)
  66 AC_SUBST(LIBGNOME_REQUIRED)
  67 AC_SUBST(LIBGNOMEUI_REQUIRED)
  68 AC_SUBST(LIBXML_REQUIRED)
  69 AC_SUBST(LIBGNOMEPRINT_REQUIRED)
  70 AC_SUBST(LIBGNOMEPRINTUI_REQUIRED)
  71 AC_SUBST(LIBGNOMECANVAS_REQUIRED)
  72 AC_SUBST(LIBGLADE_REQUIRED)
  73
  74
  75 dnl ---------------------------------------------------------------------------
  76 dnl - GLABELS prerequisites
  77 dnl ---------------------------------------------------------------------------
  78 PKG_CHECK_MODULES(GLABELS, \
  79 glib-2.0 >= $GLIB_REQUIRED \
  80 gtk+-2.0 >= $GTK_REQUIRED \
  81 libgnome-2.0 >= $LIBGNOME_REQUIRED \
  82 libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED \
  83 libxml-2.0 >= $LIBXML_REQUIRED \
  84 libgnomeprint-2.2 >= $LIBGNOMEPRINT_REQUIRED \
  85 libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED \
  86 libgnomecanvas-2.0 >= $LIBGNOMECANVAS_REQUIRED \
  87 libglade-2.0 >= $LIBGLADE_REQUIRED \
  88 )
  89
  90 AC_SUBST(GLABELS_CFLAGS)
  91 AC_SUBST(GLABELS_LIBS)
  92
  93
  94 dnl ---------------------------------------------------------------------------
  95 dnl - LIBGLABELS more modest prerequisites
  96 dnl ---------------------------------------------------------------------------
  97 PKG_CHECK_MODULES(LIBGLABELS, \
  98 glib-2.0 >= $GLIB_REQUIRED \
  99 libxml-2.0 >= $LIBXML_REQUIRED \
 100 )
 101
 102 AC_SUBST(LIBGLABELS_CFLAGS)
 103 AC_SUBST(LIBGLABELS_LIBS)
 104
 105
 106 dnl ---------------------------------------------------------------------------
 107 dnl - Enable deprecation testing
 108 dnl ---------------------------------------------------------------------------
 109 AC_ARG_ENABLE(deprecations,
 110               [AC_HELP_STRING([--enable-deprecations],
 111                               [warn about deprecated usages [default=no]])],,
 112               [enable_deprecations=no])
 113
 114 if test "x$enable_deprecations" = "xyes"; then
 115    DISABLE_DEPRECATED_CFLAGS="\
 116 -DG_DISABLE_DEPRECATED \
 117 -DGDK_DISABLE_DEPRECATED \
 118 -DGTK_DISABLE_DEPRECATED \
 119 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 120 -DGNOME_DISABLE_DEPRECATED"
 121    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 122 fi
 123
 124
 125 dnl ---------------------------------------------------------------------------
 126 dnl - Is freedesktop mime dbase available?
 127 dnl ---------------------------------------------------------------------------
 128 AC_PATH_PROG(UPDATE_MIME_DATABASE, update-mime-database, no)
 129 AM_CONDITIONAL(HAVE_NEW_MIME, test x$UPDATE_MIME_DATABASE != xno)
 130
 131 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database, no)
 132 AM_CONDITIONAL(HAVE_NEWER_MIME, test x$UPDATE_DESKTOP_DATABASE != xno)
 133
 134 AC_ARG_ENABLE(update-mimedb, AC_HELP_STRING([--disable-update-mimedb],
 135               [disable the update-mime-database after install [default=no]]),,
 136               enable_update_mimedb=yes)
 137 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 138
 139 AC_ARG_ENABLE(update-desktopdb, AC_HELP_STRING([--disable-update-desktopdb],
 140               [disable the update-desktop-database after install [default=no]]),,
 141               enable_update_desktopdb=yes)
 142 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 143
 144
 145 dnl ---------------------------------------------------------------------------
 146 dnl - Supported languages
 147 dnl ---------------------------------------------------------------------------
 148 GETTEXT_PACKAGE=glabels
 149 AC_SUBST(GETTEXT_PACKAGE)
 150 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 151
 152 dnl Add the languages here.
 153 ALL_LINGUAS="fr de ja pt_BR es ru zh_TW.Big5 pl cs it"
 154 AM_GLIB_GNU_GETTEXT
 155
 156
 157 dnl ---------------------------------------------------------------------------
 158 dnl - Makefiles, etc.
 159 dnl ---------------------------------------------------------------------------
 160 AC_OUTPUT([
 161 Makefile
 162 barcode-0.98/Makefile
 163 libglabels/Makefile
 164 libglabels/libglabels.pc
 165 src/Makefile
 166 src/pixmaps/Makefile
 167 src/stock-pixmaps/Makefile
 168 src/mygal/Makefile
 169 src/recent-files/Makefile
 170 data/Makefile
 171 data/templates/Makefile
 172 data/pixmaps/Makefile
 173 data/mime/Makefile
 174 data/glade/Makefile
 175 data/desktop/Makefile
 176 data/dtd/Makefile
 177 data/man/Makefile
 178 po/Makefile.in
 179 help/Makefile
 180 help/C/Makefile
 181 docs/Makefile
 182 docs/libglabels/Makefile
 183 glabels.spec
 184 ])
 185
 186
 187 dnl ---------------------------------------------------------------------------
 188 dnl - Print configuration information
 189 dnl ---------------------------------------------------------------------------
 190 echo "
 191 Configuration:
 192
 193         Package:                ${PACKAGE}-${VERSION}:
 194         Installation prefix     ${prefix}
 195         Source code location:   ${srcdir}
 196         Compiler:               ${CC}
 197
 198 "
 199
 200 cat ${srcdir}/MESSAGE-OF-DOOM
 201