git.sur5r.net Git - cc65/blob - libsrc/apple2/chline.s

   1 ;
   2 ; Ullrich von Bassewitz, 08.08.1998
   3 ;
   4 ; void __fastcall__ chlinexy (unsigned char x, unsigned char y, unsigned char length);
   5 ; void __fastcall__ chline (unsigned char length);
   6 ;
   7
   8         .export         _chlinexy, _chline, chlinedirect
   9         .import         gotoxy, cputdirect
  10
  11         .include        "zeropage.inc"
  12         .include        "apple2.inc"
  13
  14 _chlinexy:
  15         pha                     ; Save the length
  16         jsr     gotoxy          ; Call this one, will pop params
  17         pla                     ; Restore the length and run into _chline
  18
  19 _chline:
  20         .ifdef  __APPLE2ENH__
  21         ldx     #'S'            ; MouseText character
  22         ldy     INVFLG
  23         cpy     #$FF            ; Normal character display mode?
  24         beq     chlinedirect
  25         .endif
  26         ldx     #'-' | $80      ; Horizontal line, screen code
  27
  28 chlinedirect:
  29         stx     tmp1
  30         cmp     #$00            ; Is the length zero?
  31         beq     done            ; Jump if done
  32         sta     tmp2
  33 :       lda     tmp1            ; Screen code
  34         jsr     cputdirect      ; Direct output
  35         dec     tmp2
  36         bne     :-
  37 done:   rts