git.sur5r.net Git - cc65/blob - libsrc/apple2/cvline.s

   1 ;
   2 ; Ullrich von Bassewitz, 08.08.1998
   3 ;
   4 ; void __fastcall__ cvlinexy (unsigned char x, unsigned char y, unsigned char length);
   5 ; void __fastcall__ cvline (unsigned char length);
   6 ;
   7
   8         .export         _cvlinexy, _cvline, cvlinedirect
   9         .import         gotoxy, putchar, newline
  10
  11         .include        "zeropage.inc"
  12
  13 _cvlinexy:
  14         pha                     ; Save the length
  15         jsr     gotoxy          ; Call this one, will pop params
  16         pla                     ; Restore the length and run into _cvline
  17
  18 _cvline:
  19         .ifdef  __APPLE2ENH__
  20         ldx     #'|' | $80      ; Vertical line, screen code
  21         .else
  22         ldx     #'!' | $80      ; Vertical line, screen code
  23         .endif
  24
  25 cvlinedirect:
  26         stx     tmp1
  27         cmp     #$00            ; Is the length zero?
  28         beq     done            ; Jump if done
  29         sta     tmp2
  30 :       lda     tmp1            ; Screen code
  31         jsr     putchar         ; Write, no cursor advance
  32         jsr     newline         ; Advance cursor to next line
  33         dec     tmp2
  34         bne     :-
  35 done:   rts