git.sur5r.net Git - cc65/blob - libsrc/c128/crt0.s

   1 ;
   2 ; Startup code for cc65 (C128 version)
   3 ;
   4 ; This must be the *first* file on the linker command line
   5 ;
   6
   7         .export         _exit
   8         .import         condes, initlib, donelib
   9         .import         initconio, doneconio, zerobss
  10         .import         push0, _main
  11         .import         RESTOR, BSOUT, CLRCH
  12         .import         __IRQFUNC_TABLE__, __IRQFUNC_COUNT__
  13         .import         __RAM_START__, __RAM_SIZE__
  14
  15         .include        "zeropage.inc"
  16         .include        "c128.inc"
  17
  18
  19 ; ------------------------------------------------------------------------
  20 ; Constants
  21
  22 IRQInd          = $2FD  ; JMP $0000 - used as indirect IRQ vector
  23
  24 ; ------------------------------------------------------------------------
  25 ; Place the startup code in a special segment to cope with the quirks of
  26 ; c128 banking.
  27
  28 .segment        "STARTUP"
  29
  30 ; BASIC header with a SYS call
  31
  32         .org    $1BFF
  33         .word   Head            ; Load address
  34 Head:   .word   @Next
  35         .word   1000            ; Line number
  36         .byte   $9E,"7181"      ; SYS 7181
  37         .byte   $00             ; End of BASIC line
  38 @Next:  .word   0               ; BASIC end marker
  39         .reloc
  40
  41 ; ------------------------------------------------------------------------
  42 ; Actual code
  43
  44 ; Close open files
  45
  46         jsr     CLRCH
  47
  48 ; Switch to the second charset
  49
  50         lda     #14
  51         jsr     BSOUT
  52
  53 ; Set the bank for the file name our execution bank
  54
  55         lda     #0
  56         sta     FNAM_BANK
  57
  58 ; Before doing anything else, we have to setup our banking configuration.
  59 ; Otherwise just the lowest 16K are actually RAM. Writing through the ROM
  60 ; to the underlying RAM works, but it is bad style.
  61
  62         lda     MMU_CR          ; Get current memory configuration...
  63         pha                     ; ...and save it for later
  64         lda     #CC65_MMU_CFG   ; Bank0 with kernal ROM
  65         sta     MMU_CR
  66
  67 ; Save the zero page locations we need
  68
  69         ldx     #zpspace-1
  70 L1:     lda     sp,x
  71         sta     zpsave,x
  72         dex
  73         bpl     L1
  74
  75 ; Clear the BSS data
  76
  77         jsr     zerobss
  78
  79 ; Save system stuff and setup the stack
  80
  81         pla                     ; Get MMU setting
  82         sta     mmusave
  83
  84         tsx
  85         stx     spsave          ; Save the system stack pointer
  86
  87         lda     #<(__RAM_START__ + __RAM_SIZE__)
  88         sta     sp
  89         lda     #>(__RAM_START__ + __RAM_SIZE__)
  90         sta     sp+1            ; Set argument stack ptr
  91
  92 ; Call module constructors
  93
  94         jsr     initlib
  95
  96 ; Initialize conio stuff
  97
  98         jsr     initconio
  99
 100 ; If we have IRQ functions, chain our stub into the IRQ vector
 101
 102         lda     #<__IRQFUNC_COUNT__
 103         beq     NoIRQ1
 104         lda     IRQVec
 105         ldx     IRQVec+1
 106         sta     IRQInd+1
 107         stx     IRQInd+2
 108         lda     #<IRQStub
 109         ldx     #>IRQStub
 110         sei
 111         sta     IRQVec
 112         stx     IRQVec+1
 113         cli
 114
 115 ; Pass an empty command line
 116
 117 NoIRQ1: jsr     push0           ; argc
 118         jsr     push0           ; argv
 119
 120         ldy     #4              ; Argument size
 121         jsr     _main           ; call the users code
 122
 123 ; Back from main (this is also the _exit entry). Reset the IRQ vector if
 124 ; we chained it.
 125
 126 _exit:  lda     #<__IRQFUNC_COUNT__
 127         beq     NoIRQ2
 128         lda     IRQInd+1
 129         ldx     IRQInd+2
 130         sei
 131         sta     IRQVec
 132         stx     IRQVec+1
 133         cli
 134
 135 ; Run module destructors
 136
 137 NoIRQ2: jsr     donelib
 138
 139 ; Reset the conio stuff
 140
 141         jsr     doneconio
 142
 143 ; Reset the stack
 144
 145         ldx     spsave
 146         txs
 147
 148 ; Copy back the zero page stuff
 149
 150         ldx     #zpspace-1
 151 L2:     lda     zpsave,x
 152         sta     sp,x
 153         dex
 154         bpl     L2
 155
 156 ; Reset the memory configuration
 157
 158         lda     mmusave
 159         sta     MMU_CR
 160
 161 ; Done, restore kernal vectors in an attempt to cleanup
 162
 163         jmp     RESTOR
 164
 165 ; ------------------------------------------------------------------------
 166 ; The C128 has ROM parallel to the RAM starting from $4000. The startup code
 167 ; above will change this setting so that we have RAM from $0000-$BFFF. This
 168 ; works quite well with the exception of interrupts: The interrupt handler
 169 ; is in ROM, and the ROM switches back to the ROM configuration, which means
 170 ; that parts of our program may not be accessible. To solve this, we place
 171 ; the following code into a special segment called "LOWCODE" which will be
 172 ; placed just above the startup code, so it goes into a RAM area that is
 173 ; not banked.
 174
 175 .segment        "LOWCODE"
 176
 177 IRQStub:
 178         cld                             ; Just to be sure
 179         lda     MMU_CR                  ; Get old register value
 180         pha                             ; And save on stack
 181         lda     #CC65_MMU_CFG           ; Bank 0 with kernal ROM
 182         sta     MMU_CR
 183         ldy     #<(__IRQFUNC_COUNT__*2)
 184         lda     #<__IRQFUNC_TABLE__
 185         ldx     #>__IRQFUNC_TABLE__
 186         jsr     condes                  ; Call the functions
 187         pla                             ; Get old register value
 188         sta     MMU_CR
 189         jmp     IRQInd                  ; Jump to the saved IRQ vector
 190
 191
 192 ; ------------------------------------------------------------------------
 193 ; Data
 194
 195 .data
 196 zpsave: .res    zpspace
 197
 198 .bss
 199 spsave: .res    1
 200 mmusave:.res    1
 201
 202
 203