git.sur5r.net Git - cc65/blob - libsrc/atari/clrscr.s

   1 ;
   2 ; Christian Groessler, Apr-2000
   3 ;
   4 ; void clrscr (void);
   5 ;
   6
   7         .export         _clrscr
   8
   9         .include        "atari.inc"
  10
  11 .ifdef DIRECT_SCREEN
  12
  13         .importzp       ptr1
  14
  15 _clrscr:lda     SAVMSC          ; screen memory
  16         sta     ptr1
  17         lda     SAVMSC+1
  18         clc
  19         adc     #>(40*24)
  20         sta     ptr1+1
  21         lda     #0              ; screen code of space char
  22         ldy     #<(40*24)       ; 40x24: size of default atari screen
  23         ldx     #>(40*24)
  24 _clr1:  sta     (ptr1),y
  25         dey
  26         bne     _clr1
  27         sta     (ptr1),y
  28         dex
  29         bmi     done
  30         ldy     ptr1+1
  31         dey
  32         sty     ptr1+1
  33         ldy     #255
  34         jmp     _clr1
  35
  36 done:   sta     COLCRS
  37         sta     ROWCRS
  38         rts
  39
  40 .else
  41
  42         .import         putchar
  43 _clrscr:
  44         lda     #ATCLR
  45         jmp     putchar
  46
  47 .endif