git.sur5r.net Git - cc65/blob - libsrc/atari/joy/atrstd.s

   1 ;
   2 ; Standard joystick driver for the Atari. May be used multiple times when linked
   3 ; to the statically application.
   4 ;
   5 ; Ullrich von Bassewitz, 2002-12-21
   6 ; Using the readjoy code from Christian Groessler
   7 ;
   8
   9         .include        "zeropage.inc"
  10
  11         .include        "joy-kernel.inc"
  12         .include        "joy-error.inc"
  13         .include        "atari.inc"
  14
  15         .macpack        generic
  16
  17
  18 ; ------------------------------------------------------------------------
  19 ; Header. Includes jump table
  20
  21 .segment        "JUMPTABLE"
  22
  23 ; Driver signature
  24
  25         .byte   $6A, $6F, $79           ; "joy"
  26         .byte   JOY_API_VERSION         ; Driver API version number
  27
  28 ; Library reference
  29
  30         .addr   $0000
  31
  32 ; Button state masks (8 values)
  33
  34         .byte   $01                     ; JOY_UP
  35         .byte   $02                     ; JOY_DOWN
  36         .byte   $04                     ; JOY_LEFT
  37         .byte   $08                     ; JOY_RIGHT
  38         .byte   $10                     ; JOY_FIRE
  39         .byte   $00                     ; JOY_FIRE2 not available
  40         .byte   $00                     ; Future expansion
  41         .byte   $00                     ; Future expansion
  42
  43 ; Jump table.
  44
  45         .addr   INSTALL
  46         .addr   UNINSTALL
  47         .addr   COUNT
  48         .addr   READJOY
  49         .addr   0                       ; IRQ entry not used
  50
  51 ; ------------------------------------------------------------------------
  52 ; Constants
  53
  54 JOY_COUNT       = 4             ; Number of joysticks we support
  55
  56
  57 ; ------------------------------------------------------------------------
  58 ; Data.
  59
  60
  61 .code
  62
  63 ; ------------------------------------------------------------------------
  64 ; INSTALL routine. Is called after the driver is loaded into memory. If
  65 ; possible, check if the hardware is present and determine the amount of
  66 ; memory available.
  67 ; Must return an JOY_ERR_xx code in a/x.
  68 ;
  69
  70 INSTALL:
  71         lda     #JOY_ERR_OK
  72         ldx     #0
  73 ;       rts                     ; Run into UNINSTALL instead
  74
  75 ; ------------------------------------------------------------------------
  76 ; UNINSTALL routine. Is called before the driver is removed from memory.
  77 ; Can do cleanup or whatever. Must not return anything.
  78 ;
  79
  80 UNINSTALL:
  81         rts
  82
  83
  84 ; ------------------------------------------------------------------------
  85 ; COUNT: Return the total number of available joysticks in a/x.
  86 ;
  87
  88 COUNT:
  89         lda     #JOY_COUNT
  90         ldx     $fcd8
  91         cpx     #$a2
  92         beq     _400800
  93         lsr     a               ; XL and newer machines only have 2 ports
  94 _400800:
  95         ldx     #0
  96         rts
  97
  98 ; ------------------------------------------------------------------------
  99 ; READ: Read a particular joystick passed in A.
 100 ;
 101
 102 READJOY:
 103         and     #3              ; fix joystick number
 104         tax                     ; Joystick number (0-3) into X
 105
 106 ; Read joystick
 107
 108         lda     STRIG0,x        ; get button
 109         asl     a
 110         asl     a
 111         asl     a
 112         asl     a
 113         ora     STICK0,x        ; add position information
 114         eor     #$1F
 115         ldx     #0              ; fix X
 116         rts