git.sur5r.net Git - cc65/blob - libsrc/atari/break.s

   1 ;
   2 ; Christian Groessler, 27-Feb-2000
   3 ;
   4 ; void set_brk (unsigned Addr);
   5 ; void reset_brk (void);
   6 ;
   7
   8         .export         _set_brk, _reset_brk
   9         .destructor     _reset_brk
  10         .export         _brk_a, _brk_x, _brk_y, _brk_sr, _brk_pc
  11
  12         .include        "atari.inc"
  13
  14
  15 .bss
  16 _brk_a:         .res    1
  17 _brk_x:         .res    1
  18 _brk_y:         .res    1
  19 _brk_sr:        .res    1
  20 _brk_pc:        .res    2
  21
  22 oldvec:         .res    2               ; Old vector
  23
  24
  25 .data
  26 uservec:        jmp     $FFFF           ; Patched at runtime
  27
  28
  29 .code
  30
  31 ; Set the break vector
  32 .proc   _set_brk
  33
  34         sta     uservec+1
  35         stx     uservec+2       ; Set the user vector
  36
  37         lda     oldvec
  38         ora     oldvec+1        ; Did we save the vector already?
  39         bne     L1              ; Jump if we installed the handler already
  40
  41         lda     VBREAK
  42         sta     oldvec
  43         lda     VBREAK+1
  44         sta     oldvec+1        ; Save the old vector
  45
  46 L1:     lda     #<brk_handler   ; Set the break vector to our routine
  47         sta     VBREAK
  48         lda     #>brk_handler
  49         sta     VBREAK+1
  50         rts
  51
  52 .endproc
  53
  54
  55 ; Reset the break vector
  56 .proc   _reset_brk
  57
  58         lda     oldvec
  59         ldx     oldvec+1
  60         beq     @L9             ; Jump if vector not installed
  61         sta     VBREAK
  62         stx     VBREAK+1
  63         lda     #$00
  64         sta     oldvec          ; Clear the old vector
  65         stx     oldvec+1
  66 @L9:    rts
  67
  68 .endproc
  69
  70
  71
  72 ; Break handler, called if a break occurs
  73
  74 .proc   brk_handler
  75
  76         sty     _brk_y
  77         stx     _brk_x
  78         pla
  79         sta     _brk_a
  80         pla
  81         and     #$EF            ; Clear break bit
  82         sta     _brk_sr
  83         pla                     ; PC low
  84         sec
  85         sbc     #2              ; Point to start of brk
  86         sta     _brk_pc
  87         pla                     ; PC high
  88         sbc     #0
  89         sta     _brk_pc+1
  90
  91         jsr     uservec         ; Call the user's routine
  92
  93         lda     _brk_pc+1
  94         pha
  95         lda     _brk_pc
  96         pha
  97         lda     _brk_sr
  98         pha
  99         ldx     _brk_x
 100         ldy     _brk_y
 101         lda     _brk_a
 102         rti                     ; Jump back...
 103
 104 .endproc
 105
 106