git.sur5r.net Git - cc65/blob - libsrc/atari/clrscr.s

   1 ;
   2 ; Christian Groessler, Apr-2000
   3 ;
   4 ; void clrscr (void);
   5 ;
   6
   7         .export         _clrscr
   8         .include        "atari.inc"
   9         .importzp       ptr1
  10         .import         setcursor
  11
  12 _clrscr:lda     SAVMSC          ; screen memory
  13         sta     ptr1
  14         lda     SAVMSC+1
  15         clc
  16         adc     #>(40*24)
  17         sta     ptr1+1
  18         lda     #0              ; screen code of space char
  19         sta     OLDCHR
  20         ldy     #<(40*24)       ; 40x24: size of default atari screen
  21         ldx     #>(40*24)
  22 _clr1:  sta     (ptr1),y
  23         dey
  24         bne     _clr1
  25         sta     (ptr1),y
  26         dex
  27         bmi     done
  28         ldy     ptr1+1
  29         dey
  30         sty     ptr1+1
  31         ldy     #255
  32         jmp     _clr1
  33
  34 done:   sta     COLCRS
  35         sta     ROWCRS
  36         jmp     setcursor