git.sur5r.net Git - cc65/blob - libsrc/atari/break.s

   1 ;
   2 ; Christian Groessler, 27-Feb-2000
   3 ;
   4 ; void set_brk (unsigned Addr);
   5 ; void reset_brk (void);
   6 ;
   7
   8         .export         _set_brk, _reset_brk
   9         .export         _brk_a, _brk_x, _brk_y, _brk_sr, _brk_pc
  10         .import         _atexit
  11
  12         .include        "atari.inc"
  13
  14
  15 .bss
  16 _brk_a:         .res    1
  17 _brk_x:         .res    1
  18 _brk_y:         .res    1
  19 _brk_sr:        .res    1
  20 _brk_pc:        .res    2
  21
  22 oldvec:         .res    2               ; Old vector
  23
  24
  25 .data
  26 uservec:        jmp     $FFFF           ; Patched at runtime
  27
  28
  29 .code
  30
  31 ; Set the break vector
  32 .proc   _set_brk
  33
  34         sta     uservec+1
  35         stx     uservec+2       ; Set the user vector
  36
  37         lda     oldvec
  38         ora     oldvec+1        ; Did we save the vector already?
  39                 bne     L1              ; Jump if we installed the handler already
  40
  41         lda     VBREAK
  42         sta     oldvec
  43         lda     VBREAK+1
  44         sta     oldvec+1        ; Save the old vector
  45
  46         lda     #<_reset_brk
  47         ldx     #>_reset_brk
  48         jsr     _atexit         ; Install an exit handler
  49
  50 L1:     lda     #<brk_handler   ; Set the break vector to our routine
  51         sta     VBREAK
  52         lda     #>brk_handler
  53         sta     VBREAK+1
  54         rts
  55
  56 .endproc
  57
  58
  59 ; Reset the break vector
  60 .proc   _reset_brk
  61
  62         lda     oldvec
  63         sta     VBREAK
  64         lda     oldvec+1
  65         sta     VBREAK+1
  66         rts
  67
  68 .endproc
  69
  70
  71
  72 ; Break handler, called if a break occurs
  73
  74 .proc   brk_handler
  75
  76         sty     _brk_y
  77         stx     _brk_x
  78         pla
  79         sta     _brk_a
  80         pla
  81         and     #$EF            ; Clear break bit
  82         sta     _brk_sr
  83         pla                     ; PC low
  84         sec
  85         sbc     #2              ; Point to start of brk
  86         sta     _brk_pc
  87         pla                     ; PC high
  88         sbc     #0
  89         sta     _brk_pc+1
  90
  91         jsr     uservec         ; Call the user's routine
  92
  93         lda     _brk_pc+1
  94         pha
  95         lda     _brk_pc
  96         pha
  97         lda     _brk_sr
  98         pha
  99         ldx     _brk_x
 100         ldy     _brk_y
 101         lda     _brk_a
 102         rti                     ; Jump back...
 103
 104 .endproc
 105
 106