git.sur5r.net Git - cc65/blob - libsrc/c64/c64-numpad.s

   1 ;
   2 ; Joystick driver using C128 number pad in 64 mode.
   3 ; May be used multiple times when linked to the statically application.
   4 ;
   5 ; Stefan Haubenthal, 2004-01-26
   6 ; Based on Ullrich von Bassewitz, 2002-12-20
   7 ;
   8
   9         .include        "zeropage.inc"
  10
  11         .include        "joy-kernel.inc"
  12         .include        "joy-error.inc"
  13         .include        "c64.inc"
  14
  15         .macpack        generic
  16
  17
  18 ; ------------------------------------------------------------------------
  19 ; Header. Includes jump table
  20
  21 .segment        "JUMPTABLE"
  22
  23 ; Driver signature
  24
  25         .byte   $6A, $6F, $79           ; "joy"
  26         .byte   JOY_API_VERSION         ; Driver API version number
  27
  28 ; Button state masks (8 values)
  29
  30         .byte   $02                     ; JOY_UP        "8"
  31         .byte   $10                     ; JOY_DOWN      "2"
  32         .byte   $20                     ; JOY_LEFT      "4"
  33         .byte   $08                     ; JOY_RIGHT     "6"
  34         .byte   $04                     ; JOY_FIRE      "5" ENTER
  35         .byte   $00                     ; JOY_FIRE2 unavailable
  36         .byte   $00                     ; Future expansion
  37         .byte   $00                     ; Future expansion
  38
  39 ; Jump table.
  40
  41         .addr   INSTALL
  42         .addr   UNINSTALL
  43         .addr   COUNT
  44         .addr   READ
  45         .addr   0                       ; IRQ entry unused
  46
  47 ; ------------------------------------------------------------------------
  48 ; Constants
  49
  50 JOY_COUNT       = 1             ; Number of joysticks we support
  51
  52
  53 ; ------------------------------------------------------------------------
  54 ; Data.
  55
  56
  57 .code
  58
  59 ; ------------------------------------------------------------------------
  60 ; INSTALL routine. Is called after the driver is loaded into memory. If
  61 ; possible, check if the hardware is present and determine the amount of
  62 ; memory available.
  63 ; Must return an JOY_ERR_xx code in a/x.
  64 ;
  65
  66 INSTALL:
  67         lda     #JOY_ERR_OK             ; Assume we have a joystick
  68         ldx     VIC_CLK_128             ; Test for a C128
  69         cpx     #$FF
  70         bne     @C128                   ; Jump if we have one
  71         lda     #JOY_ERR_NO_DEVICE      ; No C128 -> no numpad
  72 @C128:  ldx     #0                      ; Set high byte
  73
  74 ;       rts                     ; Run into UNINSTALL instead
  75
  76 ; ------------------------------------------------------------------------
  77 ; UNINSTALL routine. Is called before the driver is removed from memory.
  78 ; Can do cleanup or whatever. Must not return anything.
  79 ;
  80
  81 UNINSTALL:
  82         rts
  83
  84
  85 ; ------------------------------------------------------------------------
  86 ; COUNT: Return the total number of available joysticks in a/x.
  87 ;
  88
  89 COUNT:  lda     #JOY_COUNT
  90         ldx     #0
  91         rts
  92
  93 ; ------------------------------------------------------------------------
  94 ; READ: Read a particular joystick passed in A.
  95 ;
  96
  97 READ:   tax                     ; Clear high byte
  98         lda     #$FD
  99         ldy     #$FE
 100         sei
 101         sta     VIC_KBD_128
 102         lda     CIA1_PRB
 103         and     #%00110000
 104         eor     #%00110000
 105         lsr
 106         lsr
 107         sty     VIC_KBD_128
 108         eor     CIA1_PRB
 109         iny
 110         sty     VIC_KBD_128     ; Reset to $FF
 111         cli
 112         and     #%11111110
 113         eor     #%11111110
 114         rts
 115